Wolfram Language & System Documentation Center

PearsonDistribution

PearsonDistribution[a₁,a₀,b₂,b₁,b₀]

represents a distribution of the Pearson family with parameters a₁, a₀, b₂, b₁, and b₀.

PearsonDistribution[type,a₁,a₀,b₂,b₁,b₀]

represents a Pearson distribution of given type.

Details

The probability density satisfies the differential equation .
The Pearson family of distributions is historically divided into seven types. By giving the form PearsonDistribution[type,…], the type will implicitly provide domain and parameter constraints.
PearsonDistribution[1,…] is a shifted and rescaled BetaDistribution.
PearsonDistribution[2,…] is a symmetric shifted and rescaled BetaDistribution.
PearsonDistribution[3,…] includes NormalDistribution and GammaDistribution.
PearsonDistribution[4,…] is not related to standard distributions.
PearsonDistribution[5,…] is a shifted InverseGammaDistribution.
PearsonDistribution[6,…] is a shifted and rescaled FRatioDistribution.
PearsonDistribution[7,…] is a shifted and rescaled StudentTDistribution.
With symbolic parameters and no type argument, the first type whose parameter assumptions are not explicitly violated is assumed. Types are tried in the order 4, 1, 6, 3, 5, 2, and 7.
The parameter assumptions can be obtained from DistributionParameterAssumptions.
PearsonDistribution allows a₁, a₀, b₂, b₁, and b₀ to be quantities such that one can find a unit for x that makes dimensionless. »
PearsonDistribution can be used with such functions as Mean, CDF, and RandomVariate.

Background & Context

PearsonDistribution represents a statistical distribution belonging to one of seven types as determined by argument structure. Pearson distributions originate with English mathematician Karl Pearson, who devised them in order to model distributions that are visibly skewed.
The overall shape of the probability density function (PDF) of a Pearson distribution varies significantly based on its arguments. For example, the PDF of type I Pearson distributions may be either monotonic increasing, monotonic decreasing, or may have a single "peak" (i.e. a global maximum), whereas the PDF of type IV Pearson distributions always has a single peak and looks similar to skewed, asymmetric Gaussian distributions. In addition, the PDFs of various types of PearsonDistribution may be defined and supported over different types of intervals (for example, the domain of a type I Pearson is a bounded, finite-length interval, whereas the domain of a type IV is all of ), and the tails of the PDF may be "fat" (i.e. the PDF decreases non-exponentially for large values ) or "thin" (i.e. the PDF decreases exponentially for large ), depending on the type. (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.)
Pearson type IV is commonly used to fit distributions obtained from data or from Monte Carlo simulations, whereas the other Pearson families are intended to approximate unimodal distributions that are modeled well by type IV but not by other more "standard" distributions. Many distributions are described by (or are limiting values and/or special cases of) families of Pearson distributions, meaning Pearson distributions are extremely general in the types of phenomena they may model. For example, certain types of Pearson distributions play fundamental roles in describing disease transmission behavior, properties of Wiener processes, fundamental concepts in Bayesian statistics, the size of insurance claims, and bacterial gene expression.
RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a Pearson distribution. Distributed[x,PearsonDistribution[type,a₁,a₀,b₂,b₁,b₀]], written more concisely as xPearsonDistribution[type,a₁,a₀,b₂,b₁,b₀], can be used to assert that a random variable x is distributed according to a Pearson distribution of a given type. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
The probability density and cumulative distribution functions for Pearson distributions of a given type may be given using PDF[PearsonDistribution[type,a₁,a₀,b₂,b₁,b₀],x] and CDF[PearsonDistribution[type,a₁,a₀,b₂,b₁,b₀],x]. Pearson distributions are special in the sense that their PDF satisfies a first-order differential equation involving a simple rational function of the form . The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively. When a Pearson distribution is finite, its first four moments uniquely determine it.
DistributionFitTest can be used to test if a given dataset is consistent with a Pearson distribution, EstimatedDistribution to estimate a Pearson parametric distribution from given data, and FindDistributionParameters to fit data to a Pearson distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic Pearson distribution and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic Pearson distribution.
TransformedDistribution can be used to represent a transformed Pearson distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a Pearson distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving Pearson distributions.
PearsonDistribution is closely related to a number of other distributions. For example, types I and II Pearson distributions are shifted and rescaled versions of BetaDistribution, type III generalizes both NormalDistribution and GammaDistribution, type V is a shifted version of InverseGammaDistribution, and types VI and VII are shifted and rescaled versions of FRatioDistribution and StudentTDistribution, respectively. Though type IV Pearson distributions are unrelated to other standard distributions in this usual sense, they have PDFs that appear to be asymmetric versions of StudentTDistribution. Furthermore, for certain argument values, type IV Pearson distributions become generalizations of CauchyDistribution. PearsonDistribution is also closely related to ArcSinDistribution, BetaPrimeDistribution, PowerDistribution, ParetoDistribution, LevyDistribution, InverseChiSquareDistribution, HotellingTSquareDistribution, HalfNormalDistribution, and ErlangDistribution.

Examples

open all close all

Basic Examples (4)

Probability density function:

Wolfram Language code:

Plot[Table[PDF[PearsonDistribution[a1, -85, 37, 26, 58], x], {a1, {45, 57, 75}}]//Evaluate, {x, -3, 15}, Filling -> Axis, PlotRange -> All]

Wolfram Language code:

Plot[Table[PDF[PearsonDistribution[57, a0, 37, 26, 58], x], {a0, {-130, -86, -45}}]//Evaluate, {x, -3, 15}, Filling -> Axis, PlotRange -> All]

Wolfram Language code:

Plot[Table[PDF[PearsonDistribution[45, -85, 37, 26, b0], x], {b0, {10, 400, 10 ^ 3}}]//Evaluate, {x, -10, 15}, Filling -> Axis, PlotRange -> All]

Cumulative distribution function:

Wolfram Language code:

Plot[Table[CDF[PearsonDistribution[a1, -85, 37, 26, 58], x], {a1, {45, 57, 75}}]//Evaluate, {x, -3, 15}, Filling -> Axis, PlotRange -> All]

Wolfram Language code:

Plot[Table[CDF[PearsonDistribution[57, a0, 37, 26, 58], x], {a0, {-130, -86, -45}}]//Evaluate, {x, -3, 15}, Filling -> Axis, PlotRange -> All]

Wolfram Language code:

Plot[Table[CDF[PearsonDistribution[45, -85, 37, 26, b0], x], {b0, {10, 400, 10 ^ 3}}]//Evaluate, {x, -10, 15}, Filling -> Axis, PlotRange -> All]

Mean and variance of Pearson type 4:

Wolfram Language code: Mean[PearsonDistribution[4, a1, a0, b2, b1, b0]]

Wolfram Language code: Variance[PearsonDistribution[4, a1, a0, b2, b1, b0]]

Pearson type 5 distribution:

Wolfram Language code: PDF[PearsonDistribution[5, Subscript[a, 1], Subscript[a, 0], Subscript[b, 2], Subscript[b, 1], Subscript[b, 0]], x]

Scope (8)

Generate a sample of pseudorandom numbers from a Pearson distribution:

Wolfram Language code: data = RandomVariate[PearsonDistribution[45, -85, 37, 26, 100], 10 ^ 5];

Wolfram Language code:

Show[Histogram[data, {-10, 40, 2}, "PDF"], Plot[PDF[TruncatedDistribution[{-10, 40}, PearsonDistribution[45, -85, 37, 26, 100]], x]//Evaluate, {x, -10, 40}, PlotRange -> All, PlotStyle -> Thick]]

Distribution parameters estimation:

Wolfram Language code: sample = RandomVariate[PearsonDistribution[55, -45, 31, 26, 158], 10 ^ 4];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, PearsonDistribution[a0, a1, a2, 25, 58]]

Compare the density histogram of the sample with the PDF of the estimated distribution:

Wolfram Language code:

Show[Histogram[sample, {-20, 60, 1}, "PDF"], Plot[PDF[TruncatedDistribution[{-20, 60}, edist], x], {x, -50, 100}, PlotRange -> All, Exclusions -> None, PlotStyle -> Thick]]

Skewness:

Wolfram Language code:

Plot3D[Skewness[PearsonDistribution[a1, a0, 2, 20, 100]], {a1, 10, 100}, {a0, -100, -10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]

Wolfram Language code:

Plot3D[Skewness[PearsonDistribution[10, -100, 2, b1, b0]], {b1, 1, 5}, {b0, 1, 6}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-2, 2, 2}]

Wolfram Language code: Skewness[PearsonDistribution[4, a1, a0, b2, b1, b0]]//FullSimplify

Kurtosis:

Wolfram Language code:

Plot3D[Kurtosis[PearsonDistribution[a1, a0, 1, 2, 10]], {a1, 10, 100}, {a0, -10, -1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]

Wolfram Language code:

Plot3D[Kurtosis[PearsonDistribution[10, -100, 1, b1, b0]], {b1, 1, 5}, {b0, 1, 6}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-2, 2, 2}]

Wolfram Language code: Kurtosis[PearsonDistribution[4, a1, a0, b2, b1, b0]]//Together

Different moments with closed forms as functions of parameters of Pearson type 4:

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//FullSimplify, {r, 3}], M]

Wolfram Language code: Moment[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//Simplify

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//FullSimplify, {r, 3}], CM]

Wolfram Language code: CentralMoment[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//Simplify

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//FullSimplify, {r, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[PearsonDistribution[4, a1, a0, b2, b1, b0], r]//FullSimplify, {r, 3}], C]

Hazard function:

Wolfram Language code:

Plot[Table[HazardFunction[PearsonDistribution[a1, -2, 2, 20, 100], x], {a1, {3, 5, 10}}]//Evaluate, {x, -10, 40}, Filling -> Axis]

Wolfram Language code:

Plot[Table[HazardFunction[PearsonDistribution[10, -2, 2, b1, 100], x], {b1, {-1, 1, 20}}]//Evaluate, {x, -10, 20}, Filling -> Axis]

Wolfram Language code:

Plot[Table[HazardFunction[PearsonDistribution[10, -2, 2, 2, b0], x], {b0, {1, 2, 4}}]//Evaluate, {x, -2, 4}, Filling -> Axis]

Quantile function:

Wolfram Language code:

Plot[Table[Quantile[PearsonDistribution[-87, 45, -10, 100, b0], q], {b0, {-10 ^ 4, -10 ^ 3, -300}}]//Evaluate, {q, 0, 1}, Filling -> Axis, PlotRange -> {-40, 40}]

Wolfram Language code:

Plot[Table[Quantile[PearsonDistribution[-10, 90, -2, b1, 10], q], {b1, {-10, 10, 20}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code:

Plot[Table[Quantile[PearsonDistribution[a1, 40, 10, 20, -100], q], {a1, {3, 7, 10}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Consistent use of Quantity in parameters yields QuantityDistribution:

Wolfram Language code:

optionPrice𝒟 = PearsonDistribution[Quantity[57, "USDollars"], Quantity[-86, "USDollars"^2], Quantity[3, "USDollars"], Quantity[26, "USDollars"^2], Quantity[58, "USDollars"^3]]

Find skewness of the option price under this model:

Wolfram Language code: Skewness[optionPrice𝒟]//N

Applications (3)

PearsonDistribution of type 4 is the only type not related to other standard distributions:

Wolfram Language code: 𝒫IV = PearsonDistribution[4, a1, a0, 1, b1, b0] /. {b1 -> 1, b0 -> 2, a0 -> 2, a1 -> 3}

Wolfram Language code: pdf = PDF[𝒫IV, x]

Wolfram Language code: sample = RandomVariate[𝒫IV, 10 ^ 4];

Wolfram Language code: Show[Histogram[sample, {-10, 10, 0.5}, "PDF"], Plot[pdf, {x, -10, 10}, PlotStyle -> Thick, PlotRange -> All]]

Find the probability for a Pearson IV random variate to be outside the plotted region:

Wolfram Language code: NProbability[x > 10 || x < -10, x𝒫IV]

Moments of PearsonDistribution satisfy a three-term recurrence equation implied by the defining differential equation for the density function :

Wolfram Language code:

eq[r_] := r * Subscript[b, 0] * Moment[r - 1] + (r + 1) Subscript[b, 1] * Moment[r] + (r + 2) Subscript[b, 2] * Moment[r + 1] - Subscript[a, 1] * Moment[r + 1] - Subscript[a, 0] * Moment[r]

Express moment equations using standardized central moments:

Wolfram Language code:

meq = Table[MomentConvert[eq[r], CentralMoment], {r, 0, 3}] /. {Moment[1] -> μ, CentralMoment[2] -> σ^2, CentralMoment[3] -> Sqrt[Subscript[β, 1]]σ^3, CentralMoment[4] -> Subscript[β, 2]σ^4}

Augment equations to fix coefficient normalization:

Wolfram Language code:

meq = Join[meq, {Subscript[a, 0] + (12 μ Subscript[β, 1] + 2 μ (9 - 5 Subscript[β, 2]) + σ Sqrt[Subscript[β, 1]] (3 + Subscript[β, 2]))}];

Solve equations:

Wolfram Language code:

{sol} = Solve[meq == 0, {Subscript[a, 0], Subscript[a, 1], Subscript[b, 2], Subscript[b, 1], Subscript[b, 0]}]//FullSimplify

Define Pearson distribution in terms of standardized central moments:

Wolfram Language code:

𝒫ℯ𝒶𝓇𝓈ℴ𝓃 = PearsonDistribution[Subscript[a, 1], Subscript[a, 0], Subscript[b, 2], Subscript[b, 1], Subscript[b, 0]] /. sol

Check the solution:

Wolfram Language code: Mean[𝒫ℯ𝒶𝓇𝓈ℴ𝓃]//FullSimplify

Wolfram Language code: StandardDeviation[𝒫ℯ𝒶𝓇𝓈ℴ𝓃]//Simplify[#, σ > 0]&

Wolfram Language code: Skewness[𝒫ℯ𝒶𝓇𝓈ℴ𝓃]//Simplify[#, σ > 0]&

Wolfram Language code: Kurtosis[𝒫ℯ𝒶𝓇𝓈ℴ𝓃]//Simplify[#, σ > 0]&

Define Pearson distribution with zero mean and unit variance, and parameterized by skewness and kurtosis:

Wolfram Language code:

stPearson[t_, β1_, β2_] = PearsonDistribution[t, 2 (9 + 6 β1 - 5 β2), -Sqrt[β1] (3 + β2), 6 + 3 β1 - 2 β2, -Sqrt[β1] (3 + β2), 3β1 - 4 β2];

Obtain parameter inequalities for Pearson types 1, 4, and 6:

Wolfram Language code:

RegionFunc[β1_, β2_] = Table[Legended[Reduce[β2 > β1 + 1 && DistributionParameterAssumptions[stPearson[t, β1, β2]], {β1, β2}, Reals], Row[{Text["type -> "], t}]], {t, {1, 4, 6}}]

Wolfram Language code:

PearsonDiagram[data_List] := Module[{gr, sβ1, sβ2, β1, β2}, 
	sβ1 = Skewness[data] ^ 2;
	sβ2 = Kurtosis[data];
	gr = Show[
	RegionPlot[RegionFunc[β1, β2]//Evaluate, {β1, 0, Max[10, Ceiling[1.1 * sβ1, 5]]}, {β2, 0, Max[10, Ceiling[1.1 * sβ2, 5]]}, PlotPoints -> 50, Epilog -> {PointSize[0.02], Red, Point[{sβ1, sβ2}]}]
	]
	]

Wolfram Language code:

BlockRandom[SeedRandom[2010];
	vec = RandomVariate[ParetoDistribution[2, 12.3], 10 ^ 5];]

Determine the type of PearsonDistribution whose moments match sampling moments:

Wolfram Language code: PearsonDiagram[vec]

Compare with the estimated distribution:

Wolfram Language code: EstimatedDistribution[vec, PearsonDistribution[a1, a0, b2, b1, b0], ParameterEstimator -> "MethodOfMoments"]

Properties & Relations (24)

Certain members of the PearsonDistribution family are closed under affine transforms:

Wolfram Language code:

TransformedDistribution[μ + σ x, xPearsonDistribution[4, Subscript[a, 1], Subscript[a, 0], Subscript[b, 2], Subscript[b, 1], Subscript[b, 0]]]

Wolfram Language code:

TransformedDistribution[-x, xPearsonDistribution[4, Subscript[a, 1], Subscript[a, 0], Subscript[b, 2], Subscript[b, 1], Subscript[b, 0]]]

Relationships to other distributions:

ArcSinDistribution is a special type of Pearson type 1 and type 2 distributions:

Wolfram Language code: p1 = PDF[PearsonDistribution[1, 1, -1 / 2, 1, -1, 0], x]

Wolfram Language code: p2 = PDF[PearsonDistribution[2, 1, -(1/2), 1, -1, 0], x]

Wolfram Language code: PDF[ArcSinDistribution[{0, 1}], x]

Wolfram Language code: {p1 - %, p2 - %}//Simplify

BetaDistribution is a special case of Pearson type 1 distribution:

Wolfram Language code: CDF[PearsonDistribution[1, 1, (α/-α - β), (1/-α - β), (-1/-α - β), 0], x]//FullSimplify

Wolfram Language code: CDF[BetaDistribution[1 + α, 1 + β], x]

Wolfram Language code: % - %%

PowerDistribution is a special case of Pearson type 1 distribution:

Wolfram Language code: PDF[PearsonDistribution[1, 1 - α, (α - 1) / k, 1, -1 / k, 0], x]//FullSimplify[#, k > 0]&

Wolfram Language code: PDF[PowerDistribution[k, α], x]//PowerExpand

Wolfram Language code: FullSimplify[% - %%, 0 < x < 1 / k]

WignerSemicircleDistribution is a special case of Pearson type 1 and type 2 distributions:

Wolfram Language code: p1 = Refine[PDF[PearsonDistribution[1, 1, 0, -1, 0, r^2], x], r > 0]

Wolfram Language code: p2 = Refine[PDF[PearsonDistribution[2, 1, 0, -1, 0, r^2], x], r > 0]

Wolfram Language code: PDF[WignerSemicircleDistribution[r], x]

Wolfram Language code: {p1 - %, p2 - %}//FullSimplify

ChiSquareDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, 1, -ν + 2, 0, 2, 0], x]//FullSimplify

Wolfram Language code: PDF[ChiSquareDistribution[ν], x]

Wolfram Language code: % - %%

ErlangDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, 1, (-k + 1/λ), 0, (1/λ), 0], x]//Refine[#, λ > 0]&

Wolfram Language code: PDF[ErlangDistribution[k, λ], x]//Refine[#, λ > 0]&

Wolfram Language code: % - %%//FullSimplify[#, λ > 0]&

ExponentialDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, 1, 0, 0, (1/λ), 0], x]//Refine[#, λ > 0]&

Wolfram Language code: PDF[ExponentialDistribution[λ], x]

Wolfram Language code: FullSimplify[% - %%, λ > 0 && x > 0]

GammaDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, 1, -α β + β, 0, β, 0], x]//FullSimplify[#, β > 0]&

Wolfram Language code: PDF[GammaDistribution[α, β], x]

Wolfram Language code: % - %%

Scaled HalfNormalDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, θ^2, 0, 0, 0, (π/2)], x]//Refine[#, θ > 0]&

Wolfram Language code: 1 / 2 PDF[HalfNormalDistribution[θ], x]//Refine[#, x > 0]&

Wolfram Language code: % - %%

Wolfram Language code: Integrate[(E^-(x^2 θ^2/π) θ/π), {x, -∞, ∞}, Assumptions -> θ > 0]

NormalDistribution is a special case of Pearson type 3 distribution:

Wolfram Language code: PDF[PearsonDistribution[3, σ^-2, -μ σ^-2, 0, 0, 1], x]//FullSimplify[#, σ > 0]&

Wolfram Language code: PDF[NormalDistribution[μ, σ], x]

Wolfram Language code: % - %%

CauchyDistribution is a limiting case of Pearson type 4 distribution:

Wolfram Language code: Limit[PDF[PearsonDistribution[4, 1, -a, (1 + ϵ/2), -a, (a^2 + b^2/2)], x], ϵ -> 0]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: %% - %//FullSimplify

CauchyDistribution is a special case of Pearson type 7 distribution:

Wolfram Language code: PDF[PearsonDistribution[7, 2, -2a, 1, -2a, a^2 + b^2], x]//FullSimplify[#, b > 0]&

Wolfram Language code: PDF[CauchyDistribution[a, b], x]//FullSimplify[#, b > 0]&

Wolfram Language code: %% - %//FullSimplify

StudentTDistribution is a special case of Pearson type 4 and type 7 distributions:

Wolfram Language code: p4 = PDF[PearsonDistribution[4, 1, 0, (1/ν + 1), 0, (ν/1 + ν)], x]//FullSimplify[#, ν > 0]&

Wolfram Language code: p7 = PDF[PearsonDistribution[7, 1, 0, (1/ν + 1), 0, (ν/1 + ν)], x]//FullSimplify

Wolfram Language code: PDF[StudentTDistribution[ν], x]//PowerExpand//FullSimplify

Wolfram Language code: {p4 - %, p7 - %}

Generalized StudentTDistribution is a special case of Pearson type 4 and type 7 distributions:

Wolfram Language code:

p4 = PDF[PearsonDistribution[4, 1, -μ, (1/ν + 1), -(2 μ/ν + 1), (μ^2 + ν σ^2/ν + 1)], x]//FullSimplify[#, ν > 0 && σ > 0]&

Wolfram Language code: p7 = PDF[PearsonDistribution[7, 1, -μ, (1/ν + 1), -(2 μ/ν + 1), (μ^2 + ν σ^2/ν + 1)], x]//FullSimplify

Wolfram Language code: PDF[StudentTDistribution[μ, σ, ν], x]//FullSimplify//PowerExpand

Wolfram Language code: {p4 - %, p7 - %}//FullSimplify[#, ν > 0 && σ > 0]&

InverseChiSquareDistribution is a special case of Pearson type 5 distribution:

Wolfram Language code: PDF[PearsonDistribution[5, 1, (-1/2 + ν), (2/2 + ν), 0, 0], x]//FullSimplify

Wolfram Language code: PDF[InverseChiSquareDistribution[ν], x]//PowerExpand

Wolfram Language code: % - %%

Scaled InverseChiSquareDistribution is a special case of Pearson type 5 distribution:

Wolfram Language code: PDF[PearsonDistribution[5, 1, -(ν ξ/2 + ν), (2/2 + ν), 0, 0], x]

Wolfram Language code: PDF[InverseChiSquareDistribution[ν, ξ], x]

Wolfram Language code: % - %%//FullSimplify

InverseGammaDistribution is a special case of Pearson type 5 distribution:

Wolfram Language code: PDF[PearsonDistribution[5, 1, (-β/1 + α), (1/1 + α), 0, 0], x]//FullSimplify

Wolfram Language code: PDF[InverseGammaDistribution[α, β], x]//PowerExpand

Wolfram Language code: % - %%

LevyDistribution is a special case of Pearson type 5 distribution:

Wolfram Language code: PDF[PearsonDistribution[5, 1, -μ - (σ/3), (2/3), -(4/3)μ, (2/3)μ^2], x]//FullSimplify

Wolfram Language code: PDF[LevyDistribution[μ, σ], x]//PowerExpand

Wolfram Language code: % - %%//Simplify

BetaPrimeDistribution is a special case of Pearson type 6 distribution:

Wolfram Language code: PDF[PearsonDistribution[6, 1, (1 - p/q + 1), (1/q + 1), (1/q + 1), 0], x]

Wolfram Language code: PDF[BetaPrimeDistribution[p, q], x]

Wolfram Language code: % - %%//FullSimplify

FRatioDistribution is a special case of Pearson type 6 distribution:

Wolfram Language code: PDF[PearsonDistribution[6, 1, -(m n - 2m/n(2 + m)), (2/2 + m), (2 m/n(2 + m)), 0], x]//FullSimplify[#, m > 0 && n > 0]&

Wolfram Language code: PDF[FRatioDistribution[n, m], x]

Wolfram Language code: % - %%//FullSimplify

HotellingTSquareDistribution is a special case of Pearson type 6 distribution:

Wolfram Language code:

PDF[PearsonDistribution[6, 1, -(m(n - 2)/3 + m - n), (2/3 + m - n), (2 m/3 + m - n), 0], x]//FullSimplify[#, m > 0 && n > 0]&

Wolfram Language code: PDF[HotellingTSquareDistribution[n, m], x]

Wolfram Language code: % - %%//FullSimplify[#, n > 0 && m > 0]&

ParetoDistribution is a special case of Pearson type 6 distribution:

Wolfram Language code:

CDF[PearsonDistribution[6, 1 + 1 / α, -μ (1 + 1 / α), 1 / α, -2 μ  / α + k / α, μ (μ  / α - k / α)], x]//FullSimplify[#, α > 0 && k > 0]&

Wolfram Language code: CDF[ParetoDistribution[k, α, μ], x]//PowerExpand//FullSimplify[#, k > 0 && α > 0]&

Wolfram Language code: % - %%//FullSimplify

Neat Examples (1)

PDFs for different values with CDF contours:

Wolfram Language code:

dist = PearsonDistribution[52, a0, 35, 24, 59];cdf = Function[{x, a0}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, -2, 50}, {a0, -200, 100}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotPoints -> 200, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

More Learning

Tech Support

Data Science, Finance & Business

Engineering

Science & Technology

Technology for Education

Education Initiatives

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

PearsonDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (8)

Applications (3)

Properties & Relations (24)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

PearsonDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (8)

Applications (3)

Properties & Relations (24)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX