RandomImage
RandomImage[max]
gives an image with pseudorandom pixel values in the range 0 to max.
RandomImage[{min,max}]
generates pseudorandom pixel values in the range min to max.
RandomImage[dist]
generates pixel values using a symbolic distribution dist.
RandomImage[…,size]
generates a random image of the specified size.
RandomImage[…,size,"type"]
gives an image converted to the specified type.
Details and Options
- RandomImage gives an image where pixel values are drawn from a specified distribution. The pixel values are not correlated spatially.
- Random images can be used for creating synthetic noise images and image effects.
- RandomImage by default gives an image of a real type.
- RandomImage[] is equivalent to RandomImage[1,{150,150}].
- RandomImage[…] is equivalent to RandomImage[…,{150,150}].
- The size specification can be one of the following:
-
side 2D image of size {side,side} {width,height} 2D image size specification {width,depth,height} 3D image size specification - Possible settings for "type" include:
-
"Bit" integer 0 or 1 "Byte" integer 0 through 255 "Bit16" integer 0 through 65535 "Real32" single-precision real (32 bit) "Real64" double-precision real (64 bit) - RandomImage accepts all Image and Image3D options with the following additions and modifications:
-
ColorSpace Automatic generates an image of the specified color space Interleaving None whether to generate an interleaved image
Examples
open all close allBasic Examples (3)
Scope (8)
Distribution (5)
By default, pixel values range from 0 to 1:
RandomImage[]Specify a range of pixel values:
RandomImage[{.5, .8}]ImageHistogram[%]Generate an image from pseudorandom values in the range 0 to 
:
RandomImage[.3]ImageHistogram[%]A random image from a normal distribution:
RandomImage[NormalDistribution[.5, .1]]ImageHistogram[%]Generate a 4-channel image using some multivariate distribution:
RandomImage[MultinormalDistribution[{0, .1, .2, .3}, .02 * {{1, .2, 0, 0}, {.2, 1, .3, 0}, {0, .3, 1, 0}, {0, 0, 0, 1}}]]ImageHistogram[%, Appearance -> "Separated"]Size (2)
By default, a 
2D image is generated:
RandomImage[1]Specify the image dimensions for a square image:
RandomImage[1, 100]RandomImage[1, {200, 100}]Specify the 3D image dimensions:
RandomImage[1, {40, 30, 20}]Options (5)
ColorSpace (4)
By default, no explicit color space is assumed:
RandomImage[1]ImageColorSpace[%]RandomImage[1, ColorSpace -> "Grayscale"]ImageColorSpace[%]Generate a random "RGB" image:
RandomImage[1, ColorSpace -> "RGB"]Generate an "HSB" image using some univariate distribution:
RandomImage[UniformDistribution[{.2, .6}], ColorSpace -> "HSB"]Generate a "LAB" image using a multivariate uniform distribution with specific bounds:
RandomImage[UniformDistribution[{{0, 1}, {-1, 1}, {-1, 1}}], ColorSpace -> "LAB"]Applications (4)
i = [image];
ImageAdd[i, RandomImage[{-.1, .1}, ImageDimensions[i]]]i = [image];
ImageMultiply[i, RandomImage[{0.8, 1.2}, ImageDimensions[i]]]RandomImage[LaplaceDistribution[0, .2], {100, 100}]RGB image simulating salt-and-pepper noise using a heavy-tail distribution:
RandomImage[CauchyDistribution[0, .2], {100, 100}, ColorSpace -> "RGB"]Properties & Relations (7)
Generate an image with constant intensity:
RandomImage[EmpiricalDistribution[{.7}], {100, 100}]Use the specialized function ConstantImage instead:
ConstantImage[.7, {100, 100}]Generate the random data using RandomReal:
Image[RandomReal[1, {100, 100}]]Generate a random binary image using RandomInteger:
Image[RandomInteger[1, {100, 100}]]Generate the random data using RandomVariate:
Image[RandomVariate[NormalDistribution[.5, .1], {100, 100}]]In a uniformly random image, neighboring pixels are not correlated:
image = RandomImage[1]ImageHistogram[image]ImageCooccurrence[image, 32]//MatrixPlotAfter local filtering, pixel values drawn from the original distribution are spatially correlated:
imgcorr = HistogramTransform[GaussianFilter[image, 3], image]ImageCooccurrence[imgcorr, 32]//MatrixPlotCreate an image with pixels randomly chosen from a list of colors:
Image[RandomChoice[{Red, Green, Blue}, {10, 10}]]Create an image from colors randomly chosen from a convex hull defined by a list of colors:
Image[RandomPoint[ConvexHullMesh[List@@@{Red, Green, Blue, Orange}], {10, 10}]]Possible Issues (1)
Out-of-range pixel values are rendered as black or white:
RandomImage[{-10, 10}, {100, 100}]Use ImageAdjust to see the full range of values:
ImageAdjust[%]Neat Examples (1)
Show the effect of various types of noise: original image, Poisson noise, uniform noise, Gaussian noise, Laplacian noise, salt-and-pepper noise:
img = [image] ;
dims = ImageDimensions@img;
l = Flatten@ImagePartition[img, {First@dims / 6, Last@dims}];
ImageAssemble[ImagePad[#, {{1, 1}, {0, 0}}]& /@ Flatten[{First@l, ImageEffect[l[[2]], {"PoissonNoise", .5}], MapThread[ImageAdd[#1, RandomImage[#2, ImageDimensions@#1]]&, {l[[3 ;; ]], {UniformDistribution[{-.2, .2}], NormalDistribution[0, .1], LaplaceDistribution[0, .05], CauchyDistribution[0, .02]}}]}]]Text
Wolfram Research (2010), RandomImage, Wolfram Language function, https://reference.wolfram.com/language/ref/RandomImage.html (updated 2020).
CMS
Wolfram Language. 2010. "RandomImage." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/RandomImage.html.
APA
Wolfram Language. (2010). RandomImage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RandomImage.html