NormalDistribution
NormalDistribution[μ,σ]
represents a normal (Gaussian) distribution with mean μ and standard deviation σ.
represents a normal distribution with zero mean and unit standard deviation.
Details
- The probability density for value
in a normal distribution is proportional to 
. » - NormalDistribution allows μ to be any real number and σ to be any positive real number.
- NormalDistribution allows μ and σ to be any quantities of the same unit dimensions. »
- NormalDistribution can be used with such functions as Mean, CDF, and RandomVariate. »
Background & Context
- NormalDistribution[μ,σ] represents the so-called "normal" statistical distribution that is defined over the real numbers. The distribution is parametrized by a real number μ and a positive real number σ, where μ is the mean of the distribution, σ is known as the standard deviation, and σ2 is known as the variance. The probability density function (PDF) of a normal distribution is unimodal, with the peak occurring at the mean
, and the parameter σ determines both the height of the PDF and the "thickness" of its tails. The PDF of a normal distribution is symmetric about its maximum, and the tails of its PDF are "thin" in the sense that the PDF decreases exponentially for large values of 
. (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.) The zero-argument form NormalDistribution[] is equivalent to NormalDistribution[0,1] and is sometimes called the standard normal distribution. - Due to the presence of the Gaussian function
in its PDF, a normal distribution is sometimes referred to as a Gaussian distribution. Informally, a normal distribution may also be referred to as a "bell curve" as a result of the bell-like shape of its PDF. However, it should be noted that other distributions such as CauchyDistribution, StudentTDistribution, and LogisticDistribution also display qualitatively similar "bell" shapes. - Random variables that are normally distributed are sometimes called normal variates, and the standard normal distribution may also be referred to as the unit normal distribution.
- Normal distributions are among the most widely occurring probability distributions and thus have many applications. For example, normally distributed values are of fundamental importance in applications of the Monte Carlo method. In addition, the normal distribution is also fundamental in defining the so-called Wiener process, a continuous-time stochastic process
consisting of independent increments 
, each of which is independent and identically normally distributed with 
and 
for 
. Moreover, a number of probabilistic and statistical values including percentile ranks and 
- and 
-scores are derived from normal distributions. Furthermore, because of the central limit theorem, the mean of a sufficiently large number of independent random variables will be approximately normally distributed provided certain hypotheses are satisfied, regardless of the original distributions describing the variables. The normal distribution also arises naturally when modeling a number of physical phenomena, such as the velocity of ideal gas molecules, the positions of particles experiencing diffusion, and the long-timescale behavior of thermal light. In addition, a large number of biological phenomena, including sizes of living tissue and quantities such as fasting blood glucose level and blood pressure, yield variables whose logarithms tend to be normally distributed. - RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a normal distribution. Distributed[x,NormalDistribution[μ,σ]], written more concisely as xNormalDistribution[μ,σ], can be used to assert that a random variable x is distributed according to a normal distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
- The probability density and cumulative distribution functions may be given using PDF[NormalDistribution[μ,σ],x] and CDF[NormalDistribution[μ,σ],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
- DistributionFitTest can be used to test if a given dataset is consistent with a normal distribution, EstimatedDistribution to estimate a normal parametric distribution from given data, and FindDistributionParameters to fit data to a normal distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic normal distribution, and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic normal distribution.
- TransformedDistribution can be used to represent a transformed normal distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a normal distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving normal distributions.
- NormalDistribution is closely related to a number of other distributions. A number of distributions, including LogNormalDistribution, HalfNormalDistribution, NoncentralChiSquareDistribution, and LevyDistribution, can be viewed as transformed versions of NormalDistribution, while NormalDistribution can also be considered a limiting case of a number of distributions, including HyperbolicDistribution, StudentTDistribution, PoissonDistribution, and BinomialDistribution. In addition, NormalDistribution is a special case of ExponentialPowerDistribution (PDF[NormalDistribution[μ,σ],x] is the same as PDF[ExponentialPowerDistribution[2,μ,σ],x]), SkewNormalDistribution (PDF[NormalDistribution[μ,σ],x] is the same as PDF[SkewNormalDistribution[μ,σ,0],x]), and PearsonDistribution (PDF[NormalDistribution[μ,σ],x] is the same as PDF[PearsonDistribution[3,σ-2,-μ σ-2,0,0,1],x] when σ>0) and is the marginal distribution of BinormalDistribution and MultinormalDistribution. NormalDistribution is also closely related to StableDistribution, RiceDistribution, RayleighDistribution, MaxwellDistribution, LevyDistribution, LaplaceDistribution, JohnsonDistribution, ChiDistribution, and ChiSquareDistribution.
Examples
open all close allBasic Examples (4)
Plot[Table[PDF[NormalDistribution[0, σ], x], {σ, {.75, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]Plot[Table[PDF[NormalDistribution[μ, 1.5], x], {μ, {-1, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]PDF[NormalDistribution[μ, σ], x]Cumulative distribution function:
Plot[Table[CDF[NormalDistribution[0, σ], x], {σ, {.75, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]Plot[Table[CDF[NormalDistribution[μ, 1.5], x], {μ, {-1, 1, 2}}]//Evaluate, {x, -6, 6}, Filling -> Axis]CDF[NormalDistribution[μ, σ], x]Mean[NormalDistribution[μ, σ]]Variance[NormalDistribution[μ, σ]]Median[NormalDistribution[μ, σ]]Scope (7)
Generate a sample of pseudorandom numbers from a normal distribution:
data = RandomVariate[NormalDistribution[1, 3], 10 ^ 4];Compare its histogram to the PDF:
Show[
Histogram[data, 20, "PDF"],
Plot[PDF[NormalDistribution[1, 3], x], {x, -9, 9}, PlotStyle -> Thick]]Distribution parameters estimation:
sample = RandomVariate[NormalDistribution[2, 3], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, NormalDistribution[μ, σ]]Compare the density histogram of the sample with the PDF of the estimated distribution:
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, -6, 11}, PlotStyle -> Thick]]Skewness and kurtosis are constant:
Skewness[NormalDistribution[μ, σ]]Kurtosis[NormalDistribution[μ, σ]]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[NormalDistribution[μ, σ], k]//Expand, {k, 5}], M]Closed form for symbolic order:
Moment[NormalDistribution[μ, σ], r]FormulaGrid[Table[CentralMoment[NormalDistribution[μ, σ], k], {k, 5}], CM]Closed form for symbolic order:
CentralMoment[NormalDistribution[μ, σ], r]FormulaGrid[Table[FactorialMoment[NormalDistribution[μ, σ], k]//Expand, {k, 5}], FM]FormulaGrid[Table[Cumulant[NormalDistribution[μ, σ], k], {k, 5}], C]Closed form for symbolic order:
Cumulant[NormalDistribution[μ, σ], r]Hazard function of a normal distribution is increasing:
Plot[Table[HazardFunction[NormalDistribution[-1, σ], x], {σ, {2, 3, 4}}]//Evaluate, {x, -8, -2}, Filling -> Axis]Plot[Table[HazardFunction[NormalDistribution[μ, 2], x], {μ, {-2, 0, 1}}]//Evaluate, {x, -4, 4}, Filling -> Axis]HazardFunction[NormalDistribution[μ, σ], x]Plot[Table[Quantile[NormalDistribution[-2, σ], q], {σ, {1 / 2, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Median[NormalDistribution[-2, σ]]]Plot[Table[Quantile[NormalDistribution[μ, 2], q], {μ, {-1, 1, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[NormalDistribution[μ, σ], q]Consistent use of Quantity in parameters yields QuantityDistribution:
height𝒟 = NormalDistribution[Quantity[MixedMagnitude[{5, 9}], MixedUnit[{"Feet", "Inches"}]], Quantity[5., "Inches"]]Quartiles[%]Applications (11)
Find the percentage of values that lie between 
and 
:
Probability[μ - σ < x < μ + σ, x NormalDistribution[μ, σ]]
Probability[μ - 2 σ < x < μ + 2σ, x NormalDistribution[μ, σ]]
Probability[μ - 3 σ < x < μ + 3σ, x NormalDistribution[μ, σ]]percentage[n_] := Probability[μ - n σ < x < μ + n σ, x NormalDistribution[μ, σ]]Table[N[percentage[n], 10], {n, 6}]Compute 
‐values for a 
‐test under the null hypothesis 
and the alternative 
:
CDF[NormalDistribution[], z]
1 - CDF[NormalDistribution[], z]
2 CDF[NormalDistribution[], -Abs[z]]A battery has a lifetime that is approximately normally distributed with a mean of 1000 hours and a standard deviation of 50 hours. Find the fraction with a lifetime between 800 and 1000 hours:
p = Probability[Quantity[800, "Hours"] < x < Quantity[1000, "Hours"], xNormalDistribution[Quantity[1000, "Hours"], Quantity[50, "Hours"]]]Out of 100 batteries, compute how many have a lifetime between 800 and 1000 hours:
Mean[BinomialDistribution[100, p]]N[%]Coffee beans are sold in 5 lb sacks that have true weight normally distributed with a mean of 5 lbs and a variance of 0.01 lb
. Find the probability that a given sack weighs at least 4 lbs, 15 oz:
Probability[x > Quantity[MixedMagnitude[{4, 15}], MixedUnit[{"Pounds", "Ounces"}]], xNormalDistribution[Quantity[5, "Pounds"], Sqrt[Quantity[0.01, "Pounds"^2]]]]This can be directly computed from the SurvivalFunction:
SurvivalFunction[NormalDistribution[Quantity[5, "Pounds"], Sqrt[Quantity[0.01, "Pounds"^2]]], Quantity[MixedMagnitude[{4, 15}], MixedUnit[{"Pounds", "Ounces"}]]]A company manufactures nails with length normally distributed, mean 0.497 inches, and standard deviation 0.002 inches. Find the fraction that satisfies the specification of length equal to 0.5 inches plus/minus 0.004 inches:
len𝒟 = NormalDistribution[["0.497 in"], ["0.002 in"]]minlen = [".5 in"] - ["0.004 in"];maxlen = [".5 in"] + ["0.004 in"];Probability[minlen < len < maxlen, len len𝒟]Direct computation with CDF:
CDF[ len𝒟, maxlen] - CDF[ len𝒟, minlen]A company manufactures nails with length normally distributed and a mean of 0.5 inches. If 50% of the produced nails have lengths between 0.495 and 0.505, find the standard deviation:
Probability[Quantity[0.495, "Inches"] < x < Quantity[0.505, "Inches"], xNormalDistribution[Quantity[0.5, "Inches"], Quantity[σ, "Inches"]], Assumptions -> σ > 0]FindRoot[% == 0.5, {σ, 1.5}]A sample is selected from a distribution with mean 5 and standard deviation 1.5. Find the minimum size 
of the sample so that with probability 0.97 the sample mean is within 0.8 of the distribution mean:
prob = Probability[-0.8 + 5 < m < 0.8 + 5, mNormalDistribution[5, 1.5 / Sqrt[n]]]The probability as a function of sample size:
DiscretePlot[prob, {n, 1, 30}]Find the minimum sample size 
:
NMinimize[{n, prob ≥ 0.97}, {n, 12, 25}]The weight of a person, including luggage, has normal distribution with mean 225 lbs and standard deviation 50 lbs. A plane's load limit is 10000 lbs and it can take 44 passengers. With the maximum number of passengers on board, find the probability of the plane being overloaded:
totalWeightDist = TransformedDistribution[Subsuperscript[∑, k = 1, 44]Subscript[x, k], Table[Subscript[x, k]NormalDistribution[Quantity[225, "Pounds"], Quantity[50, "Pounds"]], {k, 44}]]Probability[x > Quantity[10000, "Pounds"], xtotalWeightDist]N[%]Normally distributed points in the plane:
Graphics[{AbsolutePointSize[1], Point[RandomVariate[NormalDistribution[], {10 ^ 4, 2}]]}]Normally distributed points in 3D:
Graphics3D[{AbsolutePointSize[1], Point[RandomVariate[NormalDistribution[], {10 ^ 4, 3}]]}]Normal distribution was traditionally used to analyze the fractional stock price changes from the previous closing price. Find the estimated distribution for the daily fractional price changes of the S&P 500 index from January 1, 2000, to January 1, 2009:
sp500 = FinancialData["SP500", "FractionalChange",
{{2000, 1, 1}, {2009, 1, 1}, "Day"}]The range of fractional prices falls within the range of the normal distribution:
MinMax[sp500]edist = EstimatedDistribution[sp500, NormalDistribution[μ, σ]]Compare the histogram of the data with the PDF of the estimated distribution:
hist = Histogram[sp500, Automatic, "PDF"];
Show[hist, Plot[PDF[edist, Quantity[x, "%"]], {x, -10, 12}, PlotStyle -> Thick, PlotRange -> All]]Find the probability of the fractional price change being greater than 0.5%:
NProbability[x > 0.5, xedist]Find the mean fractional price change:
Mean[edist]Simulate fractional price changes for 30 days:
ListLinePlot[RandomVariate[edist, 30], AxesLabel -> Automatic]Show that using LogisticDistribution provides better fit than using normal distribution:
LogisticEstimate = EstimatedDistribution[sp500, LogisticDistribution[μ, β]]Show[hist, Plot[{PDF[edist, Quantity[x, "%"]], PDF[LogisticEstimate, Quantity[x, "%"]]}, {x, -10, 12}, PlotStyle -> Thick, PlotRange -> All, PlotLegends -> {"Fit with normal distribution", "Fit with logistic distribution"}]]Generate Gaussian white noise:
𝒫 = WhiteNoiseProcess[]data = RandomFunction[𝒫, {0, 40}];ListPlot[data, Filling -> Axis]Properties & Relations (36)
Normal distribution is closed under translation and scaling:
TransformedDistribution[a z + b, zNormalDistribution[μ, σ]]In general, affine transformations of independent normals are normal:
TransformedDistribution[a1 z1 + a2 z2 + c, {z1NormalDistribution[μ1, σ1], z2NormalDistribution[μ2, σ2]}]Normal distribution is closed under addition:
TransformedDistribution[x + y, {xNormalDistribution[Subscript[μ, 1], Subscript[σ, 1]], yNormalDistribution[Subscript[μ, 2], Subscript[σ, 2]]}]The normal distribution is symmetric about its mean:
Probability[u < -x + Mean[NormalDistribution[μ, σ]], uNormalDistribution[μ, σ]]Probability[u > x + Mean[NormalDistribution[μ, σ]], uNormalDistribution[μ, σ]]% - %%Parameter mixture of a normal distribution with a normal distribution is again a normal distribution:
ParameterMixtureDistribution[NormalDistribution[p, Subscript[σ, 1]], pNormalDistribution[μ, Subscript[σ, 2]]]Relationships to other distributions:
Normal (SN) JohnsonDistribution is a normal distribution:
PDF[JohnsonDistribution["SN", μ, σ, γ, δ], x]PDF[NormalDistribution[γ - μ δ / σ, δ / σ], x]% - %%//FullSimplify[#, σ > 0 && δ > 0]&StudentTDistribution goes to a normal distribution as 
goes to 
:
Limit[PDF[StudentTDistribution[ν], x], ν -> ∞]PDF[NormalDistribution[0, 1], x]% - %%Normal distribution is a transformation of LogNormalDistribution:
TransformedDistribution[Log[u], uLogNormalDistribution[μ, σ]]The inverse transformation of normal distribution yields LogNormalDistribution:
TransformedDistribution[Exp[u], uNormalDistribution[μ, σ]]HalfNormalDistribution is a truncated normal distribution:
PDF[HalfNormalDistribution[θ], x]PDF[TruncatedDistribution[{0, ∞}, NormalDistribution[0, 1 / (θSqrt[2 / π])]], x]FullSimplify[%% - %]The normal and half-normal distributions:
Block[{θ = 1}, Plot[{Legended[PDF[NormalDistribution[0, 1 / (θSqrt[2 / π])], x], "normal"], Legended[PDF[HalfNormalDistribution[θ], x], "half-normal"]}, {x, -3, 3}, Filling -> Axis]]HalfNormalDistribution is a transformation of normal distribution:
TransformedDistribution[Abs[x], xNormalDistribution[0, Sqrt[π / 2] / θ]]HalfNormalDistribution is a transformation of normal distribution:
TransformedDistribution[Abs[x - μ], xNormalDistribution[μ, Sqrt[π / 2] / θ]]NormalDistribution is a special case of ExponentialPowerDistribution:
PDF[ExponentialPowerDistribution[2, μ, σ], x]PDF[NormalDistribution[μ, σ], x]% - %%//FullSimplifyNormal distribution is a special case of SkewNormalDistribution with shape parameter 
:
PDF[SkewNormalDistribution[0, σ, 0], x]PDF[NormalDistribution[0, σ], x]% - %%SkewNormalDistribution is a transformation of normal distribution:
TransformedDistribution[α Abs[u] + v, {u, v}ProductDistribution[{NormalDistribution[0, σ / Sqrt[1 + α ^ 2] ], 2}]]Sum of squares of 
standard normally distributed variables follows ChiSquareDistribution:
𝒟 = TransformedDistribution[x ^ 2 + y ^ 2 + w ^ 2 + z ^ 2, {x, y, w, z}ProductDistribution[{NormalDistribution[], 4}]]Sum of squares of normally distributed variables has NoncentralChiSquareDistribution:
TransformedDistribution[u ^ 2 + v ^ 2 + w ^ 2, {uNormalDistribution[μ1, 1], vNormalDistribution[μ2, 1], wNormalDistribution[μ3, 1]}]The norm of 
standard normally distributed variables follows ChiDistribution:
TransformedDistribution[Norm[{x, y, w, z}], {x, y, w, z}ProductDistribution[{NormalDistribution[], 4}]]The norm of three standard normal variables has MaxwellDistribution, a case of ChiDistribution:
𝒟 = TransformedDistribution[Norm[{x, y, z}], {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]PDF[𝒟, x]PDF[MaxwellDistribution[1], x]% - %%The norm of two standard normally distributed variables follows RayleighDistribution:
TransformedDistribution[Norm[{x, y}], {x, y}ProductDistribution[{NormalDistribution[], 2}]]The norm of two normally distributed variables follows RiceDistribution:
𝒟 = TransformedDistribution[Norm[{u, v}], {u, v}ProductDistribution[{NormalDistribution[α / Sqrt[2], β], 2}]];Block[{α = .3, β = 2}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[RiceDistribution[α , β], x], {x, 0, 12}, PlotStyle -> Thick]]]NormalDistribution is the limiting case of HyperbolicDistribution of 
for 
and 
:
Limit[With[{β = 0, δ = σ^2α}, PDF[HyperbolicDistribution[λ, α, β, δ, μ], x]], α -> Infinity, Assumptions -> σ > 0 && {λ, μ, x}∈Reals]PDF[NormalDistribution[μ, σ], x]% - %%If 
, 
, 
, and 
are independent and normal, then 
has LaplaceDistribution:
𝒟 = TransformedDistribution[x y + u v, {x, y, u, v}ProductDistribution[{NormalDistribution[], 4}]];Show[Histogram[RandomVariate[𝒟, 10 ^ 4], {-5, 5, 0.5}, "PDF"], Plot[PDF[TruncatedDistribution[{-5, 5}, LaplaceDistribution[0, 1]], x], {x, -6, 6}, PlotStyle -> Thick]]Confirm via equality of CharacteristicFunction:
CharacteristicFunction[𝒟, t] == CharacteristicFunction[LaplaceDistribution[], t]If 
, 
, 
, and 
are independent and normal, then 
has LaplaceDistribution:
𝒟 = TransformedDistribution[w z - u v, {w, z, u, v}ProductDistribution[{NormalDistribution[], 4}]];Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[LaplaceDistribution[0, 1], x], {x, -6, 6}, PlotRange -> All, PlotStyle -> Thick]]Confirm via equality of CharacteristicFunction:
CharacteristicFunction[𝒟, t] == CharacteristicFunction[LaplaceDistribution[], t]Ratio of two normally distributed variables has CauchyDistribution:
TransformedDistribution[u / v, {u, v}ProductDistribution[{NormalDistribution[], 2}]]Square of a normally distributed variable is a special case of GammaDistribution, and also of ChiSquareDistribution:
𝒟 = TransformedDistribution[u ^ 2, uNormalDistribution[]]PDF[𝒟, x]PDF[GammaDistribution[1 / 2, 2], x]Simplify[% - %%]LaplaceDistribution is a parameter mixture of a normal distribution with RayleighDistribution:
𝒟 = ParameterMixtureDistribution[NormalDistribution[μ, σ], σRayleighDistribution[ν]]StudentTDistribution is a parameter mixture of a normal distribution with GammaDistribution:
ParameterMixtureDistribution[NormalDistribution[μ, 1 / Sqrt[λ2]], λ2GammaDistribution[ν / 2, 2 / ν / σ^2], Assumptions -> σ > 0]LevyDistribution is a transformation of a normal distribution:
TransformedDistribution[(1/x^2), xNormalDistribution[]]TransformedDistribution[(x - μ) ^ -2, xNormalDistribution[μ, σ]]Normal distribution is a special case of type 3 PearsonDistribution:
PDF[PearsonDistribution[3, σ^-2, -μ σ^-2, 0, 0, 1], x]//FullSimplify[#, σ > 0]&PDF[NormalDistribution[μ, σ], x]% - %%Normal distribution is a StableDistribution:
PDF[NormalDistribution[μ, σ], x]PDF[StableDistribution[0, 2, 0, μ, σ / Sqrt[2]], x]% - %%//SimplifyNormal distribution is the marginal distribution of BinormalDistribution:
MarginalDistribution[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], 1]MarginalDistribution[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], 2]Normal distribution is the marginal distribution of MultinormalDistribution:
Σ = (| | | |
| --------- | --------- | --------- |
| σ1^2 | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2 | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2 |);MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 1]MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 2]MarginalDistribution[MultinormalDistribution[{μ1, μ2, μ3}, Σ], 3]NormalDistribution can be obtained from MultinormalDistribution:
Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};TransformedDistribution[u + v, {u, v}MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]StudentTDistribution can be obtained from NormalDistribution and ChiSquareDistribution:
𝒟 = TransformedDistribution[z Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];PDF[𝒟, x]//FullSimplify[#, ν > 0]&PDF[StudentTDistribution[ν], x]//FunctionExpand//PowerExpandFullSimplify[% - %%, x ≠ 0]NoncentralStudentTDistribution can be obtained from NormalDistribution and ChiSquareDistribution:
𝒟 = TransformedDistribution[(z + δ)Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];Block[{δ = 3, ν = 15}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[NoncentralStudentTDistribution[ν, δ], x], {x, -10, 10}, PlotStyle -> Thick]]]VarianceGammaDistribution can be obtained from GammaDistribution and normal distribution:
dist = TransformedDistribution[μ + β * v + Sqrt[v] * u, {uNormalDistribution[0, 1], vGammaDistribution[λ, 2 / (α - β) / (α + β)]}];MomentGeneratingFunction[dist, x]E^x μ(1 / (1 + (2 x β/-α^2 + β^2)) / (1 + (x^2/-α^2 + β (2 x + β))))^λ//SimplifyMomentGeneratingFunction[VarianceGammaDistribution[λ, α, β, μ], x]//Simplify%% / %//FullSimplify[#, λ > 0 && β > 0]&Possible Issues (2)
NormalDistribution is not defined when μ is not a real number:
Mean[NormalDistribution[3 + I, 6]]
NormalDistribution is not defined when σ is not a positive real number:
Mean[NormalDistribution[3, -6]]
Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:
Mean[NormalDistribution[μ, σ]] /. {μ -> I, σ -> -1}Neat Examples (1)
PDFs for different σ values with CDF contours:
cdf = Function[{x, σ}, Evaluate[CDF[NormalDistribution[0, σ], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[NormalDistribution[0, σ], x], {x, -5, 5}, {σ, 1, 5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All, Exclusions -> None], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
An Elementary Introduction to the Wolfram LanguageText
Wolfram Research (2007), NormalDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/NormalDistribution.html (updated 2016).
CMS
Wolfram Language. 2007. "NormalDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/NormalDistribution.html.
APA
Wolfram Language. (2007). NormalDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NormalDistribution.html