Wolfram Language & System Documentation Center

FormulaData[name]

gives the equations for the formula name.

FormulaData[name,{var1quantity1,var2quantity2,…}]

solves or simplifies equations using the specified values quantityi for the variables vari.

FormulaData[name,"property"]

gives the value of the specified property for the formula name.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Usage  
Multiple Equations  
Variable Specification  
Options  
UnitSystem  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
Common Physical Constants  
Explore Fundamental Physics Formulas  
See Also
Related Guides
History
Cite this Page

FormulaData

FormulaData[name]

gives the equations for the formula name.

FormulaData[name,{var1quantity1,var2quantity2,…}]

solves or simplifies equations using the specified values quantityi for the variables vari.

FormulaData[name,"property"]

gives the value of the specified property for the formula name.

Details and Options

  • FormulaData returns algebraic equations for formulas using standard names such as "OhmsLaw" or "LawOfSines".
  • The variables returned by FormulaData are expressed with the QuantityVariable wrapper.
  • Specified values for vari can be entered as a List or Association.
  • When specifying a list of values to insert into an equation, an input variable value can be specified with var->value; var can be a string or QuantityVariable, and value can be a number, symbol, or Quantity.
  • If the number of unspecified variables equals the number of equations, FormulaData will attempt to solve for the remaining variables for a real-valued solution. Otherwise it will replace all specified variables with the supplied values.
  • FormulaData[] returns a list of all available formulas.
  • FormulaData["Properties"] returns all available properties for formulas.
  • Properties include:
  • "Classes"what classes contain this formula
    "DefaultValues"sample values for the variables
    "ExternalIdentifiers"source information for the formula
    "Formula"equations for the formula
    "QuantityVariableDimensions"list of base dimensions for all variables
    "QuantityVariableNames"English names for all variables
    "QuantityVariablePhysicalQuantities"physical quantities for all variables
    "QuantityVariables"list of all variables in the formula
    "QuantityVariableTable"details on all variables for the formula
  • "Classes" include general categories such as "Physics" or "Chemistry" as well as subcategorizations such as {"Physics", "Mechanics"}.
  • "Association" can be specified as a second or third argument to alter output to Association. FormulaData[name, "Association"] returns the equation or equations as an Association with the left-hand side of the equations as keys. FormulaData[name,{var1quantity1,var2quantity2,…},"Association"] returns the solution to the formula or simplified equations as an Association. FormulaData[name,"property","Association"] returns an Association instead of a List.
  • FormulaData takes the following options:
  • UnitSystem $UnitSystemunit system in which results are returned
    "UseDefaultValues"Falsesupply default values for unspecified units

Examples

open all close all

Basic Examples  (3)

Find the equation for a formula:

Wolfram Language code: FormulaData["OhmsLaw"]

Include values to solve for formula variables:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"], "R" -> Quantity[1, "Ohms"]}]

Formula names can be found with FormulaLookup:

Wolfram Language code: FormulaLookup["kinetic energy"]
Wolfram Language code: FormulaData["KineticEnergy"]

Formula values can be inserted using free-form input ():

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> ["3V"], "R" -> ["2Ω"]}]

Scope  (16)

Usage  (9)

Find all formulas used by FormulaData:

Wolfram Language code: FormulaData[]//Short

Find all properties supported by FormulaData:

Wolfram Language code: FormulaData["Properties"]

Get all instances of QuantityVariable in the equations:

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariables"]

Find the physical quantities for the equation variables:

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariablePhysicalQuantities"]

Learn the variable names for the equation:

Wolfram Language code: FormulaData["ConeMomentOfInertia", "QuantityVariableNames"]

Find the dimensions of physical quantities for the equation:

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariableDimensions"]

Display all the properties of the formula variables:

Wolfram Language code: FormulaData["OhmsLaw", "QuantityVariableTable"]

Find source information for formulas:

Wolfram Language code: FormulaData["DolbearsLaw", "ExternalIdentifiers"]
Wolfram Language code: FormulaData[{"BussardRamjet", "PhotonDrive"}, "ExternalIdentifiers"]

Find what classes a formula belongs to:

Wolfram Language code: FormulaData["OhmsLaw", "Classes"]

Multiple Equations  (3)

Some formulas have multiple equations:

Wolfram Language code: FormulaData["ConeMomentOfInertia"]

Formulas with multiple equations will be solved for all variables if possible:

Wolfram Language code: FormulaData["TriangleAreaSSS", {"a" -> Quantity[1, "Meters"], "b" -> Quantity[1, "Meters"], "c" -> Quantity[1, "Meters"]}]

Some formula standard names are specified as lists, such as the different forms of Planck's radiation law:

Wolfram Language code: FormulaLookup["planck's law"]
Wolfram Language code: Column[{FormulaData[{"PlanckRadiationLaw", "Wavelength"}], FormulaData[{"PlanckRadiationLaw", "Frequency"}]}]

Variable Specification  (4)

Formula variables can be specified with QuantityVariable:

Wolfram Language code: FormulaData["OhmsLaw", {QuantityVariable["V", "ElectricPotential"] -> Quantity[1, "Volts"]}]

The symbol component of QuantityVariable can also be used:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"]}]

Variables are valid inputs for a formula variable:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> x}]

Pure numbers are also valid:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> 2}]

Association can be used to specify formula variables:

Wolfram Language code: FormulaData["OhmsLaw", <|QuantityVariable["V", "ElectricPotential"] -> Quantity[1, "Volts"]|>]

Options  (1)

UnitSystem  (1)

Use UnitSystem to control the units for results:

Wolfram Language code: FormulaData["DolbearsLaw", {"N" -> 60}, UnitSystem -> "Imperial"]
Wolfram Language code: FormulaData["DolbearsLaw", {"N" -> 60}, UnitSystem -> "Metric"]

Applications  (1)

Formula equations can be used in subsequent calculations:

Wolfram Language code: equation = FormulaData["StefanBoltzmannLaw", {"ϵ" -> 1, "T" -> Quantity[t, "Kelvins"]}]

Integrate over temperature:

Wolfram Language code: Integrate[equation[[2]], {t, 0, 1000}]

Plot the behavior of the equation:

Wolfram Language code: Plot[equation[[2]], {t, 0, 1000}, AxesLabel -> {"temperature", equation[[1]]}]

Properties & Relations  (2)

Use FormulaLookup to find formulas by class or name:

Wolfram Language code: FormulaLookup["uncertianty relation"]

Classes include strings and more specific lists of strings:

Wolfram Language code: FormulaLookup[{"Physics", "QuantumMechanics"}]//Short

Get a list of available classes:

Wolfram Language code: FormulaLookup["Classes"]//Short

Find classes for a specific formula:

Wolfram Language code: FormulaData["OhmsLaw", "Classes"]

Possible Issues  (3)

Use FormulaLookup to find the names of formulas:

Wolfram Language code: FormulaData["ohm's law"]
Wolfram Language code: FormulaLookup["ohm's law"]

Input quantities should have appropriate dimensions:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Amps"]}]

If there are fewer unspecified variables than equations in the formula, then the system is overdetermined:

Wolfram Language code: FormulaData["OhmsLaw", {"V" -> Quantity[1, "Volts"], "I" -> Quantity[1, "Amperes"], "R" -> Quantity[1, "Ohms"]}]

Neat Examples  (2)

Common Physical Constants  (1)

Find all formulas that contain both the speed of light and Planck's constant as parameters:

Wolfram Language code: Grid[{#, FormulaData[#]}& /@ Select[FormulaData[], MemberQ[FormulaData[#], "SpeedOfLight", ∞] && MemberQ[FormulaData[#], "PlanckConstant", ∞]&], Dividers -> Center, Alignment -> Left]

Explore Fundamental Physics Formulas  (1)

Select all formulas that contain Planck's constant, speed of light, or gravitational constant as a parameter:

Wolfram Language code: chGFormulas = Select[(Column[Flatten@{#, FormulaData[#], FormulaData[#, "QuantityVariableTable"]}]& /@ FormulaData[]) /. Quantity[q_, "ReducedPlanckConstant"] :> Quantity[q /. None -> 1 / (2Pi), "PlanckConstant"], MemberQ[#, "PlanckConstant" | "SpeedOfLight" | "GravitationalConstant", ∞]&];

Construct a network of formulas based on related physical quantities:

Wolfram Language code: chGformulaNetwork = Select[{UndirectedEdge[#1, #2], Length[Intersection @@(Union[Last /@ Cases[#, _QuantityVariable, ∞]]& /@ {#1, #2})]}&@@@ Subsets[chGFormulas, {2}], Last[#] > 0&];
Wolfram Language code: Graph[First /@ chGformulaNetwork, EdgeWeight -> 1 / (Last /@ chGformulaNetwork), GraphLayout -> {"VertexLayout" -> {"SpringElectricalEmbedding", "EdgeWeighted" -> True}}, VertexLabels -> Placed["Name", Tooltip]]
Wolfram Research (2014), FormulaData, Wolfram Language function, https://reference.wolfram.com/language/ref/FormulaData.html (updated 2019).

Text

Wolfram Research (2014), FormulaData, Wolfram Language function, https://reference.wolfram.com/language/ref/FormulaData.html (updated 2019).

CMS

Wolfram Language. 2014. "FormulaData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/FormulaData.html.

APA

Wolfram Language. (2014). FormulaData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FormulaData.html

BibTeX

@misc{reference.wolfram_2026_formuladata, author="Wolfram Research", title="{FormulaData}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/FormulaData.html}", note=[Accessed: 01-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_formuladata, organization={Wolfram Research}, title={FormulaData}, year={2019}, url={https://reference.wolfram.com/language/ref/FormulaData.html}, note=[Accessed: 01-September-2026]}