A modern list api for Emacs. No 'cl required.

It's available on marmalade and Melpa:

M-x package-install dash

Or you can just dump dash.el in your load path somewhere.

If you want the function combinators, then also:

M-x package-install dash-functional

Add this to the big comment block at the top:

;; Package-Requires: ((dash "2.10.0"))

To get function combinators:

;; Package-Requires: ((dash "2.10.0") (dash-functional "1.2.0") (emacs "24"))

Font lock of dash functions in emacs lisp buffers is now optional. Include this in your emacs settings to get syntax highlighting:

(eval-after-load "dash" '(dash-enable-font-lock))

Functions in this category take a transforming function, which is then applied sequentially to each or selected elements of the input list. The results are collected in order and returned as new list.

• -map (fn list)
• -map-when (pred rep list)
• -map-indexed (fn list)
• -annotate (fn list)
• -splice (pred fun list)
• -splice-list (pred new-list list)
• -mapcat (fn list)
• -copy (arg)

Functions returning a sublist of the original list.

• -filter (pred list)
• -remove (pred list)
• -non-nil (list)
• -slice (list from &optional to step)
• -take (n list)
• -drop (n list)
• -take-while (pred list)
• -drop-while (pred list)
• -select-by-indices (indices list)

Bag of various functions which modify input list.

• -keep (fn list)
• -concat (&rest lists)
• -flatten (l)
• -flatten-n (num list)
• -replace (old new list)
• -insert-at (n x list)
• -replace-at (n x list)
• -update-at (n func list)
• -remove-at (n list)
• -remove-at-indices (indices list)

Functions reducing lists into single value.

• -reduce-from (fn initial-value list)
• -reduce-r-from (fn initial-value list)
• -reduce (fn list)
• -reduce-r (fn list)
• -count (pred list)
• -sum (list)
• -product (list)
• -min (list)
• -min-by (comparator list)
• -max (list)
• -max-by (comparator list)

Operations dual to reductions, building lists from seed value rather than consuming a list to produce a single value.

• -iterate (fun init n)
• -unfold (fun seed)

• -any? (pred list)
• -all? (pred list)
• -none? (pred list)
• -only-some? (pred list)
• -contains? (list element)
• -same-items? (list list2)
• -is-prefix? (prefix list)
• -is-suffix? (suffix list)
• -is-infix? (infix list)

Functions partitioning the input list into a list of lists.

• -split-at (n list)
• -split-with (pred list)
• -split-on (item list)
• -split-when (fn list)
• -separate (pred list)
• -partition (n list)
• -partition-all (n list)
• -partition-in-steps (n step list)
• -partition-all-in-steps (n step list)
• -partition-by (fn list)
• -partition-by-header (fn list)
• -group-by (fn list)

Return indices of elements based on predicates, sort elements by indices etc.

• -elem-index (elem list)
• -elem-indices (elem list)
• -find-index (pred list)
• -find-last-index (pred list)
• -find-indices (pred list)
• -grade-up (comparator list)
• -grade-down (comparator list)

Operations pretending lists are sets.

• -union (list list2)
• -difference (list list2)
• -intersection (list list2)
• -distinct (list)

Other list functions not fit to be classified elsewhere.

• -rotate (n list)
• -repeat (n x)
• -cons* (&rest args)
• -snoc (list elem &rest elements)
• -interpose (sep list)
• -interleave (&rest lists)
• -zip-with (fn list1 list2)
• -zip (&rest lists)
• -zip-fill (fill-value &rest lists)
• -cycle (list)
• -pad (fill-value &rest lists)
• -table (fn &rest lists)
• -table-flat (fn &rest lists)
• -first (pred list)
• -some (pred list)
• -last (pred list)
• -first-item (list)
• -last-item (list)
• -butlast (list)
• -sort (comparator list)
• -list (&rest args)
• -fix (fn list)

Functions pretending lists are trees.

• -tree-seq (branch children tree)
• -tree-map (fn tree)
• -tree-map-nodes (pred fun tree)
• -tree-reduce (fn tree)
• -tree-reduce-from (fn init-value tree)
• -tree-mapreduce (fn folder tree)
• -tree-mapreduce-from (fn folder init-value tree)
• -clone (list)

• -> (x &optional form &rest more)
• ->> (x form &rest more)
• --> (x form &rest more)

Convenient versions of let and let* constructs combined with flow control.

• -when-let (var-val &rest body)
• -when-let* (vars-vals &rest body)
• -if-let (var-val then &rest else)
• -if-let* (vars-vals then &rest else)
• -let (varlist &rest body)
• -let* (varlist &rest body)
• -lambda (match-form &rest body)

Functions iterating over lists for side-effect only.

• -each (list fn)
• -each-while (list pred fn)
• -dotimes (num fn)

• !cons (car cdr)
• !cdr (list)

These combinators require Emacs 24 for its lexical scope. So they are offered in a separate package: dash-functional.

• -partial (fn &rest args)
• -rpartial (fn &rest args)
• -juxt (&rest fns)
• -compose (&rest fns)
• -applify (fn)
• -on (operator transformer)
• -flip (func)
• -const (c)
• -cut (&rest params)
• -not (pred)
• -orfn (&rest preds)
• -andfn (&rest preds)
• -iteratefn (fn n)
• -fixfn (fn &optional equal-test halt-test)
• -prodfn (&rest fns)

There are also anaphoric versions of functions where that makes sense, prefixed with two dashes instead of one.

While -map takes a function to map over the list, you can also use the anaphoric form with double dashes - which will then be executed with it exposed as the list item. Here's an example:

(-map (lambda (n) (* n n)) '(1 2 3 4)) ;; normal version

(--map (* it it) '(1 2 3 4)) ;; anaphoric version

of course the original can also be written like

(defun square (n) (* n n))

(-map 'square '(1 2 3 4))

which demonstrates the usefulness of both versions.

Functions in this category take a transforming function, which is then applied sequentially to each or selected elements of the input list. The results are collected in order and returned as new list.

Return a new list consisting of the result of applying fn to the items in list.

(-map (lambda (num) (* num num)) '(1 2 3 4)) ;; => '(1 4 9 16)
(-map 'square '(1 2 3 4)) ;; => '(1 4 9 16)
(--map (* it it) '(1 2 3 4)) ;; => '(1 4 9 16)

Return a new list where the elements in list that does not match the pred function are unchanged, and where the elements in list that do match the pred function are mapped through the rep function.

Alias: -replace-where

See also: -update-at

(-map-when 'even? 'square '(1 2 3 4)) ;; => '(1 4 3 16)
(--map-when (> it 2) (* it it) '(1 2 3 4)) ;; => '(1 2 9 16)
(--map-when (= it 2) 17 '(1 2 3 4)) ;; => '(1 17 3 4)

Return a new list consisting of the result of (fn index item) for each item in list.

In the anaphoric form --map-indexed, the index is exposed as it-index.

(-map-indexed (lambda (index item) (- item index)) '(1 2 3 4)) ;; => '(1 1 1 1)
(--map-indexed (- it it-index) '(1 2 3 4)) ;; => '(1 1 1 1)

Return a list of cons cells where each cell is fn applied to each element of list paired with the unmodified element of list.

(-annotate '1+ '(1 2 3)) ;; => '((2 . 1) (3 . 2) (4 . 3))
(-annotate 'length '(("h" "e" "l" "l" "o") ("hello" "world"))) ;; => '((5 "h" "e" "l" "l" "o") (2 "hello" "world"))
(--annotate (< 1 it) '(0 1 2 3)) ;; => '((nil . 0) (nil . 1) (t . 2) (t . 3))

Splice lists generated by fun in place of elements matching pred in list.

fun takes the element matching pred as input.

This function can be used as replacement for ,@ in case you need to splice several lists at marked positions (for example with keywords).

See also: -splice-list, -insert-at

(-splice 'even? (lambda (x) (list x x)) '(1 2 3 4)) ;; => '(1 2 2 3 4 4)
(--splice 't (list it it) '(1 2 3 4)) ;; => '(1 1 2 2 3 3 4 4)
(--splice (equal it :magic) '((list of) (magical) (code)) '((foo) (bar) :magic (baz))) ;; => '((foo) (bar) (list of) (magical) (code) (baz))

Splice new-list in place of elements matching pred in list.

See also: -splice, -insert-at

(-splice-list 'keywordp '(a b c) '(1 :foo 2)) ;; => '(1 a b c 2)
(-splice-list 'keywordp nil '(1 :foo 2)) ;; => '(1 2)

Return the concatenation of the result of mapping fn over list. Thus function fn should return a list.

(-mapcat 'list '(1 2 3)) ;; => '(1 2 3)
(-mapcat (lambda (item) (list 0 item)) '(1 2 3)) ;; => '(0 1 0 2 0 3)
(--mapcat (list 0 it) '(1 2 3)) ;; => '(0 1 0 2 0 3)

Create a shallow copy of list.

(-copy '(1 2 3)) ;; => '(1 2 3)
(let ((a '(1 2 3))) (eq a (-copy a))) ;; => nil

Functions returning a sublist of the original list.

Return a new list of the items in list for which pred returns a non-nil value.

Alias: -select

(-filter (lambda (num) (= 0 (% num 2))) '(1 2 3 4)) ;; => '(2 4)
(-filter 'even? '(1 2 3 4)) ;; => '(2 4)
(--filter (= 0 (% it 2)) '(1 2 3 4)) ;; => '(2 4)

Return a new list of the items in list for which pred returns nil.

Alias: -reject

(-remove (lambda (num) (= 0 (% num 2))) '(1 2 3 4)) ;; => '(1 3)
(-remove 'even? '(1 2 3 4)) ;; => '(1 3)
(--remove (= 0 (% it 2)) '(1 2 3 4)) ;; => '(1 3)

Return all non-nil elements of list.

(-non-nil '(1 nil 2 nil nil 3 4 nil 5 nil)) ;; => '(1 2 3 4 5)

Return copy of list, starting from index from to index to.

from or to may be negative. These values are then interpreted modulo the length of the list.

If step is a number, only each STEPth item in the resulting section is returned. Defaults to 1.

(-slice '(1 2 3 4 5) 1) ;; => '(2 3 4 5)
(-slice '(1 2 3 4 5) 0 3) ;; => '(1 2 3)
(-slice '(1 2 3 4 5 6 7 8 9) 1 -1 2) ;; => '(2 4 6 8)

Return a new list of the first n items in list, or all items if there are fewer than n.

(-take 3 '(1 2 3 4 5)) ;; => '(1 2 3)
(-take 17 '(1 2 3 4 5)) ;; => '(1 2 3 4 5)

Return the tail of list without the first n items.

(-drop 3 '(1 2 3 4 5)) ;; => '(4 5)
(-drop 17 '(1 2 3 4 5)) ;; => '()

Return a new list of successive items from list while (pred item) returns a non-nil value.

(-take-while 'even? '(1 2 3 4)) ;; => '()
(-take-while 'even? '(2 4 5 6)) ;; => '(2 4)
(--take-while (< it 4) '(1 2 3 4 3 2 1)) ;; => '(1 2 3)

Return the tail of list starting from the first item for which (pred item) returns nil.

(-drop-while 'even? '(1 2 3 4)) ;; => '(1 2 3 4)
(-drop-while 'even? '(2 4 5 6)) ;; => '(5 6)
(--drop-while (< it 4) '(1 2 3 4 3 2 1)) ;; => '(4 3 2 1)

Return a list whose elements are elements from list selected as (nth i list) for all i from indices.

(-select-by-indices '(4 10 2 3 6) '("v" "e" "l" "o" "c" "i" "r" "a" "p" "t" "o" "r")) ;; => '("c" "o" "l" "o" "r")
(-select-by-indices '(2 1 0) '("a" "b" "c")) ;; => '("c" "b" "a")
(-select-by-indices '(0 1 2 0 1 3 3 1) '("f" "a" "r" "l")) ;; => '("f" "a" "r" "f" "a" "l" "l" "a")

Bag of various functions which modify input list.

Return a new list of the non-nil results of applying fn to the items in list.

(-keep 'cdr '((1 2 3) (4 5) (6))) ;; => '((2 3) (5))
(-keep (lambda (num) (when (> num 3) (* 10 num))) '(1 2 3 4 5 6)) ;; => '(40 50 60)
(--keep (when (> it 3) (* 10 it)) '(1 2 3 4 5 6)) ;; => '(40 50 60)

Return a new list with the concatenation of the elements in the supplied lists.

(-concat '(1)) ;; => '(1)
(-concat '(1) '(2)) ;; => '(1 2)
(-concat '(1) '(2 3) '(4)) ;; => '(1 2 3 4)

Take a nested list l and return its contents as a single, flat list.

See also: -flatten-n

(-flatten '((1))) ;; => '(1)
(-flatten '((1 (2 3) (((4 (5))))))) ;; => '(1 2 3 4 5)
(-flatten '(1 2 (3 . 4))) ;; => '(1 2 (3 . 4))

Flatten num levels of a nested list.

See also: -flatten

(-flatten-n 1 '((1 2) ((3 4) ((5 6))))) ;; => '(1 2 (3 4) ((5 6)))
(-flatten-n 2 '((1 2) ((3 4) ((5 6))))) ;; => '(1 2 3 4 (5 6))
(-flatten-n 3 '((1 2) ((3 4) ((5 6))))) ;; => '(1 2 3 4 5 6)

Replace all old items in list with new.

Elements are compared using equal.

See also: -replace-at

(-replace 1 "1" '(1 2 3 4 3 2 1)) ;; => '("1" 2 3 4 3 2 "1")
(-replace "foo" "bar" '("a" "nice" "foo" "sentence" "about" "foo")) ;; => '("a" "nice" "bar" "sentence" "about" "bar")
(-replace 1 2 nil) ;; => nil

Return a list with x inserted into list at position n.

See also: -splice, -splice-list

(-insert-at 1 'x '(a b c)) ;; => '(a x b c)
(-insert-at 12 'x '(a b c)) ;; => '(a b c x)

Return a list with element at Nth position in list replaced with x.

See also: -replace

(-replace-at 0 9 '(0 1 2 3 4 5)) ;; => '(9 1 2 3 4 5)
(-replace-at 1 9 '(0 1 2 3 4 5)) ;; => '(0 9 2 3 4 5)
(-replace-at 4 9 '(0 1 2 3 4 5)) ;; => '(0 1 2 3 9 5)

Return a list with element at Nth position in list replaced with (func (nth n list)).

See also: -map-when

(-update-at 0 (lambda (x) (+ x 9)) '(0 1 2 3 4 5)) ;; => '(9 1 2 3 4 5)
(-update-at 1 (lambda (x) (+ x 8)) '(0 1 2 3 4 5)) ;; => '(0 9 2 3 4 5)
(--update-at 2 (length it) '("foo" "bar" "baz" "quux")) ;; => '("foo" "bar" 3 "quux")

Return a list with element at Nth position in list removed.

See also: -remove-at-indices, -remove

(-remove-at 0 '("0" "1" "2" "3" "4" "5")) ;; => '("1" "2" "3" "4" "5")
(-remove-at 1 '("0" "1" "2" "3" "4" "5")) ;; => '("0" "2" "3" "4" "5")
(-remove-at 2 '("0" "1" "2" "3" "4" "5")) ;; => '("0" "1" "3" "4" "5")

Return a list whose elements are elements from list without elements selected as (nth i list) for all i from indices.

See also: -remove-at, -remove

(-remove-at-indices '(0) '("0" "1" "2" "3" "4" "5")) ;; => '("1" "2" "3" "4" "5")
(-remove-at-indices '(0 2 4) '("0" "1" "2" "3" "4" "5")) ;; => '("1" "3" "5")
(-remove-at-indices '(0 5) '("0" "1" "2" "3" "4" "5")) ;; => '("1" "2" "3" "4")

Functions reducing lists into single value.

Return the result of applying fn to initial-value and the first item in list, then applying fn to that result and the 2nd item, etc. If list contains no items, return initial-value and fn is not called.

In the anaphoric form --reduce-from, the accumulated value is exposed as acc.

(-reduce-from '- 10 '(1 2 3)) ;; => 4
(-reduce-from (lambda (memo item) (concat "(" memo " - " (int-to-string item) ")")) "10" '(1 2 3)) ;; => "(((10 - 1) - 2) - 3)"
(--reduce-from (concat acc " " it) "START" '("a" "b" "c")) ;; => "START a b c"

Replace conses with fn, nil with initial-value and evaluate the resulting expression. If list is empty, initial-value is returned and fn is not called.

Note: this function works the same as -reduce-from but the operation associates from right instead of from left.

(-reduce-r-from '- 10 '(1 2 3)) ;; => -8
(-reduce-r-from (lambda (item memo) (concat "(" (int-to-string item) " - " memo ")")) "10" '(1 2 3)) ;; => "(1 - (2 - (3 - 10)))"
(--reduce-r-from (concat it " " acc) "END" '("a" "b" "c")) ;; => "a b c END"

Return the result of applying fn to the first 2 items in list, then applying fn to that result and the 3rd item, etc. If list contains no items, fn must accept no arguments as well, and reduce return the result of calling fn with no arguments. If list has only 1 item, it is returned and fn is not called.

In the anaphoric form --reduce, the accumulated value is exposed as acc.

(-reduce '- '(1 2 3 4)) ;; => -8
(-reduce (lambda (memo item) (format "%s-%s" memo item)) '(1 2 3)) ;; => "1-2-3"
(--reduce (format "%s-%s" acc it) '(1 2 3)) ;; => "1-2-3"

Replace conses with fn and evaluate the resulting expression. The final nil is ignored. If list contains no items, fn must accept no arguments as well, and reduce return the result of calling fn with no arguments. If list has only 1 item, it is returned and fn is not called.

The first argument of fn is the new item, the second is the accumulated value.

Note: this function works the same as -reduce but the operation associates from right instead of from left.

(-reduce-r '- '(1 2 3 4)) ;; => -2
(-reduce-r (lambda (item memo) (format "%s-%s" memo item)) '(1 2 3)) ;; => "3-2-1"
(--reduce-r (format "%s-%s" acc it) '(1 2 3)) ;; => "3-2-1"

Counts the number of items in list where (pred item) is non-nil.

(-count 'even? '(1 2 3 4 5)) ;; => 2
(--count (< it 4) '(1 2 3 4)) ;; => 3

Return the sum of list.

(-sum '()) ;; => 0
(-sum '(1)) ;; => 1
(-sum '(1 2 3 4)) ;; => 10

Return the product of list.

(-product '()) ;; => 1
(-product '(1)) ;; => 1
(-product '(1 2 3 4)) ;; => 24

Return the smallest value from list of numbers or markers.

(-min '(0)) ;; => 0
(-min '(3 2 1)) ;; => 1
(-min '(1 2 3)) ;; => 1

Take a comparison function comparator and a list and return the least element of the list by the comparison function.

See also combinator -on which can transform the values before comparing them.

(-min-by '> '(4 3 6 1)) ;; => 1
(--min-by (> (car it) (car other)) '((1 2 3) (2) (3 2))) ;; => '(1 2 3)
(--min-by (> (length it) (length other)) '((1 2 3) (2) (3 2))) ;; => '(2)

Return the largest value from list of numbers or markers.

(-max '(0)) ;; => 0
(-max '(3 2 1)) ;; => 3
(-max '(1 2 3)) ;; => 3

Take a comparison function comparator and a list and return the greatest element of the list by the comparison function.

See also combinator -on which can transform the values before comparing them.

(-max-by '> '(4 3 6 1)) ;; => 6
(--max-by (> (car it) (car other)) '((1 2 3) (2) (3 2))) ;; => '(3 2)
(--max-by (> (length it) (length other)) '((1 2 3) (2) (3 2))) ;; => '(1 2 3)

Operations dual to reductions, building lists from seed value rather than consuming a list to produce a single value.

Return a list of iterated applications of fun to init.

This means a list of form:

(init (fun init) (fun (fun init)) ...)

n is the length of the returned list.

(-iterate '1+ 1 10) ;; => '(1 2 3 4 5 6 7 8 9 10)
(-iterate (lambda (x) (+ x x)) 2 5) ;; => '(2 4 8 16 32)
(--iterate (* it it) 2 5) ;; => '(2 4 16 256 65536)

Build a list from seed using fun.

This is "dual" operation to -reduce-r: while -reduce-r consumes a list to produce a single value, -unfold takes a seed value and builds a (potentially infinite!) list.

fun should return nil to stop the generating process, or a cons (a . b), where a will be prepended to the result and b is the new seed.

(-unfold (lambda (x) (unless (= x 0) (cons x (1- x)))) 10) ;; => '(10 9 8 7 6 5 4 3 2 1)
(--unfold (when it (cons it (cdr it))) '(1 2 3 4)) ;; => '((1 2 3 4) (2 3 4) (3 4) (4))
(--unfold (when it (cons it (butlast it))) '(1 2 3 4)) ;; => '((1 2 3 4) (1 2 3) (1 2) (1))

Return t if (pred x) is non-nil for any x in list, else nil.

Alias: -any-p, -some?, -some-p

(-any? 'even? '(1 2 3)) ;; => t
(-any? 'even? '(1 3 5)) ;; => nil
(--any? (= 0 (% it 2)) '(1 2 3)) ;; => t

Return t if (pred x) is non-nil for all x in list, else nil.

Alias: -all-p, -every?, -every-p

(-all? 'even? '(1 2 3)) ;; => nil
(-all? 'even? '(2 4 6)) ;; => t
(--all? (= 0 (% it 2)) '(2 4 6)) ;; => t

Return t if (pred x) is nil for all x in list, else nil.

Alias: -none-p

(-none? 'even? '(1 2 3)) ;; => nil
(-none? 'even? '(1 3 5)) ;; => t
(--none? (= 0 (% it 2)) '(1 2 3)) ;; => nil

Return t if at least one item of list matches pred and at least one item of list does not match pred. Return nil both if all items match the predicate or if none of the items match the predicate.

Alias: -only-some-p

(-only-some? 'even? '(1 2 3)) ;; => t
(-only-some? 'even? '(1 3 5)) ;; => nil
(-only-some? 'even? '(2 4 6)) ;; => nil

Return non-nil if list contains element.

The test for equality is done with equal, or with -compare-fn if that's non-nil.

Alias: -contains-p

(-contains? '(1 2 3) 1) ;; => t
(-contains? '(1 2 3) 2) ;; => t
(-contains? '(1 2 3) 4) ;; => nil

Return true if list and list2 has the same items.

The order of the elements in the lists does not matter.

Alias: -same-items-p

(-same-items? '(1 2 3) '(1 2 3)) ;; => t
(-same-items? '(1 2 3) '(3 2 1)) ;; => t
(-same-items? '(1 2 3) '(1 2 3 4)) ;; => nil

Return non-nil if prefix is prefix of list.

Alias: -is-prefix-p

(-is-prefix? '(1 2 3) '(1 2 3 4 5)) ;; => t
(-is-prefix? '(1 2 3 4 5) '(1 2 3)) ;; => nil
(-is-prefix? '(1 3) '(1 2 3 4 5)) ;; => nil

Return non-nil if suffix is suffix of list.

Alias: -is-suffix-p

(-is-suffix? '(3 4 5) '(1 2 3 4 5)) ;; => t
(-is-suffix? '(1 2 3 4 5) '(3 4 5)) ;; => nil
(-is-suffix? '(3 5) '(1 2 3 4 5)) ;; => nil

Return non-nil if infix is infix of list.

This operation runs in o(n^2) time

Alias: -is-infix-p

(-is-infix? '(1 2 3) '(1 2 3 4 5)) ;; => t
(-is-infix? '(2 3 4) '(1 2 3 4 5)) ;; => t
(-is-infix? '(3 4 5) '(1 2 3 4 5)) ;; => t

Functions partitioning the input list into a list of lists.

Return a list of ((-take n list) (-drop n list)), in no more than one pass through the list.

(-split-at 3 '(1 2 3 4 5)) ;; => '((1 2 3) (4 5))
(-split-at 17 '(1 2 3 4 5)) ;; => '((1 2 3 4 5) nil)

Return a list of ((-take-while pred list) (-drop-while pred list)), in no more than one pass through the list.

(-split-with 'even? '(1 2 3 4)) ;; => '(nil (1 2 3 4))
(-split-with 'even? '(2 4 5 6)) ;; => '((2 4) (5 6))
(--split-with (< it 4) '(1 2 3 4 3 2 1)) ;; => '((1 2 3) (4 3 2 1))

Split the list each time item is found.

Unlike -partition-by, the item is discarded from the results. Empty lists are also removed from the result.

Comparison is done by equal.

See also -split-when

(-split-on '| '(Nil | Leaf a | Node [Tree a])) ;; => '((Nil) (Leaf a) (Node [Tree a]))
(-split-on ':endgroup '("a" "b" :endgroup "c" :endgroup "d" "e")) ;; => '(("a" "b") ("c") ("d" "e"))
(-split-on ':endgroup '("a" "b" :endgroup :endgroup "d" "e")) ;; => '(("a" "b") ("d" "e"))

Split the list on each element where fn returns non-nil.

Unlike -partition-by, the "matched" element is discarded from the results. Empty lists are also removed from the result.

This function can be thought of as a generalization of split-string.

(-split-when 'even? '(1 2 3 4 5 6)) ;; => '((1) (3) (5))
(-split-when 'even? '(1 2 3 4 6 8 9)) ;; => '((1) (3) (9))
(--split-when (memq it '(&optional &rest)) '(a b &optional c d &rest args)) ;; => '((a b) (c d) (args))

Return a list of ((-filter pred list) (-remove pred list)), in one pass through the list.

(-separate (lambda (num) (= 0 (% num 2))) '(1 2 3 4 5 6 7)) ;; => '((2 4 6) (1 3 5 7))
(--separate (< it 5) '(3 7 5 9 3 2 1 4 6)) ;; => '((3 3 2 1 4) (7 5 9 6))
(-separate 'cdr '((1 2) (1) (1 2 3) (4))) ;; => '(((1 2) (1 2 3)) ((1) (4)))

Return a new list with the items in list grouped into n-sized sublists. If there are not enough items to make the last group n-sized, those items are discarded.

(-partition 2 '(1 2 3 4 5 6)) ;; => '((1 2) (3 4) (5 6))
(-partition 2 '(1 2 3 4 5 6 7)) ;; => '((1 2) (3 4) (5 6))
(-partition 3 '(1 2 3 4 5 6 7)) ;; => '((1 2 3) (4 5 6))

Return a new list with the items in list grouped into n-sized sublists. The last group may contain less than n items.

(-partition-all 2 '(1 2 3 4 5 6)) ;; => '((1 2) (3 4) (5 6))
(-partition-all 2 '(1 2 3 4 5 6 7)) ;; => '((1 2) (3 4) (5 6) (7))
(-partition-all 3 '(1 2 3 4 5 6 7)) ;; => '((1 2 3) (4 5 6) (7))

Return a new list with the items in list grouped into n-sized sublists at offsets step apart. If there are not enough items to make the last group n-sized, those items are discarded.

(-partition-in-steps 2 1 '(1 2 3 4)) ;; => '((1 2) (2 3) (3 4))
(-partition-in-steps 3 2 '(1 2 3 4)) ;; => '((1 2 3))
(-partition-in-steps 3 2 '(1 2 3 4 5)) ;; => '((1 2 3) (3 4 5))

Return a new list with the items in list grouped into n-sized sublists at offsets step apart. The last groups may contain less than n items.

(-partition-all-in-steps 2 1 '(1 2 3 4)) ;; => '((1 2) (2 3) (3 4) (4))
(-partition-all-in-steps 3 2 '(1 2 3 4)) ;; => '((1 2 3) (3 4))
(-partition-all-in-steps 3 2 '(1 2 3 4 5)) ;; => '((1 2 3) (3 4 5) (5))

Apply fn to each item in list, splitting it each time fn returns a new value.

(-partition-by 'even? '()) ;; => '()
(-partition-by 'even? '(1 1 2 2 2 3 4 6 8)) ;; => '((1 1) (2 2 2) (3) (4 6 8))
(--partition-by (< it 3) '(1 2 3 4 3 2 1)) ;; => '((1 2) (3 4 3) (2 1))

Apply fn to the first item in list. That is the header value. Apply fn to each item in list, splitting it each time fn returns the header value, but only after seeing at least one other value (the body).

(--partition-by-header (= it 1) '(1 2 3 1 2 1 2 3 4)) ;; => '((1 2 3) (1 2) (1 2 3 4))
(--partition-by-header (> it 0) '(1 2 0 1 0 1 2 3 0)) ;; => '((1 2 0) (1 0) (1 2 3 0))
(-partition-by-header 'even? '(2 1 1 1 4 1 3 5 6 6 1)) ;; => '((2 1 1 1) (4 1 3 5) (6 6 1))

Separate list into an alist whose keys are fn applied to the elements of list. Keys are compared by equal.

(-group-by 'even? '()) ;; => '()
(-group-by 'even? '(1 1 2 2 2 3 4 6 8)) ;; => '((nil 1 1 3) (t 2 2 2 4 6 8))
(--group-by (car (split-string it "/")) '("a/b" "c/d" "a/e")) ;; => '(("a" "a/b" "a/e") ("c" "c/d"))

Return indices of elements based on predicates, sort elements by indices etc.

Return the index of the first element in the given list which is equal to the query element elem, or nil if there is no such element.

(-elem-index 2 '(6 7 8 2 3 4)) ;; => 3
(-elem-index "bar" '("foo" "bar" "baz")) ;; => 1
(-elem-index '(1 2) '((3) (5 6) (1 2) nil)) ;; => 2

Return the indices of all elements in list equal to the query element elem, in ascending order.

(-elem-indices 2 '(6 7 8 2 3 4 2 1)) ;; => '(3 6)
(-elem-indices "bar" '("foo" "bar" "baz")) ;; => '(1)
(-elem-indices '(1 2) '((3) (1 2) (5 6) (1 2) nil)) ;; => '(1 3)

Take a predicate pred and a list and return the index of the first element in the list satisfying the predicate, or nil if there is no such element.

(-find-index 'even? '(2 4 1 6 3 3 5 8)) ;; => 0
(--find-index (< 5 it) '(2 4 1 6 3 3 5 8)) ;; => 3
(-find-index (-partial 'string-lessp "baz") '("bar" "foo" "baz")) ;; => 1

Take a predicate pred and a list and return the index of the last element in the list satisfying the predicate, or nil if there is no such element.

(-find-last-index 'even? '(2 4 1 6 3 3 5 8)) ;; => 7
(--find-last-index (< 5 it) '(2 7 1 6 3 8 5 2)) ;; => 5
(-find-last-index (-partial 'string-lessp "baz") '("q" "foo" "baz")) ;; => 1

Return the indices of all elements in list satisfying the predicate pred, in ascending order.

(-find-indices 'even? '(2 4 1 6 3 3 5 8)) ;; => '(0 1 3 7)
(--find-indices (< 5 it) '(2 4 1 6 3 3 5 8)) ;; => '(3 7)
(-find-indices (-partial 'string-lessp "baz") '("bar" "foo" "baz")) ;; => '(1)

Grade elements of list using comparator relation, yielding a permutation vector such that applying this permutation to list sorts it in ascending order.

(-grade-up '< '(3 1 4 2 1 3 3)) ;; => '(1 4 3 0 5 6 2)
(let ((l '(3 1 4 2 1 3 3))) (-select-by-indices (-grade-up '< l) l)) ;; => '(1 1 2 3 3 3 4)

Grade elements of list using comparator relation, yielding a permutation vector such that applying this permutation to list sorts it in descending order.

(-grade-down '< '(3 1 4 2 1 3 3)) ;; => '(2 0 5 6 3 1 4)
(let ((l '(3 1 4 2 1 3 3))) (-select-by-indices (-grade-down '< l) l)) ;; => '(4 3 3 3 2 1 1)

Operations pretending lists are sets.

Return a new list containing the elements of list1 and elements of list2 that are not in list1. The test for equality is done with equal, or with -compare-fn if that's non-nil.

(-union '(1 2 3) '(3 4 5)) ;; => '(1 2 3 4 5)
(-union '(1 2 3 4) '()) ;; => '(1 2 3 4)
(-union '(1 1 2 2) '(3 2 1)) ;; => '(1 1 2 2 3)

Return a new list with only the members of list that are not in list2. The test for equality is done with equal, or with -compare-fn if that's non-nil.

(-difference '() '()) ;; => '()
(-difference '(1 2 3) '(4 5 6)) ;; => '(1 2 3)
(-difference '(1 2 3 4) '(3 4 5 6)) ;; => '(1 2)

Return a new list containing only the elements that are members of both list and list2. The test for equality is done with equal, or with -compare-fn if that's non-nil.

(-intersection '() '()) ;; => '()
(-intersection '(1 2 3) '(4 5 6)) ;; => '()
(-intersection '(1 2 3 4) '(3 4 5 6)) ;; => '(3 4)

Return a new list with all duplicates removed. The test for equality is done with equal, or with -compare-fn if that's non-nil.

Alias: -uniq

(-distinct '()) ;; => '()
(-distinct '(1 2 2 4)) ;; => '(1 2 4)

Other list functions not fit to be classified elsewhere.

Rotate list n places to the right. With n negative, rotate to the left. The time complexity is o(n).

(-rotate 3 '(1 2 3 4 5 6 7)) ;; => '(5 6 7 1 2 3 4)
(-rotate -3 '(1 2 3 4 5 6 7)) ;; => '(4 5 6 7 1 2 3)

Return a list with x repeated n times. Return nil if n is less than 1.

(-repeat 3 :a) ;; => '(:a :a :a)
(-repeat 1 :a) ;; => '(:a)
(-repeat 0 :a) ;; => nil

Make a new list from the elements of args.

The last 2 members of args are used as the final cons of the result so if the final member of args is not a list the result is a dotted list.

(-cons* 1 2) ;; => '(1 . 2)
(-cons* 1 2 3) ;; => '(1 2 . 3)
(-cons* 1) ;; => 1

Append elem to the end of the list.

This is like cons, but operates on the end of list.

If elements is non nil, append these to the list as well.

(-snoc '(1 2 3) 4) ;; => '(1 2 3 4)
(-snoc '(1 2 3) 4 5 6) ;; => '(1 2 3 4 5 6)
(-snoc '(1 2 3) '(4 5 6)) ;; => '(1 2 3 (4 5 6))

Return a new list of all elements in list separated by sep.

(-interpose "-" '()) ;; => '()
(-interpose "-" '("a")) ;; => '("a")
(-interpose "-" '("a" "b" "c")) ;; => '("a" "-" "b" "-" "c")

Return a new list of the first item in each list, then the second etc.

(-interleave '(1 2) '("a" "b")) ;; => '(1 "a" 2 "b")
(-interleave '(1 2) '("a" "b") '("A" "B")) ;; => '(1 "a" "A" 2 "b" "B")
(-interleave '(1 2 3) '("a" "b")) ;; => '(1 "a" 2 "b")

Zip the two lists list1 and list2 using a function fn. This function is applied pairwise taking as first argument element of list1 and as second argument element of list2 at corresponding position.

The anaphoric form --zip-with binds the elements from list1 as it, and the elements from list2 as other.

(-zip-with '+ '(1 2 3) '(4 5 6)) ;; => '(5 7 9)
(-zip-with 'cons '(1 2 3) '(4 5 6)) ;; => '((1 . 4) (2 . 5) (3 . 6))
(--zip-with (concat it " and " other) '("Batman" "Jekyll") '("Robin" "Hyde")) ;; => '("Batman and Robin" "Jekyll and Hyde")

Zip lists together. Group the head of each list, followed by the second elements of each list, and so on. The lengths of the returned groupings are equal to the length of the shortest input list.

If two lists are provided as arguments, return the groupings as a list of cons cells. Otherwise, return the groupings as a list of lists.

(-zip '(1 2 3) '(4 5 6)) ;; => '((1 . 4) (2 . 5) (3 . 6))
(-zip '(1 2 3) '(4 5 6 7)) ;; => '((1 . 4) (2 . 5) (3 . 6))
(-zip '(1 2 3 4) '(4 5 6)) ;; => '((1 . 4) (2 . 5) (3 . 6))

Zip lists, with fill-value padded onto the shorter lists. The lengths of the returned groupings are equal to the length of the longest input list.

(-zip-fill 0 '(1 2 3 4 5) '(6 7 8 9)) ;; => '((1 . 6) (2 . 7) (3 . 8) (4 . 9) (5 . 0))

Return an infinite copy of list that will cycle through the elements and repeat from the beginning.

(-take 5 (-cycle '(1 2 3))) ;; => '(1 2 3 1 2)
(-take 7 (-cycle '(1 "and" 3))) ;; => '(1 "and" 3 1 "and" 3 1)
(-zip (-cycle '(1 2 3)) '(1 2)) ;; => '((1 . 1) (2 . 2))

Appends fill-value to the end of each list in lists such that they will all have the same length.

(-pad 0 '()) ;; => '(nil)
(-pad 0 '(1)) ;; => '((1))
(-pad 0 '(1 2 3) '(4 5)) ;; => '((1 2 3) (4 5 0))

Compute outer product of lists using function fn.

The function fn should have the same arity as the number of supplied lists.

The outer product is computed by applying fn to all possible combinations created by taking one element from each list in order. The dimension of the result is (length lists).

See also: -table-flat

(-table '* '(1 2 3) '(1 2 3)) ;; => '((1 2 3) (2 4 6) (3 6 9))
(-table (lambda (a b) (-sum (-zip-with '* a b))) '((1 2) (3 4)) '((1 3) (2 4))) ;; => '((7 15) (10 22))
(apply '-table 'list (-repeat 3 '(1 2))) ;; => '((((1 1 1) (2 1 1)) ((1 2 1) (2 2 1))) (((1 1 2) (2 1 2)) ((1 2 2) (2 2 2))))

Compute flat outer product of lists using function fn.

The function fn should have the same arity as the number of supplied lists.

The outer product is computed by applying fn to all possible combinations created by taking one element from each list in order. The results are flattened, ignoring the tensor structure of the result. This is equivalent to calling:

(-flatten-n (1- (length lists)) (-table fn lists))

but the implementation here is much more efficient.

See also: -flatten-n, -table

(-table-flat 'list '(1 2 3) '(a b c)) ;; => '((1 a) (2 a) (3 a) (1 b) (2 b) (3 b) (1 c) (2 c) (3 c))
(-table-flat '* '(1 2 3) '(1 2 3)) ;; => '(1 2 3 2 4 6 3 6 9)
(apply '-table-flat 'list (-repeat 3 '(1 2))) ;; => '((1 1 1) (2 1 1) (1 2 1) (2 2 1) (1 1 2) (2 1 2) (1 2 2) (2 2 2))

Return the first x in list where (pred x) is non-nil, else nil.

To get the first item in the list no questions asked, use car.

Alias: -find

(-first 'even? '(1 2 3)) ;; => 2
(-first 'even? '(1 3 5)) ;; => nil
(--first (> it 2) '(1 2 3)) ;; => 3

Return (pred x) for the first list item where (pred x) is non-nil, else nil.

Alias: -any

(-some 'even? '(1 2 3)) ;; => t
(--some (member 'foo it) '((foo bar) (baz))) ;; => '(foo bar)
(--some (plist-get it :bar) '((:foo 1 :bar 2) (:baz 3))) ;; => 2

Return the last x in list where (pred x) is non-nil, else nil.

(-last 'even? '(1 2 3 4 5 6 3 3 3)) ;; => 6
(-last 'even? '(1 3 7 5 9)) ;; => nil
(--last (> (length it) 3) '("a" "looong" "word" "and" "short" "one")) ;; => "short"

Return the first item of list, or nil on an empty list.

(-first-item '(1 2 3)) ;; => 1
(-first-item nil) ;; => nil

Return the last item of list, or nil on an empty list.

(-last-item '(1 2 3)) ;; => 3
(-last-item nil) ;; => nil

Return a list of all items in list except for the last.

(-butlast '(1 2 3)) ;; => '(1 2)
(-butlast '(1 2)) ;; => '(1)
(-butlast '(1)) ;; => nil

Sort list, stably, comparing elements using comparator. Return the sorted list. list is not modified by side effects. comparator is called with two elements of list, and should return non-nil if the first element should sort before the second.

(-sort '< '(3 1 2)) ;; => '(1 2 3)
(-sort '> '(3 1 2)) ;; => '(3 2 1)
(--sort (< it other) '(3 1 2)) ;; => '(1 2 3)

Return a list with args.

If first item of args is already a list, simply return args. If not, return a list with args as elements.

(-list 1) ;; => '(1)
(-list 1 2 3) ;; => '(1 2 3)
(-list '(1 2 3)) ;; => '(1 2 3)

Compute the (least) fixpoint of fn with initial input list.

fn is called at least once, results are compared with equal.

(-fix (lambda (l) (-non-nil (--mapcat (-split-at (/ (length it) 2) it) l))) '((1 2 3 4 5 6))) ;; => '((1) (2) (3) (4) (5) (6))
(let ((data '(("starwars" "scifi") ("jedi" "starwars" "warrior")))) (--fix (-uniq (--mapcat (cons it (cdr (assoc it data))) it)) '("jedi" "book"))) ;; => '("jedi" "starwars" "warrior" "scifi" "book")

Functions pretending lists are trees.

Return a sequence of the nodes in tree, in depth-first search order.

branch is a predicate of one argument that returns non-nil if the passed argument is a branch, that is, a node that can have children.

children is a function of one argument that returns the children of the passed branch node.

Non-branch nodes are simply copied.

(-tree-seq 'listp 'identity '(1 (2 3) 4 (5 (6 7)))) ;; => '((1 (2 3) 4 (5 (6 7))) 1 (2 3) 2 3 4 (5 (6 7)) 5 (6 7) 6 7)
(-tree-seq 'listp 'reverse '(1 (2 3) 4 (5 (6 7)))) ;; => '((1 (2 3) 4 (5 (6 7))) (5 (6 7)) (6 7) 7 6 5 4 (2 3) 3 2 1)
(--tree-seq (vectorp it) (append it nil) [1 [2 3] 4 [5 [6 7]]]) ;; => '([1 [2 3] 4 [5 [6 7]]] 1 [2 3] 2 3 4 [5 [6 7]] 5 [6 7] 6 7)

Apply fn to each element of tree while preserving the tree structure.

(-tree-map '1+ '(1 (2 3) (4 (5 6) 7))) ;; => '(2 (3 4) (5 (6 7) 8))
(-tree-map '(lambda (x) (cons x (expt 2 x))) '(1 (2 3) 4)) ;; => '((1 . 2) ((2 . 4) (3 . 8)) (4 . 16))
(--tree-map (length it) '("<body>" ("<p>" "text" "</p>") "</body>")) ;; => '(6 (3 4 4) 7)

Call fun on each node of tree that satisfies pred.

If pred returns nil, continue descending down this node. If pred returns non-nil, apply fun to this node and do not descend further.

(-tree-map-nodes 'vectorp (lambda (x) (-sum (append x nil))) '(1 [2 3] 4 (5 [6 7] 8))) ;; => '(1 5 4 (5 13 8))
(-tree-map-nodes 'keywordp (lambda (x) (symbol-name x)) '(1 :foo 4 ((5 6 :bar) :baz 8))) ;; => '(1 ":foo" 4 ((5 6 ":bar") ":baz" 8))
(--tree-map-nodes (eq (car-safe it) 'add-mode) (-concat it (list :mode 'emacs-lisp-mode)) '(with-mode emacs-lisp-mode (foo bar) (add-mode a b) (baz (add-mode c d)))) ;; => '(with-mode emacs-lisp-mode (foo bar) (add-mode a b :mode emacs-lisp-mode) (baz (add-mode c d :mode emacs-lisp-mode)))

Use fn to reduce elements of list tree. If elements of tree are lists themselves, apply the reduction recursively.

fn is first applied to first element of the list and second element, then on this result and third element from the list etc.

See -reduce-r for how exactly are lists of zero or one element handled.

(-tree-reduce '+ '(1 (2 3) (4 5))) ;; => 15
(-tree-reduce 'concat '("strings" (" on" " various") ((" levels")))) ;; => "strings on various levels"
(--tree-reduce (cond ((stringp it) (concat it " " acc)) (t (let ((sn (symbol-name it))) (concat "<" sn ">" acc "</" sn ">")))) '(body (p "some words") (div "more" (b "bold") "words"))) ;; => "<body><p>some words</p> <div>more <b>bold</b> words</div></body>"

Use fn to reduce elements of list tree. If elements of tree are lists themselves, apply the reduction recursively.

fn is first applied to init-value and first element of the list, then on this result and second element from the list etc.

The initial value is ignored on cons pairs as they always contain two elements.

(-tree-reduce-from '+ 1 '(1 (1 1) ((1)))) ;; => 8
(--tree-reduce-from (-concat acc (list it)) nil '(1 (2 3 (4 5)) (6 7))) ;; => '((7 6) ((5 4) 3 2) 1)

Apply fn to each element of tree, and make a list of the results. If elements of tree are lists themselves, apply fn recursively to elements of these nested lists.

Then reduce the resulting lists using folder and initial value init-value. See -reduce-r-from.

This is the same as calling -tree-reduce after -tree-map but is twice as fast as it only traverse the structure once.

(-tree-mapreduce 'list 'append '(1 (2 (3 4) (5 6)) (7 (8 9)))) ;; => '(1 2 3 4 5 6 7 8 9)
(--tree-mapreduce 1 (+ it acc) '(1 (2 (4 9) (2 1)) (7 (4 3)))) ;; => 9
(--tree-mapreduce 0 (max acc (1+ it)) '(1 (2 (4 9) (2 1)) (7 (4 3)))) ;; => 3

Apply fn to each element of tree, and make a list of the results. If elements of tree are lists themselves, apply fn recursively to elements of these nested lists.

Then reduce the resulting lists using folder and initial value init-value. See -reduce-r-from.

This is the same as calling -tree-reduce-from after -tree-map but is twice as fast as it only traverse the structure once.

(-tree-mapreduce-from 'identity '* 1 '(1 (2 (3 4) (5 6)) (7 (8 9)))) ;; => 362880
(--tree-mapreduce-from (+ it it) (cons it acc) nil '(1 (2 (4 9) (2 1)) (7 (4 3)))) ;; => '(2 (4 (8 18) (4 2)) (14 (8 6)))
(concat "{" (--tree-mapreduce-from (cond ((-cons-pair? it) (concat (symbol-name (car it)) " -> " (symbol-name (cdr it)))) (t (concat (symbol-name it) " : {"))) (concat it (unless (or (equal acc "}") (equal (substring it (1- (length it))) "{")) ", ") acc) "}" '((elips-mode (foo (bar . booze)) (baz . qux)) (c-mode (foo . bla) (bum . bam))))) ;; => "{elips-mode : {foo : {bar -> booze}, baz -> qux}, c-mode : {foo -> bla, bum -> bam}}"

Create a deep copy of list. The new list has the same elements and structure but all cons are replaced with new ones. This is useful when you need to clone a structure such as plist or alist.

(let* ((a '(1 2 3)) (b (-clone a))) (nreverse a) b) ;; => '(1 2 3)

Thread the expr through the forms. Insert x as the second item in the first form, making a list of it if it is not a list already. If there are more forms, insert the first form as the second item in second form, etc.

(-> '(2 3 5)) ;; => '(2 3 5)
(-> '(2 3 5) (append '(8 13))) ;; => '(2 3 5 8 13)
(-> '(2 3 5) (append '(8 13)) (-slice 1 -1)) ;; => '(3 5 8)

Thread the expr through the forms. Insert x as the last item in the first form, making a list of it if it is not a list already. If there are more forms, insert the first form as the last item in second form, etc.

(->> '(1 2 3) (-map 'square)) ;; => '(1 4 9)
(->> '(1 2 3) (-map 'square) (-remove 'even?)) ;; => '(1 9)
(->> '(1 2 3) (-map 'square) (-reduce '+)) ;; => 14

Thread the expr through the forms. Insert x at the position signified by the token it in the first form. If there are more forms, insert the first form at the position signified by it in in second form, etc.

(--> "def" (concat "abc" it "ghi")) ;; => "abcdefghi"
(--> "def" (concat "abc" it "ghi") (upcase it)) ;; => "ABCDEFGHI"
(--> "def" (concat "abc" it "ghi") upcase) ;; => "ABCDEFGHI"

Convenient versions of let and let* constructs combined with flow control.

If val evaluates to non-nil, bind it to var and execute body. var-val should be a (var val) pair.

Note: binding is done according to -let.

(-when-let (match-index (string-match "d" "abcd")) (+ match-index 2)) ;; => 5
(-when-let ((&plist :foo foo) (list :foo "foo")) foo) ;; => "foo"
(-when-let ((&plist :foo foo) (list :bar "bar")) foo) ;; => nil

If all vals evaluate to true, bind them to their corresponding vars and execute body. vars-vals should be a list of (var val) pairs.

Note: binding is done according to -let*.

(-when-let* ((x 5) (y 3) (z (+ y 4))) (+ x y z)) ;; => 15
(-when-let* ((x 5) (y nil) (z 7)) (+ x y z)) ;; => nil

If val evaluates to non-nil, bind it to var and do then, otherwise do else. var-val should be a (var val) pair.

Note: binding is done according to -let.

(-if-let (match-index (string-match "d" "abc")) (+ match-index 3) 7) ;; => 7
(--if-let (even? 4) it nil) ;; => t

If all vals evaluate to true, bind them to their corresponding vars and do then, otherwise do else. vars-vals should be a list of (var val) pairs.

Note: binding is done according to -let*.

(-if-let* ((x 5) (y 3) (z 7)) (+ x y z) "foo") ;; => 15
(-if-let* ((x 5) (y nil) (z 7)) (+ x y z) "foo") ;; => "foo"
(-if-let* (((_ _ x) '(nil nil 7))) x) ;; => 7

Bind variables according to varlist then eval body.

varlist is a list of lists of the form (pattern source). Each pattern is matched against the source "structurally". source is only evaluated once for each pattern. Each pattern is matched recursively, and can therefore contain sub-patterns which are matched against corresponding sub-expressions of source.

All the SOURCEs are evalled before any symbols are bound (i.e. "in parallel").

If varlist only contains one (pattern source) element, you can optionally specify it using a vector and discarding the outer-most parens. Thus

(-let ((`pattern` `source`)) ..)

becomes

(-let [`pattern` `source`] ..).

-let uses a convention of not binding places (symbols) starting with _ whenever it's possible. You can use this to skip over entries you don't care about. However, this is not always possible (as a result of implementation) and these symbols might get bound to undefined values.

Following is the overview of supported patterns. Remember that patterns can be matched recursively, so every a, b, aK in the following can be a matching construct and not necessarily a symbol/variable.

Symbol:

a - bind the `source` to `a`.  This is just like regular `let`.

Conses and lists:

(a) - bind `car` of cons/list to `a`

(a . b) - bind car of cons to `a` and `cdr` to `b`

(a b) - bind car of list to `a` and `cadr` to `b`

(a1 a2 a3  ...) - bind 0th car of list to `a1`, 1st to `a2`, 2nd to `a3` ...

(a1 a2 a3 ... aN . rest) - as above, but bind the Nth cdr to `rest`.

Vectors:

[a] - bind 0th element of a non-list sequence to `a` (works with
      vectors, strings, bit arrays...)

[a1 a2 a3 ...] - bind 0th element of non-list sequence to `a0`, 1st to
                 `a1`, 2nd to `a2`, ...
                 If the `pattern` is shorter than `source`, the values at
                 places not in `pattern` are ignored.
                 If the `pattern` is longer than `source`, an `error` is
                 thrown.

[a1 a2 a3 ... &rest rest] ) - as above, but bind the rest of
                              the sequence to `rest`.  This is
                              conceptually the same as improper list
                              matching (a1 a2 ... aN . rest)

Key/value stores:

(&plist key0 a0 ... keyN aN) - bind value mapped by keyK in the
                               `source` plist to aK.  If the
                               value is not found, aK is nil.

(&alist key0 a0 ... keyN aN) - bind value mapped by keyK in the
                               `source` alist to aK.  If the
                               value is not found, aK is nil.

(&hash key0 a0 ... keyN aN) - bind value mapped by keyK in the
                              `source` hash table to aK.  If the
                              value is not found, aK is nil.

Further, special keyword &keys supports "inline" matching of plist-like key-value pairs, similarly to &keys keyword of cl-defun.

(a1 a2 ... aN &keys key1 b1 ... keyN bK)

This binds n values from the list to a1 ... aN, then interprets the cdr as a plist (see key/value matching above).

(-let (([a (b c) d] [1 (2 3) 4])) (list a b c d)) ;; => '(1 2 3 4)
(-let [(a b c . d) (list 1 2 3 4 5 6)] (list a b c d)) ;; => '(1 2 3 (4 5 6))
(-let [(&plist :foo foo :bar bar) (list :baz 3 :foo 1 :qux 4 :bar 2)] (list foo bar)) ;; => '(1 2)

Bind variables according to varlist then eval body.

varlist is a list of lists of the form (pattern source). Each pattern is matched against the source structurally. source is only evaluated once for each pattern.

Each source can refer to the symbols already bound by this varlist. This is useful if you want to destructure source recursively but also want to name the intermediate structures.

See -let for the list of all possible patterns.

(-let* (((a . b) (cons 1 2)) ((c . d) (cons 3 4))) (list a b c d)) ;; => '(1 2 3 4)
(-let* (((a . b) (cons 1 (cons 2 3))) ((c . d) b)) (list a b c d)) ;; => '(1 (2 . 3) 2 3)
(-let* (((&alist "foo" foo "bar" bar) (list (cons "foo" 1) (cons "bar" (list 'a 'b 'c)))) ((a b c) bar)) (list foo a b c bar)) ;; => '(1 a b c (a b c))

Return a lambda which destructures its input as match-form and executes body.

Note that you have to enclose the match-form in a pair of parens, such that:

(-lambda (x) body)
(-lambda (x y ...) body)

has the usual semantics of lambda. Furthermore, these get translated into normal lambda, so there is no performance penalty.

See -let for the description of destructuring mechanism.

(-map (-lambda ((x y)) (+ x y)) '((1 2) (3 4) (5 6))) ;; => '(3 7 11)
(-map (-lambda ([x y]) (+ x y)) '([1 2] [3 4] [5 6])) ;; => '(3 7 11)
(funcall (-lambda ((_ . a) (_ . b)) (-concat a b)) '(1 2 3) '(4 5 6)) ;; => '(2 3 5 6)

Functions iterating over lists for side-effect only.

Call fn with every item in list. Return nil, used for side-effects only.

(let (s) (-each '(1 2 3) (lambda (item) (setq s (cons item s))))) ;; => nil
(let (s) (-each '(1 2 3) (lambda (item) (setq s (cons item s)))) s) ;; => '(3 2 1)
(let (s) (--each '(1 2 3) (setq s (cons it s))) s) ;; => '(3 2 1)

Call fn with every item in list while (pred item) is non-nil. Return nil, used for side-effects only.

(let (s) (-each-while '(2 4 5 6) 'even? (lambda (item) (!cons item s))) s) ;; => '(4 2)
(let (s) (--each-while '(1 2 3 4) (< it 3) (!cons it s)) s) ;; => '(2 1)

Repeatedly calls fn (presumably for side-effects) passing in integers from 0 through num-1.

(let (s) (-dotimes 3 (lambda (n) (!cons n s))) s) ;; => '(2 1 0)
(let (s) (--dotimes 5 (!cons it s)) s) ;; => '(4 3 2 1 0)

Destructive: Set cdr to the cons of car and cdr.

(let (l) (!cons 5 l) l) ;; => '(5)
(let ((l '(3))) (!cons 5 l) l) ;; => '(5 3)

Destructive: Set list to the cdr of list.

(let ((l '(3))) (!cdr l) l) ;; => '()
(let ((l '(3 5))) (!cdr l) l) ;; => '(5)

These combinators require Emacs 24 for its lexical scope. So they are offered in a separate package: dash-functional.

Takes a function fn and fewer than the normal arguments to fn, and returns a fn that takes a variable number of additional args. When called, the returned function calls fn with args first and then additional args.

(funcall (-partial '- 5) 3) ;; => 2
(funcall (-partial '+ 5 2) 3) ;; => 10

Takes a function fn and fewer than the normal arguments to fn, and returns a fn that takes a variable number of additional args. When called, the returned function calls fn with the additional args first and then args.

(funcall (-rpartial '- 5) 8) ;; => 3
(funcall (-rpartial '- 5 2) 10) ;; => 3

Takes a list of functions and returns a fn that is the juxtaposition of those fns. The returned fn takes a variable number of args, and returns a list containing the result of applying each fn to the args (left-to-right).

(funcall (-juxt '+ '-) 3 5) ;; => '(8 -2)
(-map (-juxt 'identity 'square) '(1 2 3)) ;; => '((1 1) (2 4) (3 9))

Takes a list of functions and returns a fn that is the composition of those fns. The returned fn takes a variable number of arguments, and returns the result of applying each fn to the result of applying the previous fn to the arguments (right-to-left).

(funcall (-compose 'square '+) 2 3) ;; => (square (+ 2 3))
(funcall (-compose 'identity 'square) 3) ;; => (square 3)
(funcall (-compose 'square 'identity) 3) ;; => (square 3)

Changes an n-arity function fn to a 1-arity function that expects a list with n items as arguments

(-map (-applify '+) '((1 1 1) (1 2 3) (5 5 5))) ;; => '(3 6 15)
(-map (-applify (lambda (a b c) (\` ((\, a) ((\, b) ((\, c))))))) '((1 1 1) (1 2 3) (5 5 5))) ;; => '((1 (1 (1))) (1 (2 (3))) (5 (5 (5))))
(funcall (-applify '<) '(3 6)) ;; => t

Return a function of two arguments that first applies transformer to each of them and then applies operator on the results (in the same order).

In types: (b -> b -> c) -> (a -> b) -> a -> a -> c

(-sort (-on '< 'length) '((1 2 3) (1) (1 2))) ;; => '((1) (1 2) (1 2 3))
(-min-by (-on '> 'length) '((1 2 3) (4) (1 2))) ;; => '(4)
(-min-by (-on 'string-lessp 'int-to-string) '(2 100 22)) ;; => 22

Swap the order of arguments for binary function func.

In types: (a -> b -> c) -> b -> a -> c

(funcall (-flip '<) 2 1) ;; => t
(funcall (-flip '-) 3 8) ;; => 5
(-sort (-flip '<) '(4 3 6 1)) ;; => '(6 4 3 1)

Return a function that returns c ignoring any additional arguments.

In types: a -> b -> a

(funcall (-const 2) 1 3 "foo") ;; => 2
(-map (-const 1) '("a" "b" "c" "d")) ;; => '(1 1 1 1)
(-sum (-map (-const 1) '("a" "b" "c" "d"))) ;; => 4

Take n-ary function and n arguments and specialize some of them. Arguments denoted by <> will be left unspecialized.

See srfi-26 for detailed description.

(funcall (-cut list 1 <> 3 <> 5) 2 4) ;; => '(1 2 3 4 5)
(-map (-cut funcall <> 5) '(1+ 1- (lambda (x) (/ 1.0 x)))) ;; => '(6 4 0.2)
(-filter (-cut < <> 5) '(1 3 5 7 9)) ;; => '(1 3)

Take an unary predicates pred and return an unary predicate that returns t if pred returns nil and nil if pred returns non-nil.

(funcall (-not 'even?) 5) ;; => t
(-filter (-not (-partial '< 4)) '(1 2 3 4 5 6 7 8)) ;; => '(1 2 3 4)

Take list of unary predicates preds and return an unary predicate with argument x that returns non-nil if at least one of the preds returns non-nil on x.

In types: [a -> Bool] -> a -> Bool

(-filter (-orfn 'even? (-partial (-flip '<) 5)) '(1 2 3 4 5 6 7 8 9 10)) ;; => '(1 2 3 4 6 8 10)
(funcall (-orfn 'stringp 'even?) "foo") ;; => t

Take list of unary predicates preds and return an unary predicate with argument x that returns non-nil if all of the preds returns non-nil on x.

In types: [a -> Bool] -> a -> Bool

(funcall (-andfn (-cut < <> 10) 'even?) 6) ;; => t
(funcall (-andfn (-cut < <> 10) 'even?) 12) ;; => nil
(-filter (-andfn (-not 'even?) (-cut >= 5 <>)) '(1 2 3 4 5 6 7 8 9 10)) ;; => '(1 3 5)

Return a function fn composed n times with itself.

fn is a unary function. If you need to use a function of higher arity, use -applify first to turn it into an unary function.

With n = 0, this acts as identity function.

In types: (a -> a) -> Int -> a -> a.

This function satisfies the following law:

(funcall (-iteratefn fn n) init) = (-last-item (-iterate fn init (1+ n))).

(funcall (-iteratefn (lambda (x) (* x x)) 3) 2) ;; => 256
(funcall (-iteratefn '1+ 3) 1) ;; => 4
(funcall (-iteratefn 'cdr 3) '(1 2 3 4 5)) ;; => '(4 5)

Return a function that computes the (least) fixpoint of fn.

fn must be a unary function. The returned lambda takes a single argument, x, the initial value for the fixpoint iteration. The iteration halts when either of the following conditions is satisified:

1. Iteration converges to the fixpoint, with equality being tested using equal-test. If equal-test is not specified, equal is used. For functions over the floating point numbers, it may be necessary to provide an appropriate appoximate comparsion test.

2. halt-test returns a non-nil value. halt-test defaults to a simple counter that returns t after -fixfn-max-iterations, to guard against infinite iteration. Otherwise, halt-test must be a function that accepts a single argument, the current value of x, and returns non-nil as long as iteration should continue. In this way, a more sophisticated convergence test may be supplied by the caller.

The return value of the lambda is either the fixpoint or, if iteration halted before converging, a cons with car halted and cdr the final output from halt-test.

In types: (a -> a) -> a -> a.

(funcall (-fixfn 'cos 'approx-equal) 0.7) ;; ~> 0.7390851332151607
(funcall (-fixfn (lambda (x) (expt (+ x 10) 0.25))) 2.0) ;; => 1.8555845286409378
(funcall (-fixfn 'sin 'approx-equal) 0.1) ;; => '(halted . t)

Take a list of n functions and return a function that takes a list of length n, applying i-th function to i-th element of the input list. Returns a list of length n.

In types (for n=2): ((a -> b), (c -> d)) -> (a, c) -> (b, d)

This function satisfies the following laws:

(-compose (-prodfn f g ...) (-prodfn f' g' ...)) = (-prodfn (-compose f f') (-compose g g') ...)
(-prodfn f g ...) = (-juxt (-compose f (-partial 'nth 0)) (-compose g (-partial 'nth 1)) ...)
(-compose (-prodfn f g ...) (-juxt f' g' ...)) = (-juxt (-compose f f') (-compose g g') ...)
(-compose (-partial 'nth n) (-prod f1 f2 ...)) = (-compose fn (-partial 'nth n))

(funcall (-prodfn '1+ '1- 'int-to-string) '(1 2 3)) ;; => '(2 1 "3")
(-map (-prodfn '1+ '1-) '((1 2) (3 4) (5 6) (7 8))) ;; => '((2 1) (4 3) (6 5) (8 7))
(apply '+ (funcall (-prodfn 'length 'string-to-int) '((1 2 3) "15"))) ;; => 18

Yes, please do. Pure functions in the list manipulation realm only, please. There's a suite of tests in dev/examples.el, so remember to add tests for your function, or I might break it later.

You'll find the repo at:

https://github.com/magnars/dash.el

Run the tests with

./run-tests.sh

Create the docs with

./create-docs.sh

I highly recommend that you install these as a pre-commit hook, so that the tests are always running and the docs are always in sync:

cp pre-commit.sh .git/hooks/pre-commit

Oh, and don't edit README.md directly, it is auto-generated. Change readme-template.md or examples-to-docs.el instead.

• Add -let destructuring to -if-let and -when-let (Fredrik Bergroth)

• Add -let, -let* and -lambda with destructuring
• Add -tree-seq and -tree-map-nodes
• Add -non-nil
• Add -fix
• Add -fixfn (dash-functional 1.2)
• Add -copy (Wilfred Hughes)

• Add -butlast

• -zip now supports more than two lists (Steve Lamb)
• Add -cycle , -pad , -annotate , -zip-fill (Steve Lamb)
• Add -table, -table-flat (finite cartesian product)
• Add -flatten-n
• -slice now supports "step" argument
• Add functional combinators -iteratefn, -prodfn
• Add -replace, -splice, -splice-list which generalize -replace-at and -insert-at
• Add -compose, -iteratefn and -prodfn (dash-functional 1.1)

• Add -is-prefix-p, -is-suffix-p, -is-infix-p (Matus Goljer)
• Add -iterate, -unfold (Matus Goljer)
• Add -split-on, -split-when (Matus Goljer)
• Add -find-last-index (Matus Goljer)
• Add -list (Johan Andersson)

• Add -same-items? (Johan Andersson)
• A few bugfixes

• Add -snoc (Matus Goljer)
• Add -replace-at, -update-at, -remove-at, and -remove-at-indices (Matus Goljer)

• Add tree operations (Matus Goljer)
• Make font-lock optional

• Add -compose (Christina Whyte)

• Add indexing operations (Matus Goljer)

• Split out dash-functional.el (Matus Goljer)
• Add -andfn, -orfn, -not, -cut, -const, -flip and -on. (Matus Goljer)
• Fix -min, -max, -min-by and -max-by (Matus Goljer)

• Add -first-item and -last-item (Wilfred Hughes)

• Add -rotate (Matus Goljer)

• Add -min, -max, -min-by and -max-by (Johan Andersson)

• Add -sum and -product (Johan Andersson)

• Add -sort
• Add -reduce-r (Matus Goljer)
• Add -reduce-r-from (Matus Goljer)

• Add -partition-in-steps
• Add -partition-all-in-steps

• Add -last (Matus Goljer)
• Add -insert-at (Emanuel Evans)
• Add -when-let and -if-let (Emanuel Evans)
• Add -when-let* and -if-let* (Emanuel Evans)
• Some bugfixes

• Matus Goljer contributed lots of features and functions.
• Takafumi Arakaki contributed -group-by.
• tali713 is the author of -applify.
• Víctor M. Valenzuela contributed -repeat.
• Nic Ferrier contributed -cons*.
• Wilfred Hughes contributed -slice, -first-item and -last-item.
• Emanuel Evans contributed -if-let, -when-let and -insert-at.
• Johan Andersson contributed -sum, -product and -same-items?
• Christina Whyte contributed -compose
• Steve Lamb contributed -cycle, -pad, -annotate, -zip-fill and an n-ary version of -zip.
• Fredrik Bergroth made the -if-let family use -let destructuring and improved script for generating documentation.
• Mark Oteiza contributed the script to create an info manual.
• Vasilij Schneidermann contributed -some.
• William West made -fixfn more robust at handling floats.

Thanks!

Copyright (C) 2012-2014 Magnar Sveen

Authors: Magnar Sveen magnars@gmail.com Keywords: lists

This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with this program. If not, see http://www.gnu.org/licenses/.