JohnsonDistribution
JohnsonDistribution
JohnsonDistribution["SB",γ,δ,μ,σ]
represents a bounded Johnson distribution with shape parameters γ, δ, location parameter μ, and scale parameter σ.
JohnsonDistribution["SL",γ,δ,μ,σ]
represents a semi-bounded Johnson distribution.
JohnsonDistribution["SU",γ,δ,μ,σ]
represents an unbounded Johnson distribution.
JohnsonDistribution["SN",γ,δ,μ,σ]
represents a normal Johnson distribution.
Details
- JohnsonDistribution represents the Johnson system of distributions. Each distribution represents the distribution of the form
, where 
is from NormalDistribution[]. - JohnsonDistribution["SB",γ,δ,μ,σ] corresponds to
. - JohnsonDistribution["SL",γ,δ,μ,σ] corresponds to
. - JohnsonDistribution["SU",γ,δ,μ,σ] corresponds to
. - JohnsonDistribution["SN",γ,δ,μ,σ] corresponds to
. - JohnsonDistribution allows γ and μ to be any real numbers and δ and σ to be any positive real numbers.
- JohnsonDistribution allows μ and σ to be any quantities of the same unit dimensions, and δ, γ to be dimensionless quantities. »
- JohnsonDistribution can be used with such functions as Mean, CDF, and RandomVariate.
Background & Context
- JohnsonDistribution["type",γ,δ,μ,σ] represents a statistical distribution belonging to one of four types as determined by its first argument and parametrized by real numbers γ (called a "shape parameter") and μ (called a "location parameter") and positive real numbers δ (called a "shape parameter") and σ (called a "scale parameter"). Overall, the probability density function (PDF) of a Johnson distribution is unimodal with a single "peak" (i.e. a global maximum), though its overall shape (its height, its spread, and its concentration near the
axis) is completely determined by the values of its arguments. In addition, the tails of the PDF are "thin" in the sense that the PDF decreases exponentially rather than decreasing algebraically for large values of x. (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.) - Johnson distributions originate with English statistician Norman Johnson, who devised them in the late 1940s in order to apply the well-established methods and theory of the normal distribution (NormalDistribution) to a wide range of possibly non-normal probability distributions via a series of simple transformations that are all easily computable using function tables that existed at the time. In particular, given an observed distribution which is non-normal, the exponential, logistic, and hyperbolic sine transformations generate Johnson distributions of which are log-normal (of type "SL"), unbounded ("SU"), and bounded ("SB") distributions, respectively; the normal ("SN") distribution corresponds to an observed distribution that is already normally distributed. Because of its flexibility, the family of Johnson distributions has been used to analyze real-world datasets in various fields including atmospheric chemistry, biomedical engineering, econometrics, management, and material science.
- RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a Johnson distribution. Distributed[x,JohnsonDistribution["type",γ,δ,μ,σ]], written more concisely as xJohnsonDistribution["type",γ,δ,μ,σ], can be used to assert that a random variable x is distributed according to a Johnson distribution of a given "type" (one of "SB", "SL", "SN", or "SU" as discussed above). Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
- The probability density and cumulative distribution functions for Johnson distributions may be given using PDF[JohnsonDistribution["type",γ,δ,μ,σ],x] and CDF[JohnsonDistribution["type",γ,δ,μ,σ],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
- DistributionFitTest can be used to test if a given dataset is consistent with a Johnson distribution, EstimatedDistribution to estimate a Johnson parametric distribution from given data, and FindDistributionParameters to fit data to a Johnson distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic Johnson distribution, and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic Johnson distribution.
- TransformedDistribution can be used to represent a transformed Johnson distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a Johnson distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving Johnson distributions.
- JohnsonDistribution is closely related to a number of other distributions. For example, JohnsonDistribution was compared to and contrasted with PearsonDistribution in Johnson's original paper, and the distributions were defined in such a way that all four types are transformations (via TransformedDistribution) of NormalDistribution. The "SL" type JohnsonDistribution is a generalization of LogNormalDistribution, and JohnsonDistribution is also closely related to HalfNormalDistribution, FisherZDistribution, ArcSinDistribution, BetaPrimeDistribution, PowerDistribution, ParetoDistribution, InverseChiSquareDistribution, and ErlangDistribution.
Examples
open all close allBasic Examples (5)
Probability density function for bounded (SB):
Plot[Table[PDF[JohnsonDistribution["SB", γ, 2, 1.1, 1.5], x], {γ, {-1, 1, 3}}]//Evaluate, {x, 1.1, 2.5}, Filling -> Axis]PDF[JohnsonDistribution["SB", γ, δ, μ, σ], x]Plot[Table[PDF[JohnsonDistribution["SL", γ, 2, 1.1, 1.5], x], {γ, {-0.5, 1, 2}}]//Evaluate, {x, 1.1, 5}, AxesOrigin -> {1.1, 0}, Filling -> Axis, PlotRange -> All]PDF[JohnsonDistribution["SL", γ, δ, μ, σ], x]Plot[Table[PDF[JohnsonDistribution["SU", γ, 2, 1.1, 1.5], x], {γ, {-2, 1, 3}}]//Evaluate, {x, -6, 6}, Filling -> Axis]PDF[JohnsonDistribution["SU", γ, δ, μ, σ], x]Plot[Table[PDF[JohnsonDistribution["SN", γ, 2, 1.1, 1.5], x], {γ, {-0.5, 1, 3}}]//Evaluate, {x, -4, 4.5}, Filling -> Axis]PDF[JohnsonDistribution["SN", γ, δ, μ, σ], x]Cumulative distribution function for bounded (SB):
Plot[Table[CDF[JohnsonDistribution["SB", γ, 2, 1.1, 1.5], x], {γ, {-1, 1, 3}}]//Evaluate, {x, 1.1, 2.5}, Filling -> Axis, Exclusions -> None]CDF[JohnsonDistribution["SB", γ, δ, μ, σ], x]Plot[Table[CDF[JohnsonDistribution["SL", γ, 2, 1.1, 1.5], x], {γ, {-0.5, 1, 2}}]//Evaluate, {x, 1.1, 5}, AxesOrigin -> {1.1, 0}, Filling -> Axis, PlotRange -> All, Exclusions -> None]CDF[JohnsonDistribution["SL", γ, δ, μ, σ], x]Plot[Table[CDF[JohnsonDistribution["SU", γ, 2, 1.1, 1.5], x], {γ, {-2, 1, 3}}]//Evaluate, {x, -6, 6}, Filling -> Axis, Exclusions -> None]CDF[JohnsonDistribution["SU", γ, δ, μ, σ], x]Plot[Table[CDF[JohnsonDistribution["SN", γ, 2, 1.1, 1.5], x], {γ, {-0.5, 1, 3}}]//Evaluate, {x, -4, 4.5}, Filling -> Axis, Exclusions -> None]CDF[JohnsonDistribution["SN", γ, δ, μ, σ], x]Mean for bounded (SB) is available numerically:
Mean[JohnsonDistribution["SB", 1, 2, 0, 1 / 2]]//NMean[JohnsonDistribution["SL", γ, δ, μ, σ]]Mean[JohnsonDistribution["SU", γ, δ, μ, σ]]//FullSimplifyMean[JohnsonDistribution["SN", γ, δ, μ, σ]]Variance for bounded (SB) is available numerically:
Variance[JohnsonDistribution["SB", 1, 2, 0, 1 / 2]]//NVariance[JohnsonDistribution["SL", γ, δ, μ, σ]]//FullSimplifyVariance[JohnsonDistribution["SU", γ, δ, μ, σ]]//FullSimplifyVariance[JohnsonDistribution["SN", γ, δ, μ, σ]]Median[JohnsonDistribution["SB", γ, δ, μ, σ]]Median[JohnsonDistribution["SL", γ, δ, μ, σ]]//FullSimplifyMedian[JohnsonDistribution["SU", γ, δ, μ, σ]]//FullSimplifyMedian[JohnsonDistribution["SN", γ, δ, μ, σ]]Scope (8)
Generate a sample of pseudorandom numbers from a bounded Johnson distribution:
data = RandomVariate[JohnsonDistribution["SB", -1, 2, 0, 3], 10 ^ 4];Compare its histogram to the PDF:
Show[
Histogram[data, 20, "PDF"],
Plot[PDF[JohnsonDistribution["SB", -1, 2, 0, 3], x], {x, 0, 3}, PlotStyle -> Thick]]Distribution parameters estimation:
sample = RandomVariate[JohnsonDistribution["SL", -1, 2, 1, 2], 10 ^ 3];Estimate the distribution parameters from sample data:
edist = EstimatedDistribution[sample, JohnsonDistribution["SL", γ, δ, 1, 2]]Compare a density histogram of the sample with the PDF of the estimated distribution:
Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 12}, PlotStyle -> Thick]]Skewness for semi-bounded (SL):
Plot[Skewness[JohnsonDistribution["SL", γ, δ, μ, σ]], {δ, 0.5, 2}]Skewness[JohnsonDistribution["SL", γ, δ, μ, σ]]//FullSimplify[#, σ > 0]&Plot3D[Skewness[JohnsonDistribution["SU", γ, δ, 0, 1]], {γ, -3, 3}, {δ, 0.1, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]Skewness[JohnsonDistribution["SU", γ, δ, μ, σ]]//FullSimplify[#, σ > 0]&Skewness[JohnsonDistribution["SN", γ, δ, μ, σ]]Kurtosis for semi-bounded (SL):
Plot[Kurtosis[JohnsonDistribution["SL", γ, δ, μ, σ]], {δ, 0.5, 2}]Kurtosis[JohnsonDistribution["SL", γ, δ, μ, σ]]//FullSimplifyPlot3D[Kurtosis[JohnsonDistribution["SU", γ, δ, 1.5, 1 / 100]], {γ, -3, 3}, {δ, 0.1, 10}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], NormalsFunction -> None, AxesLabel -> Automatic, ViewPoint -> {2, 1, 1}]Kurtosis[JohnsonDistribution["SU", γ, δ, μ, σ]]//FullSimplifyKurtosis[JohnsonDistribution["SN", γ, δ, μ, σ]]Different moments with closed forms as functions of parameters:
FormulaGrid[list_, type_] := Grid[...]Bounded (SB), no closed formula for symbolic parameters, but can be evaluated numerically:
Moment[JohnsonDistribution["SB", -1, 2, 1.5, 0.5], 2]Cumulant[JohnsonDistribution["SB", -1, 2, 1.5, 0.5], 2]FormulaGrid[Table[Moment[JohnsonDistribution["SL", γ, δ, μ, σ], k]//FullSimplify, {k, 3}], M]FormulaGrid[Table[CentralMoment[JohnsonDistribution["SL", γ, δ, μ, σ], k]//Together, {k, 3}], CM]FormulaGrid[Table[FactorialMoment[JohnsonDistribution["SL", γ, δ, μ, σ], k]//Factor, {k, 3}], FM]FormulaGrid[Table[Cumulant[JohnsonDistribution["SL", γ, δ, μ, σ], k]//Factor, {k, 3}], C]FormulaGrid[Table[Moment[JohnsonDistribution["SU", γ, δ, μ, σ], k]//FullSimplify, {k, 3}], M]FormulaGrid[Table[CentralMoment[JohnsonDistribution["SU", γ, δ, μ, σ], k]//Together, {k, 3}], CM]FormulaGrid[Table[FactorialMoment[JohnsonDistribution["SU", γ, δ, μ, σ], k]//FullSimplify, {k, 3}], FM]FormulaGrid[Table[Cumulant[JohnsonDistribution["SU", γ, δ, μ, σ], k]//Factor, {k, 3}], C]FormulaGrid[Table[Moment[JohnsonDistribution["SN", γ, δ, μ, σ], k]//FullSimplify, {k, 3}], M]FormulaGrid[Table[CentralMoment[JohnsonDistribution["SN", γ, δ, μ, σ], k]//Together, {k, 3}], CM]FormulaGrid[Table[FactorialMoment[JohnsonDistribution["SN", γ, δ, μ, σ], k]//FullSimplify, {k, 3}], FM]FormulaGrid[Table[Cumulant[JohnsonDistribution["SN", γ, δ, μ, σ], k]//Factor, {k, 3}], C]Hazard function for bounded (SB):
Plot[Table[HazardFunction[JohnsonDistribution["SB", γ, 3, -1, 2], x], {γ, {-3, 1, 4}}]//Evaluate, {x, 0, 0.9}, Filling -> Axis, PlotPoints -> 2]Plot[Table[HazardFunction[JohnsonDistribution["SL", γ, 3, -1, 2], x], {γ, {-0.5, 0, .75}}]//Evaluate, {x, 0, 10}, Filling -> Axis]Plot[Table[HazardFunction[JohnsonDistribution["SL", γ, 1 / 3, -1, 2], x], {γ, {-0.5, 0, .75}}]//Evaluate, {x, 0, 6}, Filling -> Axis, Exclusions -> None]Plot[Table[HazardFunction[JohnsonDistribution["SU", γ, 3, -1, 2], x], {γ, {-3, 1, 4}}]//Evaluate, {x, 0, 10}, Filling -> Axis]Plot[Table[HazardFunction[JohnsonDistribution["SN", γ, 3, -1, 2], x], {γ, {-3, 1, 4}}]//Evaluate, {x, 0, 10}, Filling -> Axis]Quantile function for bounded (SB):
Plot[Table[Quantile[JohnsonDistribution["SB", γ, 3, -1, 2], q], {γ, {-3, 1, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis, PlotPoints -> 2]Quantile[JohnsonDistribution["SB", γ, δ, μ, σ], q]Plot[Table[Quantile[JohnsonDistribution["SL", γ, 3, -1, 2], q], {γ, {-0.5, 0, .75}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[JohnsonDistribution["SL", γ, δ, μ, σ], q]Plot[Table[Quantile[JohnsonDistribution["SU", γ, 3, -1, 2], q], {γ, {-3, 1, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[JohnsonDistribution["SU", γ, δ, μ, σ], q]Plot[Table[Quantile[JohnsonDistribution["SN", γ, 3, -1, 2], q], {γ, {-3, 1, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]Quantile[JohnsonDistribution["SN", γ, δ, μ, σ], q]Consistent use of Quantity in parameters yields QuantityDistribution:
snowfall𝒟 = JohnsonDistribution["SU", -151.261, 43.6433, Quantity[-945.811, "Inches"], Quantity[64.1692, "Inches"]]Find the average snow accumulation:
Mean[snowfall𝒟]Applications (1)
Johnson distribution can be used to model snowfall records:
ExampleData[{"Statistics", "BuffaloSnow"}, "LongDescription"]snow = Quantity[ExampleData[{"Statistics", "BuffaloSnow"}], "Inches"];Fit Johnson (SU) distribution to the data:
edist = EstimatedDistribution[snow, JohnsonDistribution["SU", a, b, c, d]]Plot[{CDF[EmpiricalDistribution[snow], Quantity[x, "Inches"]], CDF[edist, Quantity[x, "Inches"]]}, {x, QuantityMagnitude@Min[snow], QuantityMagnitude@Max[snow]}, PlotStyle -> Thick, AxesLabel -> {"in"}]Properties & Relations (8)
The Johnson distribution family is closed under translation and scaling by a positive factor:
TransformedDistribution[k u + loc, uJohnsonDistribution["SU", a, b, c, d]]TransformedDistribution[k u + loc, uJohnsonDistribution["SL", a, b, c, d]]TransformedDistribution[k u + loc, uJohnsonDistribution["SB", a, b, c, d]]TransformedDistribution[k u + loc, uJohnsonDistribution["SN", a, b, c, d]]Relations to other distributions:
Normal (SN) Johnson distribution is a NormalDistribution:
PDF[JohnsonDistribution["SN", μ, σ, γ, δ], x]PDF[NormalDistribution[γ - μ δ / σ, δ / σ], x]% - %%//FullSimplify[#, σ > 0 && δ > 0]&Normal (SN) Johnson distribution is a transformation of standard NormalDistribution:
𝒟 = TransformedDistribution[σ( z - γ) / δ + μ, z NormalDistribution[]]CDF[𝒟, x]//FullSimplify[#, σ > 0 && δ > 0]&CDF[JohnsonDistribution["SN", γ, δ, μ, σ], x]% - %%//FullSimplifySemi-bounded (SL) Johnson distribution as a transformation of NormalDistribution:
𝒟1 = TransformedDistribution[( z - γ) / δ, zNormalDistribution[]]//Simplify[#, δ > 0]&𝒟2 = TransformedDistribution[σ Exp[z] + μ, z 𝒟1];
CDF[𝒟2, x]//FullSimplify[#, σ > 0 && δ > 0 && (γ/δ) + Log[x - μ] - Log[σ] > 0]&CDF[JohnsonDistribution["SL", γ, δ, μ, σ], x]//Simplify[#, δ > 0 && σ > 0]&//FunctionExpand% - %%//FullSimplify[#, δ > 0 && σ > 0 && x > μ]&
CDF[𝒟2, x]//FullSimplify[#, σ > 0 && δ > 0 && (γ/δ) + Log[x - μ] - Log[σ] ≤ 0]&CDF[JohnsonDistribution["SL", γ, δ, μ, σ], x]//Simplify[#, δ > 0 && σ > 0]&//FunctionExpand% - %%//FullSimplify[#, δ > 0 && σ > 0 && x > μ]&Unbounded (SU) Johnson distribution as a transformation of NormalDistribution:
𝒟1 = TransformedDistribution[( z - γ) / δ, zNormalDistribution[]]//Simplify[#, δ > 0]&𝒟2 = TransformedDistribution[σ Sinh[z] + μ, z 𝒟1];CDF[𝒟2, x]//FullSimplify[#, σ > 0 && δ > 0]&CDF[JohnsonDistribution["SU", γ, δ, μ, σ], x]% - %%//FullSimplify[#, δ > 0 && σ > 0 && x > μ && (γ > 0 || γ < 0 || γ == 0)]&Bounded (SB) Johnson distribution as a transformation of a NormalDistribution:
dist1 = TransformedDistribution[( z - γ) / δ, zNormalDistribution[], Assumptions -> δ > 0]dist2 = TransformedDistribution[1 / (1 + Exp[-u]), udist1];dist3 = TransformedDistribution[ u σ + μ, u dist2, Assumptions -> δ > 0 && σ > 0];cdf1 = CDF[dist3, x]//PowerExpand//FullSimplify[#, σ > 0 && δ > 0 && (μ | γ)∈Reals]&cdf2 = CDF[JohnsonDistribution["SB", γ, δ, μ, σ], x]//PowerExpand//FullSimplify[#, σ > 0 && δ > 0 && (μ | γ)∈Reals]&((cdf1 - cdf2) /. Log[f_] :> Log[Factor[f]])//FullSimplify[#, σ > 0 && δ > 0 && (μ | γ)∈Reals && (μ < x < μ + (σ/2) || μ + (σ/2) ≤ x < μ + σ)]&Special case of SL Johnson distribution is a LogNormalDistribution:
PDF[LogNormalDistribution[-γ / δ, 1 / δ], x]PDF[JohnsonDistribution["SL", γ, δ, 0, 1], x]% - %%//FullSimplify[#, δ > 0 && x > 0]&Neat Examples (1)
PDFs for different γ values with CDF contours:
dist = JohnsonDistribution["SB", γ, 2, 1.3, 1.4];cdf = Function[{x, γ}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];Legended[Plot3D[PDF[dist, x], {x, 1.3, 2.7}, {γ, -1, 1}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), JohnsonDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/JohnsonDistribution.html (updated 2016).
Text
Wolfram Research (2010), JohnsonDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/JohnsonDistribution.html (updated 2016).
CMS
Wolfram Language. 2010. "JohnsonDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/JohnsonDistribution.html.
APA
Wolfram Language. (2010). JohnsonDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JohnsonDistribution.html