ImagePyramid
ImagePyramid[image]
creates a Gaussian image pyramid formed from image.
ImagePyramid[image,pyrtype]
returns a Gaussian or Laplacian pyramid depending of the specified pyrtype.
ImagePyramid[image,pyrtype,n]
returns up to n levels of the pyramid.
ImagePyramid[image,pyrtype,{size}]
returns pyramid levels down to image dimensions given by size.
ImagePyramid[image,pyrtype,n,s]
returns a pyramid with successive levels downsampled by factor s.
Details and Options
- Image pyramid is a multi-resolution representation of an image to facilitate efficient multiscale processing. Typical applications include noise removal, image blending, texture synthesis and efficient rendering.
- An image pyramid consists of several images with consecutively lower resolutions. Typically, specific levels of the pyramid are processed, and the result is reconstructed using the inverse process.
- ImagePyramid works with arbitrary 2D and 3D images.
- Use InverseImagePyramid to reconstruct the image from an image pyramid.
- The pyramid type pyrtype can be any of the following:
-
"Lowpass" or "Gaussian" iteratively blurs and downsamples "Bandpass" or "Laplacian" difference pyramid by upsampling and subtracting the lower levels from the upper levels {"Lowpass",ker} use ker for downsampling {"Bandpass",ker1,ker2} use ker1 for downsampling and ker2 for upsampling pyr use specifications of a reference pyramid pyr - Kernel specification ker can be given by an array or any valid setting for Resampling.
- By default, ImagePyramid[image] creates a Gaussian pyramid with all possible levels using a scaling factor of 2.
- Using pyr["Properties"], all available properties are returned.
- Using pyr["prop"], properties or content of the constructed image pyramid can be extracted.
- Available properties "prop" are:
-
levels extract images as specific levels "ImageDimensions" dimensions of the original image "LevelCount" the number of levels available "Levels" all images "LowpassKernel" lowpass kernel used when creating the pyramid "HighpassKernel" highpass kernel used when creating the pyramid "Padding" padding scheme used when creating the pyramid "ScalingFactor" the scaling factor used when creating the pyramid "Type" type of the pyramid, "Lowpass" or "Bandpass" - Level specification levels can take any of the following settings:
-
All all levels of the pyramid n the n 
level-n counts from the last level {n1,n2,…} a list of level indices m;;n levels m through n m;;n;;s levels m through n with step s - ImagePyramid preserves the image type when creating a lowpass pyramid and returns a pyramid of a real type when creating a bandpass pyramid.
- By default, a "Reversed" padding is used. Use the Padding option to specify other settings.
Examples
open all close allBasic Examples (2)
Scope (7)
Data (3)
Lowpass pyramid of a 2D image:
pd = ImagePyramid[[image]]pd[All]Dimensions are halved at each level:
pd["ImageDimensions"]Lowpass pyramid of a 3D image:
img = ExampleData[{"TestImage3D", "CTengine"}];pd = ImagePyramid[img]pd[All]pd["ImageDimensions"]Lowpass pyramid of a partially transparent image:
img = [image];ImageMeasurements[img, "Transparency"]ipd = ImagePyramid[img, "Gaussian", 4]ipd[All]Parameters (4)
The default lowpass kernel applied in each level before downsampling is the Gaussian kernel:
image = [image];pd = ImagePyramid[image, "Lowpass"];pd[All]pd["LowpassKernel"]Use a binomial kernel instead:
pd = ImagePyramid[image, {"Lowpass", {1, 4, 6, 4, 1} / 16}];pd["LowpassKernel"] //MatrixFormpd = ImagePyramid[image, {"Lowpass", {1, 1, 1} / 3}]pd["LowpassKernel"]//MatrixFormUse a Gaussian kernel with standard deviation σ equal to half the downsampling factor a:
a = 2;σ = a / 2;
pd = ImagePyramid[
image,
{"Lowpass", GaussianMatrix[{{Automatic}, σ}]},
∞,
a
]pd[All]pd["LowpassKernel"]//MatrixFormSpecify the number of levels to be returned:
pd = ImagePyramid[[image], "Lowpass", 4]pd[All]Specify an image size that is smaller than or equal to the smallest image in the pyramid:
pd = ImagePyramid[[image], "Lowpass", {50, 50}]This pyramid has two levels. The next pyramid level of size 50×38 would have been smaller than 50×50:
pd["ImageDimensions"]Specify a single number for the size:
ImagePyramid[[image], "Lowpass", {50}]The default downsampling factor between successive levels is 2:
image = [image];
pd = ImagePyramid[image]pd["ImageDimensions"]Specify a downsampling factor of 5:
pd = ImagePyramid[image, "Lowpass", ∞, 5]pd["ImageDimensions"]Options (1)
Padding (1)
The default padding is "Reversed":
image = [image];pd = ImagePyramid[image]pd[All]pd = ImagePyramid[image, Padding -> "Fixed"]pd[All]pd = ImagePyramid[image, Padding -> Red]pd[All]Applications (6)
Efficient Image Viewer (1)
Convert a large image into a pyramid for faster viewing:
img = ExampleData[{"TestImage", "Volubilis"}];pd = ImagePyramid[img, "Gaussian"]View the image with width 320:
ImageResize[InverseImagePyramid[pd, Automatic, {320}], {320}]Compare the timings for image retrieval:
ImageResize[InverseImagePyramid[pd, Automatic, {320}], 320];//RepeatedTimingImageResize[img, 320];//RepeatedTimingMultiscale Feature Detection (3)
Apply a gradient filter at several scales simultaneously:
img = [image];pyramid = ImagePyramid[img, "Gaussian", 4]pyramidG = ImagePyramidApply[img GradientFilter[img, 1.4], pyramid];Reconstruct assuming a Laplacian pyramid to add up features extracted from all levels:
InverseImagePyramid[pyramidG, "Laplacian"]//ImageAdjustAlter pyramid levels and type to detect mountain ridges at all scales:
img = [image];pyramid = ImagePyramid[img, "Gaussian", 5]ridgePyr = ImagePyramidApply[RidgeFilter, pyramid]Reconstruct assuming a Laplacian pyramid to add up features extracted from all levels:
InverseImagePyramid[ridgePyr, "Laplacian"]//ImageAdjustPerform a multiscale saliency filtering:
img = [image];Apply ImageSaliencyFilter to an image:
ImageSaliencyFilter[img]//ImageAdjustApply a saliency filter to all levels of the image pyramid to get a multiscale result:
pd = ImagePyramid[img, "Gaussian", 3];pdSaliency = ImagePyramidApply[ImageSaliencyFilter, pd];Use Laplacian reconstruction to add up filter responses at all levels:
InverseImagePyramid[pdSaliency, "Laplacian"]//ImageAdjustImage Effects (2)
pyr = ImagePyramid[[image], "Bandpass"]Extract, negate and reinsert the three bottom levels of the image pyramid:
pyr[1 ;; 3] = Map[-#&, pyr[1 ;; 3]]Reconstruct the image pyramid to exhibit the visual effect:
InverseImagePyramid[pyr]Merge two images at just one scale:
{apple, orange} = {[image], [image]};splitMerge[i1_Image, i2_Image] :=
With[{c = Floor[1 / 2 First@ImageDimensions[i1]]},
ImageAssemble[{{ImageTake[i1, All, {1, c}], ImageTake[i2, All, {c + 1, -1}]}}]]splitMerge[apple, orange]Merge the two images at all scales:
pyramids = Map[ImagePyramid[#, "Laplacian", {2, 2}]&, {apple, orange}];pFruit = ImagePyramidApply[splitMerge, pyramids]InverseImagePyramid[pFruit]Possible Issues (1)
Images with constant alpha-channel result in Laplacian image pyramids that appear to be empty:
img = [image];ImageMeasurements[img, "Transparency"]ipd = ImagePyramid[img, "Laplacian", 4];All pyramid levels except the last one will have an alpha channel equal to 0 and appear invisible:
ipd[All]The image reconstruction works, since the data in the color channel is present and the alpha channel of the fully opaque last level contributes to the correct alpha channel for the reconstructed image:
InverseImagePyramid[ipd]Text
Wolfram Research (2019), ImagePyramid, Wolfram Language function, https://reference.wolfram.com/language/ref/ImagePyramid.html.
CMS
Wolfram Language. 2019. "ImagePyramid." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ImagePyramid.html.
APA
Wolfram Language. (2019). ImagePyramid. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImagePyramid.html