PoissonDistribution
represents a Poisson distribution with mean μ.
Details
- The probability for integer value
in a Poisson distribution is 
for 
and is zero for 
. » - PoissonDistribution allows μ to be any positive real number.
- PoissonDistribution can be used with such functions as Mean, CDF, and RandomVariate. »
Background & Context
- PoissonDistribution[μ] represents a discrete statistical distribution defined for integer values
and determined by the positive real parameter μ (the mean of the distribution). The Poisson distribution has a probability density function (PDF) that is discrete and unimodal. It is sometimes referred to as the "classical Poisson distribution" to differentiate it from the more general Poisson–Consul distribution (PoissonConsulDistribution), which is itself sometimes referred to as the "general" Poisson distribution. - The derivation of the Poisson distribution dates to the work of French mathematician Abraham de Moivre from 1711. It is, however, named for French mathematician Siméon Poisson because of Poisson's utilization of the distribution to model wrongful convictions in the late 1830s. Classically, the Poisson distribution yields the likelihood of a given number of events occurring in a fixed interval if the events occur independently of the time since the last event and at a known average rate. Because of the techniques used to derive it, the distribution has been extremely useful in modeling situations consisting of a large number of independent trials with a consistent but very small probability of occurrence (e.g. the number of deaths per year of cavalry soldiers stemming from kicks by horse). The Poisson distribution has also been used to model a number of modern phenomena including internet traffic, phone call arrivals, and scoring in sporting events, and is a valuable modeling tool in areas such as finance, biology, physics, and telecommunications.
- RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a Poisson distribution. Distributed[x,PoissonDistribution[μ]], written more concisely as xPoissonDistribution[μ], can be used to assert that a random variable x is distributed according to a Poisson distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
- The probability density and cumulative distribution functions may be given using PDF[PoissonDistribution[μ],x] and CDF[PoissonDistribution[μ],x], though one should note that there is no closed-form expression for its CDF. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively. These quantities can be visualized using DiscretePlot.
- DistributionFitTest can be used to test if a given dataset is consistent with a Poisson distribution, EstimatedDistribution to estimate a Poisson parametric distribution from given data, and FindDistributionParameters to fit data to a Poisson distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic Poisson distribution and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic Poisson distribution.
- TransformedDistribution can be used to represent a transformed Poisson distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a Poisson distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving Poisson distributions.
- PoissonDistribution is related to a number of other statistical distributions. It is generalized by PoissonConsulDistribution in the sense that the PDF of PoissonDistribution[μ] is precisely that of PoissonConsulDistribution[μ,0]. Moreover, PoissonDistribution is a limiting case for both BinomialDistribution and PolyaAeppliDistribution in the sense that the PDF of BinomialDistribution[n,μ/n] as n→∞ is precisely the same as the PDF of PoissonDistribution[μ], while the PDF for PolyaAeppliDistribution[θ,p] tends to that of PoissonDistribution[θ] as p→0. PoissonDistribution is also related to NegativeBinomialDistribution, GammaDistribution, GeometricDistribution, ExponentialDistribution, BorelTannerDistribution, BinomialDistribution, NegativeMultinomialDistribution, and MultinomialDistribution.
Examples
open all close allBasic Examples (3)
DiscretePlot[Table[PDF[PoissonDistribution[λ], k], {λ, {5, 10, 20}}]//Evaluate, {k, 0, 30}, PlotRange -> All, PlotMarkers -> Automatic]PDF[PoissonDistribution[μ], k]PDF[PoissonDistribution[μ], 0]Cumulative distribution function:
DiscretePlot[Table[CDF[PoissonDistribution[λ], k], {λ, {5, 10, 20}}]//Evaluate, {k, 0, 30}, ExtentSize -> Right]CDF[PoissonDistribution[μ], k]Mean and variance of a Poisson distribution are the same:
Mean[PoissonDistribution[μ]]Variance[PoissonDistribution[μ]]Scope (7)
Generate a sample of pseudorandom numbers from a Poisson distribution:
data = RandomVariate[PoissonDistribution[3], 10 ^ 4];Compare its histogram to the PDF:
Show[
Histogram[data, {1}, "PDF"],
DiscretePlot[PDF[PoissonDistribution[3], x], {x, 0, Max[data]}, PlotStyle -> PointSize[Medium]]]Distribution parameters estimation:
sample = RandomVariate[PoissonDistribution[3], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, PoissonDistribution[μ]]Compare the density histogram of the sample with the PDF of the estimated distribution:
Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, Max[sample]}, PlotStyle -> PointSize[Medium]]]Plot[Skewness[PoissonDistribution[μ]], {μ, 0, 10}, Filling -> Axis]Skewness[PoissonDistribution[μ]]A Poisson distribution becomes more symmetric for large values of μ:
Limit[Skewness[PoissonDistribution[μ]], μ -> Infinity]Plot[Kurtosis[PoissonDistribution[μ]], {μ, 0, 10}, Filling -> Axis]Kurtosis[PoissonDistribution[μ]]Kurtosis of normal distribution is the limiting value for kurtosis of a Poisson distribution:
Limit[Kurtosis[PoissonDistribution[μ]], μ -> ∞]Kurtosis[NormalDistribution[μ, σ]]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[PoissonDistribution[μ], k], {k, 5}], M]Closed form for symbolic order:
Moment[PoissonDistribution[μ], r]FormulaGrid[Table[CentralMoment[PoissonDistribution[μ], k], {k, 5}], CM]FormulaGrid[Table[FactorialMoment[PoissonDistribution[μ], k], {k, 5}], FM]Closed form for symbolic order:
FactorialMoment[PoissonDistribution[μ], r]FormulaGrid[Table[Cumulant[PoissonDistribution[μ], k], {k, 5}], C]Cumulant[PoissonDistribution[μ], r]DiscretePlot[Table[HazardFunction[PoissonDistribution[μ], x], {μ, {5, 10, 20}}]//Evaluate, {x, 1, 30}, PlotMarkers -> Automatic]HazardFunction[PoissonDistribution[μ], x]𝒟 = PoissonDistribution[5];
points = Table[CDF[𝒟, x], {x, 0, 10}]//N;DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]Applications (14)
CDF of PoissonDistribution is an example of a right-continuous function:
DiscretePlot[CDF[PoissonDistribution[5], x], {x, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]The average number of accidents in a city is 100 per day. Simulate the daily accidents:
RandomVariate[PoissonDistribution[100], 30]ListPlot[%, Filling -> Axis]Find the probability that there are 90 or more accidents on a single day:
Probability[x ≥ 90, xPoissonDistribution[100.]]Find the standard deviation of the number of accidents per day:
StandardDeviation[PoissonDistribution[100.]]The expected number of raindrops falling into a bucket in a 5-second interval is 20. Simulate the raindrop count for each 5-second interval:
RandomVariate[PoissonDistribution[20], 20]ListPlot[%, Filling -> Axis]Find the probability that exactly 20 raindrops fall into the bucket in 5 seconds:
Probability[x == 20, xPoissonDistribution[20.]]A radioactive material on average emits 3.2 
-particles per second; show the distribution:
DiscretePlot[PDF[PoissonDistribution[3.2], k], {k, 0, 10}]Compute the probability that more than 4 
-particles are emitted over the next second:
Probability[x > 4, xPoissonDistribution[3.2]]Simulate a typical particle count per second over 10 minutes:
ListLinePlot[RandomVariate[PoissonDistribution[3.2], 60 10]]Suppose flaws in plywood occur on average of one flaw per 50 square feet. Simulate the process of finding flaws on a per-square-foot basis:
RandomVariate[PoissonDistribution[1 / 50], 100]Find the probability that a 4-foot-by-8-foot sheet will have no flaws:
Probability[x == 0, xPoissonDistribution[4 8 / 50]]//NFor a mirror with area 7.54 cm
, the probability of no flaws is 0.9100. Using the same polishing process, another mirror with an area of 19.50 cm
is fabricated. Assuming a Poisson error process, find the probability of no flaws on the larger mirror. Using the conditions for the smaller mirror and with error distribution PoissonDistribution [λ area]:
PDF[PoissonDistribution[λ 7.54], 0] == 0.9100{sol} = Solve[% && λ > 0, λ]//QuietThe resulting mirror polishing defect distribution is then:
mirrorDefectDistribution[area_] = PoissonDistribution[λ area] /. solThe probability of no errors in the larger mirror:
PDF[mirrorDefectDistribution[19.50], 0]Typographical errors in a book are occurring randomly according to a Poisson process. On 384 pages, 158 errors are counted. Find the distribution of errors per page where the distribution is of the form PoissonDistribution[λ p], where p is the number of pages:
Mean[PoissonDistribution[λ]] == (158/384){sol} = NSolve[%, λ]pageErrorDistribution[p_] = PoissonDistribution[λ p] /. solFind the probability of exactly 0 errors per page:
PDF[pageErrorDistribution[1], 0]Probability[e == 0, epageErrorDistribution[1]]Find the probability of fewer than 2 errors per page:
CDF[pageErrorDistribution[1], 1]Probability[e < 2, epageErrorDistribution[1]]Find the probability of 1 or more errors per page:
SurvivalFunction[pageErrorDistribution[1], 0]Probability[e ≥ 1, epageErrorDistribution[1]]In modeling an adverse reaction to a medicine, it is determined that on average 2 people per 100000 have the adverse reaction. Assuming a Poisson distribution, find the adverse reaction distribution:
Mean[PoissonDistribution[λ]] == (2/100000){sol} = Solve[%, λ]adverseReactionDistribution[p_] = PoissonDistribution[λ p] /. solFind the probability that there will be at least 5 adverse reactions when the medicine is administered to 350000 people:
Probability[a ≥ 5, aadverseReactionDistribution[350000]]N[%]The number of queries 
arriving in 
seconds to a call center is Poisson distributed with parameter 
, where 
is the average arrival rate in queries per second. Assuming that the average arrival rate is 4 queries per minute, find the probability of getting more than 4 queries in 10 seconds:
NProbability[n > 4, nPoissonDistribution[(4/60)10]]Find the probability that there are fewer than 5 queries in 2 minutes:
NProbability[n ≤ 5, nPoissonDistribution[(4/60)2 60]]The number of packet arrivals 
in 
seconds at a multiplexer is Poisson distributed with parameter 
, where 
is the average arrival rate in packets per second. Find the probability that there are no packet arrivals in 
seconds:
Probability[n == 0, nPoissonDistribution[λ t]]Find the probability that 
or fewer packets arrive in 
seconds:
Probability[n ≤ k, nPoissonDistribution[λ t], Assumptions -> k∈Integers && k ≥ 0]A data center has 10000 disk drives. Suppose that a disk fails in a given day with probability 
. Find the probability that there are no failures in a given day:
Probability[n == 0, nBinomialDistribution[10000, 0.001]]That distribution is closely approximated with a Poisson distribution with parameter 
:
Probability[n == 0, nPoissonDistribution[10^410^-3 1.]]Find the probability that there are fewer than 10 failures in 2 days:
Probability[n < 10, nPoissonDistribution[10 2.]]Find the number of spare disk drives that should be available so that all failures in a day can be replaced with probability 99.9%:
prob = Probability[n ≤ k, nPoissonDistribution[10], Assumptions -> k∈Integers]Plot the cumulative probability that the number of failures is less than 
:
DiscretePlot[prob, {k, 25}, AxesLabel -> {k, None}]Find the minimum number 
for which the probability is greater than 99.9%:
Minimize[{k, prob ≥ 999 / 1000 && k < 30}, k, Integers]prob /. {{k -> 20}, {k -> 21}}//NAn LCD display has 1920×1080 pixels. A display is accepted if it has 15 or fewer faulty pixels. The probability that a pixel is faulty from production is 
. Find the proportion of displays that are accepted:
NProbability[n ≤ 15, nPoissonDistribution[1920 * 1080 * 5 * 10^-6]]Find the pixel failure rate required to produce 4000×2000 pixel displays and still have an acceptance rate of at least 90%:
prob = Probability[n ≤ 15, nPoissonDistribution[4000 * 2000 λ]]Plot the acceptance rate as a function of the pixel failure rate:
LogLogPlot[prob, {λ, 10^-7, 10^-5}, GridLines -> All, Frame -> True, FrameLabel -> {"Pixel Failure Rate", None}, PlotLabel -> "LCD Acceptance Rate"]Find the maximal acceptable pixel failure rate:
Maximize[{λ, prob ≥ 9 / 10 && 10^-6 < λ < 2 * 10^-6}, λ, Reals]//N
CDF[PoissonDistribution[4000 * 2000 λ], 15] /. λ -> First[%]A switchboard receives on average 100 calls per minute. Find what the switchboard capacity should be so that it gets saturated less than once in every 60 minutes:
satprob = Probability[x > c, xPoissonDistribution[100], Assumptions -> c∈Integers && c > 0]Show[Plot[1 / 60, {x, 110, 140}, PlotStyle -> Red], DiscretePlot[satprob, {c, 110, 140}, PlotRange -> All]]Find the minimum capacity that satisfies the constraint:
Minimize[{c, satprob ≤ 1 / 60 && 110 < c < 140}, c, Integers]In an optical communication system, transmitted light generates current at the receiver. The number of electrons follows the parametric mixture of a Poisson distribution and another distribution, depending on the type of light. If the source uses coherent laser light of intensity 
, then the electron count distribution is Poisson:
ℬ = TransformedDistribution[λ x, xBernoulliDistribution[1]];PDF[ℬ, x]//Refine[#, λ > 0]&𝒟1 = ParameterMixtureDistribution[PoissonDistribution[μ], μℬ];PDF[𝒟1, x]Which is PoissonDistribution:
PDF[PoissonDistribution[λ], x]If the source uses thermal illumination, then the Poisson parameter follows ExponentialDistribution with parameter 
and the electron count distribution is:
𝒟2 = ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ]]These two distributions are distinguishable and allow you to determine the type of source:
Block[{λ = 3}, Histogram[{RandomVariate[𝒟1, 10 ^ 3], RandomVariate[𝒟2, 10 ^ 3]}, {1}, "PDF"]]Properties & Relations (11)
The sum of Poisson variables is Poisson distributed:
TransformedDistribution[u + v, {uPoissonDistribution[Subscript[λ, 1]], vPoissonDistribution[Subscript[λ, 2]]}]Relationships to other distributions:
PoissonDistribution is a limiting case for BinomialDistribution with 
:
PDF[BinomialDistribution[n, μ / n], k]Limit[%, n -> ∞]FullSimplify[% - PDF[PoissonDistribution[μ], k], k ≥ 0]PoissonConsulDistribution simplifies to Poisson distribution:
PDF[PoissonConsulDistribution[μ, 0], x]PDF[PoissonDistribution[μ], x]% - %%//SimplifyPoisson distribution is a limiting case for PolyaAeppliDistribution:
Limit[PDF[PolyaAeppliDistribution[θ, p], x], p -> 0, Assumptions -> θ > 0, Direction -> -1]PDF[PoissonDistribution[θ], x]FullSimplify[% - %%]NegativeBinomialDistribution is a mixture of PoissonDistribution and GammaDistribution:
ParameterMixtureDistribution[PoissonDistribution[μ], μGammaDistribution[n, (1 - p) / p]]GeometricDistribution is a mixture of PoissonDistribution and GammaDistribution:
ParameterMixtureDistribution[PoissonDistribution[μ], μGammaDistribution[1, (1 - p) / p]]The parametric mixture of Poisson distribution and ExponentialDistribution follows GeometricDistribution:
ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ]]PoissonConsulDistribution is a parameter mixture of BorelTannerDistribution and PoissonDistribution:
ParameterMixtureDistribution[BorelTannerDistribution[α, n],
n PoissonDistribution[μ]]The limit of NegativeBinomialDistribution when the mean is fixed is Poisson distribution:
Solve[λ == Mean[NegativeBinomialDistribution[n, p]], p]Limit[PDF[NegativeBinomialDistribution[n, n / (n + λ)], x], n -> ∞]PDF[PoissonDistribution[λ], x]FullSimplify[% - %%]For large μ, the PoissonDistribution can be approximated by NormalDistribution:
μ = 400;
DiscretePlot[PDF[PoissonDistribution[μ], k], {k, μ - 6Sqrt[μ], μ + 6Sqrt[μ]}]Show[%, Plot[PDF[NormalDistribution[μ, Sqrt[μ]], x], {x, μ - 6Sqrt[μ], μ + 6Sqrt[μ]}, PlotStyle -> Directive[Red, Dashed]]]Possible Issues (2)
PoissonDistribution is not defined when μ is non-positive:
Mean[PoissonDistribution[-1.5]]
Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:
Mean[PoissonDistribution[μ]] /. {μ -> -1}Text
Wolfram Research (2007), PoissonDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/PoissonDistribution.html.
CMS
Wolfram Language. 2007. "PoissonDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PoissonDistribution.html.
APA
Wolfram Language. (2007). PoissonDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PoissonDistribution.html