OrderDistribution[{dist,n},k]
represents the k
-order statistics distribution for n observations from the distribution dist.
OrderDistribution[{dist,n},{k1,k2,…}]
represents the joint 
-order statistics distribution from n observations from the distribution dist.
OrderDistribution
OrderDistribution[{dist,n},k]
represents the k
-order statistics distribution for n observations from the distribution dist.
OrderDistribution[{dist,n},{k1,k2,…}]
represents the joint 
-order statistics distribution from n observations from the distribution dist.
OrderDistribution[{dist1,…,distn},…]
represents the order statistics distribution for independent distributions disti.
OrderDistribution[mdist,…]
represents the order statistics distribution for multivariate distribution mdist.
Details
- OrderDistribution[{dist,n},k] represents the distribution of the k
element in the sorted list of n samples drawn from the parent distribution dist. - The argument distribution specification is the same as in ProductDistribution. It represents a multivariate distribution and needs to be either continuous or discrete in all variables.
- OrderDistribution[dists,1] represents the distribution of Min[x1,…,xn], where {x1,…,xn} has distribution ProductDistribution[dists].
- OrderDistribution[dists,k] represents the distribution of RankedMin[{x1,…,xn},k], where {x1,…,xn} has distribution ProductDistribution[dists].
- OrderDistribution can be used with such functions as Mean, CDF, and RandomVariate.
Examples
open all close allBasic Examples (3)
OrderDistribution[{UniformDistribution[], n}, k]OrderDistribution[{ExponentialDistribution[λ], n}, 1]Order distribution of a single order statistic behaves like any other univariate distribution:
𝒟 = OrderDistribution[{DiscreteUniformDistribution[{1, 10}], n}, n]PDF[𝒟, x]Block[{n = 3}, DiscretePlot[PDF[𝒟, x], {x, 0, 10}]]Joint order distribution of two or more order statistics works like any other multivariate distribution:
𝒟 = OrderDistribution[{UniformDistribution[], n}, {i, j}]PDF[𝒟, {x, y}]Block[{n = 5, i = 2, j = 4}, Plot3D[%, {x, 0, 1}, {y, 0, 1}]]Scope (35)
Basic Uses (6)
Compare the distribution of minimum and maximum from a normal sample:
𝒟min = OrderDistribution[{NormalDistribution[], 10}, 1];
𝒟max = OrderDistribution[{NormalDistribution[], 10}, 10];Plot[{Legended[PDF[𝒟min, x], "𝒟min"], Legended[PDF[𝒟max, x], "𝒟max"]}, {x, -4, 4}, Filling -> Axis]Find the distribution of the k
-order statistics in a normal sample of 10 elements:
𝒟[k_] = OrderDistribution[{NormalDistribution[], 10}, k];Find probability density function:
pdf[k_] = PDF[𝒟[k], x]Plot the PDF of the smallest, the seventh smallest, and the largest variable:
Plot[{Legended[pdf[1], "min"], Legended[pdf[7], "7th"], Legended[pdf[10], "max"]}, {x, -3, 3}, Filling -> Axis, PlotStyle -> {Automatic, Automatic, Automatic}]quantile[k_] = Quantile[𝒟[k], q]Plot[{Legended[quantile[1], "min"], Legended[quantile[7], "k==7"], Legended[quantile[10], "max"]}, {q, 0, 1}, Filling -> Axis, PlotRange -> {-3, 3}, PlotStyle -> {Automatic, Automatic, Automatic}]Find the distribution of the maximum of 
independent discrete variables:
𝒟 = OrderDistribution[{PoissonDistribution[μ], n}, n]PDF[𝒟, x]Compare for different values of distribution parameter:
Block[{n = 10}, DiscretePlot[Evaluate[Table[Legended[PDF[𝒟, x], Row[{"μ", " = ", μ}]], {μ, {3, 5, 7}}]], {x, 1, 18}, PlotMarkers -> Automatic, Joined -> True, Filling -> None]]Find the median order statistic distribution:
𝒟 = OrderDistribution[{ExponentialDistribution[λ], 5}, 3];PDF[𝒟, x]Plot[Evaluate[Table[Legended[PDF[𝒟, x], Row[{"λ", " = ", λ}]], {λ, {0.3, 0.7, 1}}]], {x, 0, 5}, Filling -> Axis]{Mean[𝒟], Variance[𝒟]}Find the joint distribution of the smallest and the largest elements:
𝒟 = OrderDistribution[{BinomialDistribution[40, 1 / 6], 4}, {1, 4}];DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 8}, {y, 5, 15}, ExtentSize -> 1 / 2]data = RandomVariate[OrderDistribution[{NormalDistribution[], 10}, 4], 10 ^ 2];EstimatedDistribution[data, OrderDistribution[{NormalDistribution[], n}, 4]]Parametric Distributions (5)
Define the distribution of k
-order statistics of ExponentialDistribution:
𝒟 = OrderDistribution[{ExponentialDistribution[λ], n}, k];PDF[𝒟, x]Cumulative distribution function:
CDF[𝒟, x]Block[{n = 10, k = 3, λ = 2}, Table[Plot[fun[𝒟, x], {x, 0, 0.7}, Filling -> Axis, PlotLabel -> fun], {fun, {PDF, CDF, SurvivalFunction, HazardFunction}}]]Find the distribution of the maximum of a sample of a continuous distribution:
𝒟 = OrderDistribution[{WeibullDistribution[3, 2], n}, n];Find the probability density function:
PDF[𝒟, x]Plot the PDF for different sample sizes:
Plot[Table[Legended[PDF[𝒟, x], Row[{"n", " = ", n}]], {n, {5, 10, 20}}]//Evaluate, {x, 1, 4.5}, Filling -> Axis]Find the distribution of the minimum in a sample from a discrete distribution:
𝒟 = OrderDistribution[{BenfordDistribution[b], n}, 1];sample = Block[{n = 4, b = 10}, RandomVariate[𝒟, 10 ^ 4]];Block[{n = 4, b = 10}, Show[Histogram[sample, {0.5, 5.5, 1}, "PDF"], DiscretePlot[PDF[𝒟, x], {x, 0, 10}, PlotStyle -> PointSize[Medium]]]]Find the k
-order statistics of BinomialDistribution:
𝒟 = OrderDistribution[{BinomialDistribution[100, 1 / 3], 10}, k];Find the probability density function:
PDF[𝒟, x]Plot the PDF for the minimum, maximum, and the 4
-order statistics:
DiscretePlot[Table[Legended[PDF[𝒟, x], Row[{"k", " = ", k}]], {k, {1, 4, 10}}]//Evaluate, {x, 20, 50}, PlotMarkers -> Automatic]Mean and variance for the 4
-order statistics:
Block[{k = 4}, {Mean[𝒟], Variance[𝒟]}]//NSkewness and kurtosis for the 4
-order statistics:
Block[{k = 4}, {Skewness[𝒟], Kurtosis[𝒟]}]//NFind the distribution of a maximum in a sample from SkellamDistribution:
𝒟 = OrderDistribution[{SkellamDistribution[20, 10], 20}, 20];DiscretePlot[PDF[𝒟, x], {x, 10, 30}]points = Table[N[CDF[𝒟, x]], {x, 10, 30, 2}];DiscretePlot[Quantile[𝒟, x], {x, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]Nonparametric Distributions (3)
Find the distribution of the maximum in a sample from a HistogramDistribution:
hd = HistogramDistribution[RandomVariate[BirnbaumSaundersDistribution[1 / 2, 3], 10 ^ 3]];
𝒟 = OrderDistribution[{hd, 10}, 10];Plot[PDF[𝒟, x], {x, 0.2, 1.5}, PlotRange -> All, Exclusions -> None, Filling -> Axis]Find the distribution of the k
-order statistics from a SmoothKernelDistribution:
skd = SmoothKernelDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]];
𝒟 = OrderDistribution[{skd, 5}, k];Compare the density functions for the minimum, the median, and the maximum:
Plot[Table[Legended[PDF[𝒟, x], Row[{"k", " = ", k}]], {k, {1, 3, 5}}]//Evaluate, {x, -3.5, 3.5}, PlotRange -> All, Exclusions -> None, Filling -> Axis]Find the distribution of the minimum in a sample from an EmpiricalDistribution:
ed = EmpiricalDistribution[RandomVariate[PoissonDistribution[9], 20]];
𝒟 = OrderDistribution[{ed, 3}, 1];Cumulative distribution function:
DiscretePlot[CDF[𝒟, x], {x, 0, 12}, ExtentSize -> Right]Derived Distributions (7)
Find the second largest order statistic from a TruncatedDistribution:
𝒫 = TruncatedDistribution[{-1, 2}, NormalDistribution[]];
𝒟 = OrderDistribution[{𝒫, 10}, 8];Cumulative distribution function:
CDF[𝒟, x]//FullSimplifyCompare the PDFs of the order distribution and the truncated normal distribution:
Plot[{Legended[Evaluate[PDF[𝒟, x]], "𝒟"], Legended[PDF[𝒫, x], "𝒫"]}, {x, -1.2, 2}, Filling -> Axis]Find the distribution of the maximum of the sample from a ParameterMixtureDistribution:
ℳ = ParameterMixtureDistribution[RayleighDistribution[σ], σHalfNormalDistribution[θ]];
𝒟 = OrderDistribution[{ℳ, 10}, 10];Compute probability density function:
PDF[𝒟, x]//FullSimplifyPlot the PDF for different values of the parameter of the weight distribution:
Plot[Evaluate[Table[Legended[PDF[𝒟, x], Row[{"θ", " = ", θ}]], {θ, {1 / 2, 1, 1.5}}]], {x, 0, 10}, Filling -> Axis]Find the distribution of the middle element from a sample of 9 from a MixtureDistribution:
ℳ = MixtureDistribution[{4, 3}, {NormalDistribution[], NormalDistribution[2, 1 / 2]}];
𝒟 = OrderDistribution[{ℳ, 9}, 5];Compare probability density functions of mixture distribution and order distribution:
Plot[{Legended[Evaluate[PDF[𝒟, x]], "𝒟"], Legended[PDF[ℳ, x], "ℳ"]}, {x, -2, 3.5}, Filling -> Axis]{Mean[ℳ//N], Mean[𝒟//N]}Find the distribution of a minimum from a TransformedDistribution:
𝒫 = TransformedDistribution[Log[u], uExponentialDistribution[1 / 10]];
𝒟 = OrderDistribution[{𝒫, 10}, 1];Plot[PDF[𝒟, x], {x, -3, 2}, Filling -> Axis]PDF[𝒟, x]Find the joined distribution of minimum and maximum from CensoredDistribution:
𝒞 = CensoredDistribution[{2, 10}, BinomialDistribution[20, 1 / 3]];
𝒟 = OrderDistribution[{𝒞, 4}, {1, 4}];DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 5, 15}, ExtentSize -> Full]Find the distribution of a maximum from a MarginalDistribution:
ℳ = MarginalDistribution[ProbabilityDistribution[6( x - y / 2) ^ 2, {x, 0, 1}, {y, 0, 1}], 2];
𝒟 = OrderDistribution[{ℳ, 3}, 3];Plot[Evaluate[PDF[𝒟, x]], {x, 0, 1}, Filling -> Axis, PlotRange -> All]PDF[𝒟, x]Order distribution from QuantityDistribution evaluates to QuantityDistribution:
OrderDistribution[{QuantityDistribution[ExponentialDistribution[1 / 5], "Seconds"], 10}, 3]Plot[PDF[%, Quantity[x, "Seconds"]]//Evaluate, {x, 0, 10}, AxesLabel -> {"s"}, Filling -> 0]Automatic Simplifications (14)
Continuous Distributions (13)
BetaDistribution is the order distribution for UniformDistribution:
OrderDistribution[{UniformDistribution[{0, 1}], n}, k]DagumDistribution is closed under Max:
OrderDistribution[{DagumDistribution[p, a, b], n}, n]ExponentialDistribution is closed under Min:
OrderDistribution[{ExponentialDistribution[λ], n}, 1]ExtremeValueDistribution is closed under Max:
OrderDistribution[{ExtremeValueDistribution[α, β], n}, n]FrechetDistribution is closed under Max:
OrderDistribution[{FrechetDistribution[α, β], n}, n]OrderDistribution[{FrechetDistribution[α, β, μ], n}, n]GompertzMakehamDistribution is closed under Min:
OrderDistribution[{GompertzMakehamDistribution[λ, ξ], n}, 1]OrderDistribution[{GompertzMakehamDistribution[λ, ξ, θ, α], n}, 1]GumbelDistribution is closed under Min:
OrderDistribution[{GumbelDistribution[α, β], n}, 1]MaxStableDistribution is closed under Max:
OrderDistribution[{MaxStableDistribution[μ, σ, ξ], n}, n]OrderDistribution[{MaxStableDistribution[μ, σ, 0], n}, n]MinStableDistribution is closed under Min:
OrderDistribution[{MinStableDistribution[μ, σ, ξ], n}, 1]OrderDistribution[{MinStableDistribution[μ, σ, 0], n}, 1]ParetoDistribution is closed under Min:
OrderDistribution[{ParetoDistribution[k, α], n}, 1]PowerDistribution is closed under Max:
n = 4;
OrderDistribution[Table[PowerDistribution[p, a[k]], {k, n}], n]SinghMaddalaDistribution is closed under Min:
OrderDistribution[{SinghMaddalaDistribution[q, a, b], n}, 1]WeibullDistribution is closed under Min:
OrderDistribution[{WeibullDistribution[α, β], n}, 1]OrderDistribution[{WeibullDistribution[α, β, μ], n}, 1]Discrete Distributions (1)
GeometricDistribution is closed under Min:
OrderDistribution[{GeometricDistribution[p], n}, 1]Generalizations & Extensions (2)
Probability that the smallest element of the multinomial random variable equals 1:
Probability[k == 1, kOrderDistribution[MultinomialDistribution[4, {(1/5), (1/5), (1/5), (2/5)}], 1]]Compute the mean of the largest of three independent exponential distributions:
Mean[OrderDistribution[{ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]}, 3]]//FullSimplifyApplications (8)
Four six-sided dice are rolled. Find the expectation of the minimum value:
Expectation[x, xOrderDistribution[{DiscreteUniformDistribution[{1, 6}], 4}, 1]]N[%]Find the expectation of the maximum value:
Expectation[x, xOrderDistribution[{DiscreteUniformDistribution[{1, 6}], 4}, 4]]N[%]Find the expectation of the sum of the three largest values. Using the identity 
and linearity of Expectation, you get:
Expectation[x1 + x2 + x3 + x4, {x1, x2, x3, x4}ProductDistribution[{DiscreteUniformDistribution[{1, 6}], 4}]] - Expectation[x, xOrderDistribution[{DiscreteUniformDistribution[{1, 6}], 4}, 1]]N[%]Find the probability that the most successful hedge‐fund manager among 25 non‐skilled managers outperforms the market nine out of 10 years, assuming their performances are independent from each other, and from year to year:
managerSuccessDist = BinomialDistribution[10, 1 / 2];NProbability[goodYears ≥ 9, goodYearsOrderDistribution[{managerSuccessDist, 25}, 25]]Compare to the probability that one a priori chosen manager performs this well:
NProbability[goodYears ≥ 9, goodYearsmanagerSuccessDist]A random sample of size 10 from a continuous distribution 
is sorted in ascending order. A new random variate is generated. Find the probability that the eleventh sample falls between the fourth and fifth smallest values in the sorted list:
𝒟 = UniformDistribution[];n = 10;k = 4;Probability[x < z < y, {z𝒟, {x, y}OrderDistribution[{𝒟, n}, {k, k + 1}]}]The probability equals 
and is independent of k:
Table[Probability[x < z < y, {z𝒟, {x, y}OrderDistribution[{𝒟, n}, {k, k + 1}]}], {k, 1, n - 1}]It is also independent of the distribution:
𝒟 = ExponentialDistribution[1];n = 6;Table[Probability[x < z < y, {z𝒟, {x, y}OrderDistribution[{𝒟, n}, {k, k + 1}]}], {k, 1, n - 1}]Compute a sample median expectation for ExponentialDistribution:
mOdd = Expectation[x, xOrderDistribution[{ExponentialDistribution[1], 2n + 1}, n + 1]]mEven = Expectation[(x + y) / 2, {x, y}OrderDistribution[{ExponentialDistribution[1], 2n}, {n, n + 1}]]//FullSimplify
Series[mEven, {n, Infinity, 4}]Series[mOdd, {n, Infinity, 4}]Compare with the population median:
Median[ExponentialDistribution[1]]Find the distribution of range in the size 
sample from an ExponentialDistribution:
cdf = Probability[max - min < z, {min, max}OrderDistribution[{ExponentialDistribution[λ], n}, {1, n}], Assumptions -> n > 1]dist[λ_, n_] = ProbabilityDistribution[{"CDF", cdf}, {z, 0, ∞}, Assumptions -> n > 1];Find the probability density function:
pdf = PDF[dist[λ, n], z]Compare it to the histogram, assuming a sample size of 6:
Show[
Histogram[Max[#] - Min[#]& /@ RandomVariate[ExponentialDistribution[1], {10 ^ 4, 6}], 25, "PDF"],
Plot[PDF[dist[1, 6], z], {z, 0, 10}, PlotStyle -> Thick]]A new realization of random variate from ErlangDistribution is generated every minute. A record is said to occur if the value generated is larger than any prior realizations. Find the distribution of the value of the second record:
𝒟 = ErlangDistribution[k, β];The first record necessarily occurs in the first minute. Given that the second record occurs on the 
minute, its probability density is given by:
condpdf[n_, x_] = PDF[OrderDistribution[{𝒟, n}, n], x]The probability for the second record to occur on the 
minute is equal to the number of permutations with the first and last elements fixed and divided by the total number of permutations:
pr[n_] := (n - 2)! / n!The density of interest is obtained by summing over 
:
pdf[k_, β_, x_] = Sum[condpdf[n, x]pr[n], {n, 2, ∞}]
Integrate[pdf[2, 1, x], {x, 0, ∞}]Compare the PDF of the second record with the PDF of the Erlang random variate:
Plot[{Legended[pdf[2, 1, x], "pdf[x]"], Legended[PDF[𝒟 /. {k -> 2, β -> 1}, x], "PDF[𝒟, x]"]}, {x, 0, 10}, Filling -> Axis]Find the mean and standard deviation of the second record value:
Mean[ProbabilityDistribution[pdf[2, 1, x], {x, 0, ∞}]]StandardDeviation[ProbabilityDistribution[pdf[2, 1, x], {x, 0, ∞}]]Find the distribution of the largest element in a standard normal sample of size 
, where 
itself is a random number from a shifted GeometricDistribution with 
:
𝒟 = ParameterMixtureDistribution[OrderDistribution[{NormalDistribution[], n + 1}, n + 1], nGeometricDistribution[1 / 4]];Find the probability density function:
pdf = PDF[𝒟, x]Generate random numbers following this distribution:
data = RandomVariate[𝒟, 10 ^ 4];Plot the density and compare it with the histogram:
Show[Histogram[data, 25, "PDF"], Plot[pdf, {x, -4, 4}, PlotStyle -> Thick]]Approximate the mean of the distribution:
NExpectation[x, x𝒟]Compare it with the sample mean:
Mean[data]A system is composed of three identical elements defined by the lifetime distribution. The system is said to have failed when two out of three components are down. Find the lifetime distribution of this system:
componentLifetime = WeibullDistribution[2, Quantity[3, "Years"]];
systemLifetime = OrderDistribution[{componentLifetime, 3}, 2];Compare the density function of the system with the density function of a component:
Plot[{PDF[componentLifetime, Quantity[x, "Years"]], PDF[systemLifetime, Quantity[x, "Years"]]}, {x, 0, 8}, Filling -> Axis, PlotLegends -> {"Component Lifetime", "System Lifetime"}, AxesLabel -> {"yr"}]Find the mean lifetime of such a system:
Mean[systemLifetime]//NMedian[systemLifetime]N[%]Properties & Relations (3)
OrderDistribution is the distribution of the RankedMin of a random sample:
𝒹 = GammaDistribution[2, 3];
data = RandomVariate[ProductDistribution[{𝒹, 10}], 10 ^ 3];
𝒟 = OrderDistribution[{𝒹, 10}, 2];Compare the histogram of the data with the PDF of the corresponding order distribution:
Show[Histogram[RankedMin[#, 2]& /@ data, Automatic, "PDF"], Plot[PDF[𝒟, x], {x, 0, 6}, PlotStyle -> Thick]]OrderDistribution is a special case of TransformedDistribution:
Table[PDF[OrderDistribution[{NormalDistribution[], 3}, k], w], {k, 3}]Table[PDF[TransformedDistribution[RankedMin[{x, y, z}, k], {x, y, z}ProductDistribution[{NormalDistribution[], 3}]], w], {k, 3}]FullSimplify[%% - %]In particular, the extreme cases correspond to Min and Max:
{RankedMin[{x, y, z}, 1] - Min[x, y, z], RankedMin[{x, y, z}, 3] - Max[x, y, z]}//FullSimplifyExponentialDistribution is the limiting distribution of the 
where 
has a UniformDistribution:
mindist = OrderDistribution[{UniformDistribution[{0, 1}], n}, 1];CDF[mindist, x / n]Limit[CDF[mindist, x / n], n -> ∞]CDF[ExponentialDistribution[1], x]% - %%//FullSimplifyNeat Examples (1)
Table[Plot3D[PDF[OrderDistribution[{NormalDistribution[], 3}, k], {x, y}], {x, -3, 3}, {y, -3, 3}, Mesh -> None, PlotRange -> {0, 0.6}, PlotLabel -> k], {k, Subsets[Range[3], {2}]}]Table[Plot3D[PDF[OrderDistribution[{NormalDistribution[], 4}, k], {x, y}], {x, -3, 3}, {y, -3, 3}, Mesh -> None, PlotRange -> {0, 1}, PlotLabel -> k], {k, Subsets[Range[4], {2}]}]Text
Wolfram Research (2010), OrderDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/OrderDistribution.html (updated 2016).
CMS
Wolfram Language. 2010. "OrderDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/OrderDistribution.html.
APA
Wolfram Language. (2010). OrderDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/OrderDistribution.html