Wolfram Language & System Documentation Center

InterpolatingFunction[domain,…]

represents an approximate function whose values are found by interpolation.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

InterpolatingFunction

InterpolatingFunction[domain,…]

represents an approximate function whose values are found by interpolation.

Details

  • InterpolatingFunction works like Function.
  • InterpolatingFunction[…][x] finds the value of an approximate function with a particular argument x.
  • In standard output format, only the domain element of an InterpolatingFunction object is printed explicitly. The remaining elements are indicated by <>. »
  • domain specifies the domain of the data from which the InterpolatingFunction was constructed.
  • If you supply arguments outside of the domain, a warning is generated, and then an extrapolated value is returned.
  • InterpolatingFunction objects that take any number of real arguments may be constructed.
  • You can take derivatives of InterpolatingFunction objects using D and Derivative.
  • NDSolve returns its results in terms of InterpolatingFunction objects.
  • You can create InterpolatingFunction objects using Interpolation or ListInterpolation.
  • InterpolatingFunction[…][prop] gives the property prop of the InterpolatingFunction object. The following properties may be given:
  • "Coordinates"grid coordinates for each tensor product dimension
    "DerivativeOrder"what derivative of the interpolated function will be computed upon evaluation
    "Domain"the bounding box of domain of the InterpolatingFunction
    "ElementMesh"the spatial mesh if one is present
    "InterpolationMethod"the method used for interpolation
    "InterpolationOrder"the degree of polynomials used for computing interpolated values
    "Periodicity"whether the interpolating function is periodic in the respective dimensions
    "QuantityUnits"the quantity units associated with abscissa and ordinates
    "ValuesOnGrid"gives the function values at each mesh coordinate

Examples

open all close all

Basic Examples  (2)

Make an InterpolatingFunction object that will go through the given points:

Wolfram Language code: points = {{0, 0}, {1, 1}, {2, 3}, {3, 4}, {4, 3}, {5, 0}};

Only the domain is shown in standard output format:

Wolfram Language code: ifun = Interpolation[points]

Evaluate the function at a point in the domain:

Wolfram Language code: ifun[2.5]

Plot the function over its domain, showing the interpolation points:

Wolfram Language code: Plot[ifun[x], {x, 0, 5}, Epilog -> Point[points]]

Get an InterpolatingFunction object approximating the solution of a differential equation:

Wolfram Language code: ifun = First[u /. NDSolve[{u''[t] + u[t] == 0, u[0] == 0, u'[0] == 1}, u, {t, 0, π}]]

Plot the function and its derivative:

Wolfram Language code: Plot[{ifun[t], ifun'[t]}, {t, 0, π}]

Find the indefinite integral of the solution:

Wolfram Language code: Integrate[ifun[t], t]
Wolfram Language code: Plot[%, {t, 0, π}]

Scope  (5)

Basic Uses  (5)

Make an InterpolatingFunction with exact data:

Wolfram Language code: points = {{0, 0}, {1, 1}, {2, 3}, {3, 4}, {4, 3}, {5, 0}};ifun = Interpolation[points]

Compute the value using exact arithmetic:

Wolfram Language code: ifun[5 / 2]

Compute using machine-number arithmetic:

Wolfram Language code: ifun[N[5 / 2]]

Compute using arbitrary-precision arithmetic:

Wolfram Language code: ifun[N[5 / 2, 20]]

Make a new InterpolatingFunction with numerical values of all the data:

Wolfram Language code: nifun = N[ifun]

With this InterpolatingFunction values are computed using machine arithmetic:

Wolfram Language code: nifun[5 / 2]

Integrate an InterpolatingFunction:

Wolfram Language code: ifun = Interpolation[{{0, 0}, {1, 1}, {2, 3}, {3, 4}, {4, 3}, {5, 0}}];
Wolfram Language code: Integrate[ifun[x], {x, 0, 5}]

Make a new InterpolatingFunction that is the indefinite integral:

Wolfram Language code: indef[x_] = Integrate[ifun[x], x]
Wolfram Language code: Plot[{ifun[x], indef[x]}, {x, 0, 5}]

The derivative of an InterpolatingFunction is another InterpolatingFunction:

Wolfram Language code: ifun = Interpolation[{{0, 0}, {1, 1}, {2, 3}, {3, 4}, {4, 3}, {5, 0}}];
Wolfram Language code: difun = ifun'
Wolfram Language code: Plot[{ifun[x], difun[x]}, {x, 0, 5}]

Use partial derivatives of an InterpolatingFunction to check the residual for a PDE:

Wolfram Language code: ifun = NDSolveValue[{D[u[t, x], t] == D[u[t, x], x, x], u[0, x] == Exp[-100x ^ 2], u[t, 0] == 1, u[t, 1] == 0}, u, {t, 0, 1}, {x, 0, 1}];
Wolfram Language code: Plot[Derivative[1, 0][ifun][1, x] - Derivative[0, 2][ifun][1, x], {x, 0, 1}]

Make an InterpolatingFunction that takes 4 arguments:

Wolfram Language code: ifun = ListInterpolation[RandomReal[1, {5, 5, 5, 5}], {{0, 1}, {0, 2}, {0, 3}, {0, 4}}]

Integrate it across the first and last dimensions:

Wolfram Language code: integ = Integrate[ifun[x1, x2, x3, x4], {x1, 0, 1}, {x4, 0, 4}]
Wolfram Language code: Plot3D[integ, {x2, 0, 2}, {x3, 0, 3}]

Properties & Relations  (1)

InterpolatingFunction does a Piecewise polynomial interpolation:

Wolfram Language code: points = {{0, 0}, {1, 1}, {2, 3}, {3, 4}, {4, 3}, {5, 0}};ifun = Interpolation[points]
Wolfram Language code: pf[x_] = Piecewise[{{InterpolatingPolynomial[Take[points, {1, 4}], x], x < 2}, {InterpolatingPolynomial[Take[points, {2, 5}], x], 2 ≤ x < 3}, {InterpolatingPolynomial[Take[points, {3, 6}], x], x ≥ 3}}]
Wolfram Language code: Plot[pf[x] - ifun[x], {x, 0, 5}, PlotRange -> All]
Wolfram Research (1991), InterpolatingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/InterpolatingFunction.html (updated 1996).

Text

Wolfram Research (1991), InterpolatingFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/InterpolatingFunction.html (updated 1996).

CMS

Wolfram Language. 1991. "InterpolatingFunction." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/InterpolatingFunction.html.

APA

Wolfram Language. (1991). InterpolatingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InterpolatingFunction.html

BibTeX

@misc{reference.wolfram_2026_interpolatingfunction, author="Wolfram Research", title="{InterpolatingFunction}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/InterpolatingFunction.html}", note=[Accessed: 01-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_interpolatingfunction, organization={Wolfram Research}, title={InterpolatingFunction}, year={1996}, url={https://reference.wolfram.com/language/ref/InterpolatingFunction.html}, note=[Accessed: 01-September-2026]}