ExtremeValueDistribution
represents an extreme value distribution with location parameter α and scale parameter β.
represents an extreme value distribution with location parameter 0 and scale parameter 1.
Details
- The extreme value distribution gives the asymptotic distribution of the maximum value in a sample from a distribution such as the normal distribution.
- The probability density for value
in an extreme value distribution is proportional to 
. » - The asymptotic distribution of the minimum value, also sometimes called an extreme value distribution, is implemented in the Wolfram Language as GumbelDistribution. »
- ExtremeValueDistribution allows α to be any real number and β to be any positive real number.
- ExtremeValueDistribution allows α and β to be any quantities of the same unit dimensions. »
- ExtremeValueDistribution can be used with such functions as Mean, CDF, and RandomVariate. »
Background & Context
- ExtremeValueDistribution[α,β] represents a continuous statistical distribution defined over the set of real numbers and parametrized by a real number α, called a "location parameter", and a positive real number β, called a "scale parameter". While the overall behavior of the probability density function (PDF) of the extreme value distribution is smooth and unimodal, the parameters α and β determine the horizontal location and overall height and steepness, respectively, of the PDF. In addition, the tails of the PDF are "thin", in the sense that the PDF decreases exponentially for large values of
. (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.) The extreme value distribution may also be referred to as the type-1 extreme value distribution, the doubly exponential distribution (not to be confused with LaplaceDistribution, which may also be called doubly exponential), the log-Weibull distribution (WeibullDistribution), or the Gumbel-type distribution (not to be confused with GumbelDistribution). - While ExtremeValueDistribution is sometimes referred to as "the" extreme value distribution, it is actually one of four distributions (along with GumbelDistribution, FrechetDistribution, and WeibullDistribution) classified under the general heading "extreme value distribution". The extreme value distribution is obtained as the limiting distribution of greatest values in random samples of increasing size, and because its PDF is doubly exponential (i.e. is of the form Exp[-Exp[…]]), the graph of the distribution has more exaggerated features (like higher peaks and thinner tails), a property unique among distributions. It was introduced in the early 1920s to address the need in astronomy to utilize or reject outlying observations. A cornerstone in the field known as extreme value theory, the extreme value distribution is widely utilized to describe situations that are "extremely unlikely" (i.e. those in which datasets consist of variates with extreme deviations from the median), e.g. extreme floods, catastrophic insurance losses, and large wildfires. Moreover, the extreme value distribution can be used in biology as a tool to model evolutionary genetic mutations.
- RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from an extreme value distribution. Distributed[x,ExtremeValueDistribution[α,β]], written more concisely as xExtremeValueDistribution[α,β], can be used to assert that a random variable x is distributed according to an extreme value distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
- The probability density and cumulative distribution functions may be given using PDF[ExtremeValueDistribution[α,β],x] and CDF[ExtremeValueDistribution[α,β],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
- DistributionFitTest can be used to test if a given dataset is consistent with an extreme value distribution, EstimatedDistribution to estimate an extreme value parametric distribution from given data, and FindDistributionParameters to fit data to an extreme value distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic extreme value distribution and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic extreme value distribution.
- TransformedDistribution can be used to represent a transformed extreme value distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain an extreme value distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving extreme value distributions.
- The extreme value distribution is related to a number of other distributions. As mentioned previously, ExtremeValueDistribution is one of a number of distributions, including GumbelDistribution, FrechetDistribution, and WeibullDistribution, that are used to describe extremely unlikely events. This qualitative relationship also has quantitative components, as the PDF of ExtremeValueDistribution[α,β] is precisely the same as that of TransformedDistribution[-u,u GumbelDistribution[-α,β]] and TransformedDistribution[-β α Log[u/β]+α,u WeibullDistribution[α,β]]. ExtremeValueDistribution is a transformation of ExponentialDistribution and MinStableDistribution, and is a special case of MaxStableDistribution, in the sense that the PDF of ExtremeValueDistribution[α,β] is identical to that of MaxStableDistribution[α,β,0]. ExtremeValueDistribution is also related to ExpGammaDistribution, ExponentialDistribution, and LogisticDistribution.
Examples
open all close allBasic Examples (4)
Plot[Table[PDF[ExtremeValueDistribution[α, 2], x], {α, {-3, 0, 4}}]//Evaluate, {x, -8, 12}, Filling -> Axis]Plot[Table[PDF[ExtremeValueDistribution[1.5, β], x], {β, {1.5, 2, 3}}]//Evaluate, {x, -5, 10}, Filling -> Axis]PDF[ExtremeValueDistribution[α, β], x]Cumulative distribution function:
Plot[Table[CDF[ExtremeValueDistribution[α, 2], x], {α, {-3, 0, 4}}]//Evaluate, {x, -8, 12}, Filling -> Axis]Plot[Table[CDF[ExtremeValueDistribution[1.5, β], x], {β, {1.5, 2, 3}}]//Evaluate, {x, -5, 10}, Filling -> Axis]CDF[ExtremeValueDistribution[α, β], x]Mean[ExtremeValueDistribution[α, β]]Variance[ExtremeValueDistribution[α, β]]Median[ExtremeValueDistribution[α, β]]Scope (7)
Generate a sample of pseudorandom numbers from an extreme value distribution:
data = RandomVariate[ExtremeValueDistribution[3, 2.5], 10 ^ 4];Compare the histogram to the PDF:
Show[Histogram[data, 20, "PDF"], Plot[PDF[ExtremeValueDistribution[3, 2.5], x], {x, Min[data], Max[data]}, PlotStyle -> Thick]]Distribution parameters estimation:
sample = RandomVariate[ExtremeValueDistribution[2, 3], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, ExtremeValueDistribution[α, β]]Compare a density histogram of the sample with the PDF of the estimated distribution:
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, Min[sample], Max[sample]}, PlotStyle -> Thick]]Skewness and kurtosis are constant:
Skewness[ExtremeValueDistribution[α, β]]N[%]Kurtosis[ExtremeValueDistribution[α, β]]N[%]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[ExtremeValueDistribution[α, β], k]//FullSimplify, {k, 4}], M]FormulaGrid[Table[CentralMoment[ExtremeValueDistribution[α, β], k], {k, 4}], CM]FormulaGrid[Table[FactorialMoment[ExtremeValueDistribution[α, β], k]//FullSimplify, {k, 4}], FM]FormulaGrid[Table[Cumulant[ExtremeValueDistribution[α, β], k], {k, 4}], C]Closed form for symbolic order:
Cumulant[ExtremeValueDistribution[α, β], r]Plot[Table[HazardFunction[ExtremeValueDistribution[α, 2], x], {α, {1 / 2, 4, 7}}]//Evaluate, {x, -4, 15}, Filling -> Axis]Plot[Table[HazardFunction[ExtremeValueDistribution[1 / 2, β], x], {β, {1 / 2, 1, 2}}]//Evaluate, {x, -2, 4}, Filling -> Axis]HazardFunction[ExtremeValueDistribution[α, β], x]Plot[Table[Quantile[ExtremeValueDistribution[2, β], q], {β, {0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Plot[Table[Quantile[ExtremeValueDistribution[α, 1.5], q], {α, {-0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[ExtremeValueDistribution[α, β], q]Consistent use of Quantity in parameters yields QuantityDistribution:
oilPrice𝒟 = ExtremeValueDistribution[["100 USDollars/barrel"], ["18 USDollars/barrel"]]Find the median and the quartile deviation of the oil price:
{Median[oilPrice𝒟], QuartileDeviation[oilPrice𝒟]}//NApplications (3)
The lifetime of a device has an extreme value distribution. Find the reliability of the device:
r = SurvivalFunction[ExtremeValueDistribution[α, β], t]The failure rate has a horizontal asymptote that depends only on the second parameter:
HazardFunction[ExtremeValueDistribution[α, β], t]Limit[HazardFunction[ExtremeValueDistribution[α, β], t], t -> ∞, Assumptions -> α > 0 && β > 0]Find the reliability of two such devices in series:
rs = r r//PiecewiseExpandFind the reliability of two such devices in parallel:
rp = 1 - (1 - r)(1 - r)//PiecewiseExpandCompare the reliability of both systems for 
and 
:
Block[{α = 2, β = 1.5}, Plot[{rs, rp}, {t, 0, 10}, PlotLegends -> {"in series", "in parallel"}]]ExtremeValueDistribution can be used to model monthly maximum wind speeds. Recorded monthly maxima of wind speeds in km/h for Boston, MA, from January 1950 till December 2009:
maxWinds = TemporalData[TimeSeries,
{{QuantityArray[StructuredArray`StructuredData[{720},
{{66.6, 55.8, 55.8, 51.84, 50.04, 50.04, 42.48, 38.88, 66.6, 44.64, 96.48, 55.8, 48.24, 72.36,
55.8, 53.64, 53.64, 44.64, 42.48, 48.24, 44.64, 44.64, 74. ... 46.44, 51.84, 48.24,
46.44, 37.08, 46.44, 46.44, 48.24, 59.4}, "Kilometers"/"Hours", {{1}}}]]}, {{1, 720, 1}}, 1,
{"Continuous", 1}, {"Discrete", 1}, 1,
{ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 314.1];maxWinds["FirstValue"]Fit the distribution to the data:
edist = EstimatedDistribution[maxWinds, ExtremeValueDistribution[a, b]]Compare the histogram of the data with the PDF of the estimated distribution:
Show[Histogram[maxWinds, 20, "ProbabilityDensity"], Plot[PDF[edist, Quantity[x, "km per hour"]], {x, 30, 140}, PlotStyle -> Thick]]Find the probability of monthly maximum wind speed exceeding 60 mph:
Probability[x > Quantity[60, "mph"], xedist]Find the average monthly maximum wind speed:
Mean[edist]Simulate maximum wind speed for 30 months:
ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Joined -> {False, True}, Filling -> Axis, AxesOrigin -> {0, 0}, AxesLabel -> Automatic]Construct an approximation for the distribution of maximum value in a normal sample of size 
:
max𝒟 = OrderDistribution[{NormalDistribution[], n}, n];
approx𝒟 = ExtremeValueDistribution[InverseCDF[NormalDistribution[], 1 - (1/n + 1)], InverseCDF[NormalDistribution[], 1 - (1/(n + 1) E)] - InverseCDF[NormalDistribution[], 1 - (1/n + 1)]];Compare density function plots:
Table[Plot[{PDF[max𝒟, y], PDF[approx𝒟, y]}, {y, -2, 4.5}, PlotStyle -> {Dashed, Orange}, PlotRange -> All], {n, {2, 4, 8}}]approxMean = Simplify[Mean[approx𝒟]]exactMean[n_Integer] := Mean[OrderDistribution[{NormalDistribution[0., 1.], n}, n]]Compare with the mean of exact distribution:
Show[DiscretePlot[exactMean[n], {n, 2, 100}, PlotStyle -> Orange], Plot[approxMean, {n, 2, 100}, PlotRange -> All, PlotStyle -> Directive[Thick, Dashed]]]Properties & Relations (17)
Extreme value distribution is closed under translation and scaling by a positive factor:
TransformedDistribution[a * u + b, uExtremeValueDistribution[]]With arbitrary parameter values:
TransformedDistribution[a * u + b, uExtremeValueDistribution[α, β]]Skewness is the negative of the skewness of GumbelDistribution:
ExtremeValue = ExtremeValueDistribution[α, β];
Gumbel = GumbelDistribution[α, β];{Skewness[ExtremeValue], Skewness[Gumbel]}ExtremeValueDistribution is skewed to the right, while GumbelDistribution is skewed to the left:
Block[{α = 4, β = 2}, Plot[{PDF[ExtremeValue, x], PDF[Gumbel, x]}, {x, -5, 15}, Filling -> Axis, PlotLegends -> {"ExtremeValue", "Gumbel"}]]Kurtosis is the same as for GumbelDistribution:
{Kurtosis[ExtremeValueDistribution[α, β]], Kurtosis[GumbelDistribution[α, β]]}ExtremeValueDistribution is closed under taking Max:
OrderDistribution[{ExtremeValueDistribution[α, β], n}, n]TransformedDistribution[Max[x1, x2, x3], {x1, x2, x3}ProductDistribution[{ExtremeValueDistribution[α, β], 3}]]CDF of ExtremeValueDistribution solves the stability postulate equation:
CDF[OrderDistribution[{ExtremeValueDistribution[α, β], n}, n], x] == CDF[ExtremeValueDistribution[α, β], a x + b]Find the conditions on 
and 
such that the above is an identity:
Reduce[ForAll[x, %] && DistributionParameterAssumptions[ExtremeValueDistribution[α, β]], {a, b}, Reals]Relationships to other distributions:
ExtremeValueDistribution is the negative of GumbelDistribution:
TransformedDistribution[-u, uGumbelDistribution[α, β]]TransformedDistribution[-u, uExtremeValueDistribution[α, β]]ExtremeValueDistribution is a transformation of WeibullDistribution:
TransformedDistribution[m - k * Log[c * u], uWeibullDistribution[α, β], Assumptions -> c > 0 && k > 0]WeibullDistribution is a transformation of extreme value distribution:
𝒟 = TransformedDistribution[β Exp[-(u - α) / (α β) ], uExtremeValueDistribution[α, β]];Block[{α = 2, β = .5}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[WeibullDistribution[α, β], x], {x, 0, 1.5}, PlotStyle -> Thick]]]Extreme value distribution is a special case of MaxStableDistribution:
PDF[MaxStableDistribution[α, β, 0], x]PDF[ExtremeValueDistribution[α, β], x]% - %%//FullSimplifyExtreme value distribution is a transformation of MinStableDistribution:
𝒟 = TransformedDistribution[-u, uMinStableDistribution[-α, β, 0]];PDF[𝒟, x]PDF[ExtremeValueDistribution[α, β], x]% - %%//FullSimplifyExtreme value distribution is a transformation of ExponentialDistribution:
𝒟 = TransformedDistribution[α - β Log[u], uExponentialDistribution[1]];PDF[𝒟, x]//FullSimplify[#, β > 0]&PDF[ExtremeValueDistribution[α, β], x]% - %%The difference of two variates from extreme value distribution follows the same distribution as the difference of two variates from GumbelDistribution, which is LogisticDistribution:
TransformedDistribution[u - v, {uExtremeValueDistribution[α1, β], vExtremeValueDistribution[α2, β]}]TransformedDistribution[u - v, {uGumbelDistribution[α1, β], vGumbelDistribution[α2, β]}]The sum of extreme value distribution and GumbelDistribution follows LogisticDistribution:
TransformedDistribution[u + v, {uExtremeValueDistribution[α1, β], vGumbelDistribution[α2, β]}]LogisticDistribution is a ParameterMixtureDistribution of extreme value distribution:
𝒟 = ParameterMixtureDistribution[ExtremeValueDistribution[α, β], αGumbelDistribution[-β Log[γ], β]];PDF[𝒟, x]PDF[LogisticDistribution[-Log[γ]β, β], x]//Simplify% - %%The maximum of ExponentialDistribution and ExtremeValueDistribution follows ShiftedGompertzDistribution:
dist = TransformedDistribution[Max[x, y], {xExponentialDistribution[λ], yExtremeValueDistribution[Log[ξ] / λ, 1 / λ]}];CDF[dist, x]CDF[ShiftedGompertzDistribution[λ, ξ], x]% - %%//SimplifyMaximum of 
independent exponentially distributed random variables, where 
follows a PoissonDistribution, follows ExtremeValueDistribution:
res1 = Sum[CDF[OrderDistribution[{ExponentialDistribution[λ], n}, n], x]PDF[PoissonDistribution[μ], n], {n, 0, ∞}]//FullSimplify[#, x >= 0]&res2 = CDF[ExtremeValueDistribution[-(Log[(1/μ)]/λ), (1/λ)], x]//FullSimplifyFullSimplify[res1 / res2]Possible Issues (3)
The distribution of maximum values is given by ExtremeValueDistribution:
PDF[ExtremeValueDistribution[α, β], x]The distribution of minimum values is given by GumbelDistribution:
PDF[GumbelDistribution[α, β], x]ExtremeValueDistribution is not defined when α is not a real number:
Mean[ExtremeValueDistribution[3 + I, 1]]
ExtremeValueDistribution is not defined when β is not a positive real number:
Mean[ExtremeValueDistribution[3, -1]]
The substitution of invalid parameters into symbolic outputs gives results that are not meaningful:
Mean[ExtremeValueDistribution[α, β]] /. {α -> I, β -> 3}Neat Examples (1)
PDFs for different α values with CDF contours:
dist = ExtremeValueDistribution[α, 2];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[dist, x], {x, -4, 7}, {α, -3, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotPoints -> 100, PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]Text
Wolfram Research (2007), ExtremeValueDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html (updated 2016).
CMS
Wolfram Language. 2007. "ExtremeValueDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html.
APA
Wolfram Language. (2007). ExtremeValueDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExtremeValueDistribution.html