ChiSquareDistribution
represents a 
distribution with ν degrees of freedom.
Details
- The probability density for value
in a 
distribution is proportional to 
for 
, and is zero for 
. » - For integer ν, the
distribution with ν degrees of freedom gives the distribution of sums of squares of ν values independently sampled from a normal distribution. - ChiSquareDistribution allows ν to be any positive real number.
- ChiSquareDistribution allows ν to be a dimensionless quantity. »
- ChiSquareDistribution can be used with such functions as Mean, CDF, and RandomVariate. »
Background & Context
- ChiSquareDistribution[ν] represents a statistical distribution parametrized by a positive value ν indicating the degrees of freedom of the distribution. ν determines the general shape of the probability density function (PDF) of a chi-square distribution, and, depending on the values of ν, the PDF may be either monotonic decreasing or may have a single "peak" (i.e. a global maximum) with a potential singularity approaching the lower boundary of its domain.
- ChiSquareDistribution is the distribution followed by the square of a chi-distributed random variable. In other words, if
is a random variable and 
(where 
denotes "is distributed as"), then 
. The sum 
of a collection 
, 
, …, 
of identically normally distributed independent random variables is also chi-square distributed. The chi-square distribution can be used to quantify the goodness of fit between a theoretical or empirical model and a collection of samples. Specific applications include magnetic resonance imaging and the analysis of possible associations between disease exposure and transmission. - RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a chi-square distribution. Distributed[x,ChiSquareDistribution[ν]], written more concisely as xChiSquareDistribution[ν], can be used to assert that a random variable x is distributed according to a chi-square distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
- The probability density and cumulative distribution functions for chi-square distributions may be given using PDF[ChiSquareDistribution[ν],x] and CDF[ChiSquareDistribution[ν],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
- DistributionFitTest can be used to test if a given dataset is consistent with a chi-square distribution, EstimatedDistribution to estimate a chi-square parametric distribution from given data, and FindDistributionParameters to fit data to a chi-square distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic chi-square distribution and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic chi-square distribution.
- TransformedDistribution can be used to represent a transformed chi-square distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a chi-square distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving chi-square distributions.
- ChiSquareDistribution is closely related to a number of other distributions. For example, several distributions, including GammaDistribution, ExponentialDistribution, InverseChiSquareDistribution, UniformDistribution, and LaplaceDistribution, can be obtained by transformations of ChiSquareDistribution, while NormalDistribution and FRatioDistribution are limiting values for transformed versions of ChiSquareDistribution. Moreover, ChiSquareDistribution can be viewed as a special case of a number of other more general distributions, including RayleighDistribution, MaxwellDistribution, PearsonDistribution, and ParetoDistribution. ChiSquareDistribution is also closely related to BetaDistribution, StudentTDistribution, UniformDistribution, and NoncentralChiSquareDistribution.
Examples
open all close allBasic Examples (4)
Plot[Table[PDF[ChiSquareDistribution[ν], x], {ν, {0.5, 3, 5}}]//Evaluate, {x, 0, 6}, Filling -> Axis]PDF[ChiSquareDistribution[ν], x]Cumulative distribution function:
Plot[Table[CDF[ChiSquareDistribution[ν], x], {ν, {0.5, 3, 5}}]//Evaluate, {x, 0, 6}, Filling -> Axis]CDF[ChiSquareDistribution[ν], x]Mean[ChiSquareDistribution[ν]]Variance[ChiSquareDistribution[ν]]Median[ChiSquareDistribution[ν]]Scope (8)
Generate a sample of pseudorandom numbers from a 
distribution:
data = RandomVariate[ChiSquareDistribution[3], 10 ^ 4];Compare its histogram to the PDF:
Show[
Histogram[data, {0, 15, 1}, "PDF"],
Plot[PDF[ChiSquareDistribution[3], x], {x, 0, 15}, PlotStyle -> Thick]]Distribution parameters estimation:
sample = RandomVariate[ChiSquareDistribution[13], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, ChiSquareDistribution[ν]]Compare density histogram of the sample with the PDF of the estimated distribution:
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 30}, PlotStyle -> Thick]]Plot[Skewness[ChiSquareDistribution[ν]], {ν, 0, 10}]Skewness[ChiSquareDistribution[ν]]For a large number of degrees of freedom, the distribution becomes symmetric:
Limit[Skewness[ChiSquareDistribution[ν]], ν -> ∞]Plot[Kurtosis[ChiSquareDistribution[ν]], {ν, 0, 10}]Kurtosis[ChiSquareDistribution[ν]]The limiting value is the kurtosis of NormalDistribution:
Limit[Kurtosis[ChiSquareDistribution[ν]], ν -> ∞]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]FormulaGrid[Table[Moment[ChiSquareDistribution[ν], k]//Together, {k, 5}], M]Closed form for symbolic order:
Moment[ChiSquareDistribution[ν], r]FormulaGrid[Table[CentralMoment[ChiSquareDistribution[ν], k]//Together, {k, 5}], CM]Closed form for symbolic order:
CentralMoment[ChiSquareDistribution[ν], r]FormulaGrid[Table[FactorialMoment[ChiSquareDistribution[ν], k]//Together, {k, 5}], FM]FormulaGrid[Table[Cumulant[ChiSquareDistribution[ν], k], {k, 5}], C]Cumulant has closed form:
Cumulant[ChiSquareDistribution[ν], r]Plot[Table[HazardFunction[ChiSquareDistribution[ν], x], {ν, {3, 5, 7}}]//Evaluate, {x, 0, 4}, Filling -> Axis]HazardFunction[ChiSquareDistribution[ν], x]Plot[Table[Quantile[ChiSquareDistribution[ν], q], {ν, {5, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[ChiSquareDistribution[ν], q]Use dimensionless Quantity to specify the degree of freedom parameter ν:
ChiSquareDistribution[Quantity[2, "dozens"]]Applications (2)
ChiSquareDistribution is used in exact (small) sampling theory. Define 
statistics:
χSquare[data_, σ_] := Total[(data - Mean[data]) ^ 2] / σ ^ 2If data comes from a NormalDistribution, then 
statistics follow ChiSquareDistribution, even for data that is a sample of small size (less than 30):
With[{n = 10}, Show[Histogram[Table[χSquare[RandomVariate[NormalDistribution[], n], 1], {i, 10 ^ 3}], 20, "PDF"], Plot[PDF[ChiSquareDistribution[n - 1], x], {x, 0, 40}, PlotStyle -> Thick]]]The weight in grams of a particular boxed cereal product is known to follow a normal distribution. A quality assurance team samples 15 boxes at random and records their weights. Test the hypothesis that the standard deviation of the product weight is less than 36:
weights = Quantity[{367.9, 384.7, 353.8, 334.7, 450.9, 390.6, 422.6, 352.2, 330.9, 342.0, 388.9, 386.7, 374.2, 388.5, 382.2}, "Grams"];{Mean[weights], StandardDeviation[weights]}Under the null hypothesis of 
, the following statistic follows ChiSquareDistribution:
σ0 = Quantity[36, "Grams"];
χ2stat = (15 - 1)Variance[weights] / σ0^2The null hypothesis cannot be rejected at the 5% level:
χ2stat < InverseCDF[ChiSquareDistribution[14], 0.05]Assuming that the standard deviation of the product weight equals 32, compute the probability of rejecting the null hypothesis, also known as the power of the test, at the 5% level as a function of sample size:
powerFunc[σ1_, n_] := CDF[ChiSquareDistribution[n - 1], (σ0^2/σ1^2) InverseCDF[ChiSquareDistribution[n - 1], 0.05]]DiscretePlot[powerFunc[Quantity[32, "Grams"], n], {n, 15, 300}]Find the sample size required for the power of the test to be at least 80%:
Ceiling[n] /. FindRoot[powerFunc[Quantity[32, "Grams"], n] == 0.8, {n, 200, 300}]Properties & Relations (23)
ChiSquareDistribution[ν] converges to a normal distribution as ν->∞:
{μ, σ} = {Mean[ChiSquareDistribution[ν]], StandardDeviation[ChiSquareDistribution[ν]]}Table[Plot[{PDF[ChiSquareDistribution[ν], x], PDF[NormalDistribution[μ, σ], x]}, {x, μ - 2σ, μ + 2σ}, AxesOrigin -> {μ - 2σ - σ, 0}, Ticks -> {{{μ - 2σ, HoldForm[μ - 2σ]}, {μ, HoldForm[μ]}, {μ + 2σ, HoldForm[μ + 2σ]}}, Automatic}, PlotLabel -> ν], {ν, {5, 10, 25, 100}}]Sum of 
-distributed variables follows 
distribution:
TransformedDistribution[u + v, {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]Relationships to other distributions:
NoncentralChiSquareDistribution simplifies to 
distribution:
PDF[NoncentralChiSquareDistribution[ν, 0], x]PDF[ChiSquareDistribution[ν], x]% - %%
distribution is a limiting case of FRatioDistribution:
Limit[PDF[FRatioDistribution[1, m], x], m -> Infinity]PDF[ChiSquareDistribution[1], x]% - %%The ratio of two 
-distributed variables follows FRatioDistribution:
TransformedDistribution[(u / ν1) / (v / ν2), {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]Sum of squares of 
variables from NormalDistribution follows 
distribution:
𝒟 = TransformedDistribution[x ^ 2 + y ^ 2 + z ^ 2, {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]
distribution is a special case of GammaDistribution:
PDF[ChiSquareDistribution[ν], x]PDF[GammaDistribution[ν / 2, 2], x]% - %%Scaled 
distribution follows GammaDistribution:
TransformedDistribution[c * X, XChiSquareDistribution[a], Assumptions -> c > 0]The square root of a 
variable follows the ChiDistribution:
TransformedDistribution[Sqrt[u], uChiSquareDistribution[ν]]Square of RayleighDistribution with 
is a special case of 
distribution:
𝒟 = TransformedDistribution[u ^ 2, uRayleighDistribution[1]]PDF[𝒟, x]PDF[ChiSquareDistribution[2], x]Simplify[% - %%, x > 0]Square of MaxwellDistribution with 
is a special case of 
distribution:
𝒟 = TransformedDistribution[u ^ 2, uMaxwellDistribution[1]];PDF[𝒟, x]PDF[ChiSquareDistribution[3], x]FullSimplify[% - %%, x > 0]
distribution and InverseChiSquareDistribution have an inverse relationship:
TransformedDistribution[1 / u, uChiSquareDistribution[ν]]
distribution is a special case of type 3 PearsonDistribution:
PDF[PearsonDistribution[3, 1, -ν + 2, 0, 2, 0], x]//FullSimplifyPDF[ChiSquareDistribution[ν], x]% - %%A transformation of 
distribution yields BetaDistribution:
TransformedDistribution[u / (u + v), {uChiSquareDistribution[ν1], vChiSquareDistribution[ν2]}]
is a transformation of UniformDistribution:
𝒟 = TransformedDistribution[-2 Log[u], uUniformDistribution[{0, 1}]];PDF[𝒟, x]//FullSimplify[#, x∈Reals]&PDF[ChiSquareDistribution[2], x]FullSimplify[% - %%, x > 0]
distribution is a transformation of LaplaceDistribution:
𝒟 = TransformedDistribution[2 / β (Abs[u - μ] + Abs[v - μ] + Abs[w - μ]), {u, v, w}ProductDistribution[{LaplaceDistribution[μ, β], 3}]];CDF[𝒟, x]//Simplify[#, β > 0]&CDF[ChiSquareDistribution[6], x]//FunctionExpand//Simplify% - %%
𝒟1 = TransformedDistribution[2 / β Abs[z - μ], zLaplaceDistribution[μ, β]];CharacteristicFunction[𝒟1, t] ^ n//PowerExpandCharacteristicFunction[ChiSquareDistribution[2n], t]FullSimplify[% - %%, n∈Integers]
distribution is a transformation of ParetoDistribution:
𝒟 = TransformedDistribution[2 α Log[(u v w z) k ^ -4], {u, v, w, z}ProductDistribution[{ParetoDistribution[k, α], 4}]];Block[{α = 2, k = 3, n = 4}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[ChiSquareDistribution[2 n], x], {x, 0, 25}, PlotStyle -> Thick]]]
distribution is a transformation of ParetoDistribution:
𝒟 = TransformedDistribution[2 α Log[(u v w z) / (Min[{u, v, w, z}] ^ 4)], {u, v, w, z}ProductDistribution[{ParetoDistribution[k, α], 4}]];Block[{α = 2, k = 3, n = 4}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 30, "PDF"], Plot[PDF[ChiSquareDistribution[2 n - 2], x], {x, 0, 25}, PlotStyle -> Thick]]]StudentTDistribution is a transformation of 
distribution:
𝒟 = TransformedDistribution[1 / 2 Sqrt[ν](u - v) / Sqrt[u v ], {u, v}ProductDistribution[{ChiSquareDistribution[ν], 2}]];Block[{ν = 14}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], Automatic, "PDF"], Plot[PDF[StudentTDistribution[ν], x], {x, -4, 4}, PlotStyle -> Thick]]]StudentTDistribution can be obtained from ChiSquareDistribution and NormalDistribution:
𝒟 = TransformedDistribution[z Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];PDF[𝒟, x]//FullSimplify[#, ν > 0]&PDF[StudentTDistribution[ν], x]//FunctionExpand//PowerExpandFullSimplify[% - %%, x ≠ 0]NoncentralBetaDistribution can be obtained as a transformation of ChiSquareDistribution and NoncentralChiSquareDistribution:
TransformedDistribution[(x/x + y), {xNoncentralChiSquareDistribution[n, δ], yChiSquareDistribution[m]}]NoncentralStudentTDistribution can be obtained from NormalDistribution and ChiSquareDistribution:
𝒟 = TransformedDistribution[(z + δ)Sqrt[ν / w], {zNormalDistribution[], wChiSquareDistribution[ν]}];Block[{δ = 3, ν = 15}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[NoncentralStudentTDistribution[ν, δ], x], {x, -10, 10}, PlotStyle -> Thick]]]Possible Issues (2)
ChiSquareDistribution is not defined when ν is not a positive real number:
Mean[ChiSquareDistribution[-1]]
Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:
Mean[ChiSquareDistribution[ν]] /. {ν -> I}Neat Examples (1)
PDFs for different ν values with CDF contours:
cdf = Function[{x, ν}, Evaluate[CDF[ChiSquareDistribution[ν], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[ChiSquareDistribution[ν], x], {x, 0, 10}, {ν, 2, 6}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 35, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.5}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
An Elementary Introduction to the Wolfram LanguageText
Wolfram Research (2007), ChiSquareDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/ChiSquareDistribution.html (updated 2016).
CMS
Wolfram Language. 2007. "ChiSquareDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ChiSquareDistribution.html.
APA
Wolfram Language. (2007). ChiSquareDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChiSquareDistribution.html