Wolfram Language & System Documentation Center

MultinormalDistribution

MultinormalDistribution[μ,Σ]

represents a multivariate normal (Gaussian) distribution with mean vector μ and covariance matrix Σ.

MultinormalDistribution[Σ]

represents a multivariate normal distribution with zero mean vector and covariance matrix Σ.

Details

The probability density for vector in a multivariate normal distribution is proportional to .
MultinormalDistribution allows μ to be any vector of real numbers, and Σ any symmetric positive definite × matrix of real numbers with p=Length[μ].
The mean vector μ and covariance matrix Σ can be quantities such that μ⊗μ and Σ have the same unit dimensions componentwise. »
MultinormalDistribution can be used with such functions as Mean, CDF, and RandomVariate.

Background & Context

MultinormalDistribution[μ,Σ] represents a continuous multivariate statistical distribution supported over the set of of all -tuples and characterized by the property that each of the (univariate) marginal distributions is a NormalDistribution for . In other words, each of the variables satisfies x_kNormalDistribution for . The multinormal distribution MultinormalDistribution[μ,Σ] is parametrized by a vector μ of real numbers and by a positive definite symmetric matrix Σ, which satisfy nLength[μ]Length[Σ] and which define the associated mean, variance, and covariance of the distribution. The multinormal distribution is sometimes referred to as the multivariate normal distribution, as a result of the fact that its univariate marginals are normally distributed.
The probability density function (PDF) of a multinormal distribution has a single absolute maximum, though like the binormal distribution (BinormalDistribution) it may have multiple "peaks" (i.e. relative maxima). In general, the tails of each of the associated marginal PDFs are "thin" in the sense that the marginal PDF decreases exponentially rather than algebraically for large values of . (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of these marginal distributions.)
Most of the applications of the multinormal distribution correspond to the cases (BinormalDistribution) or rather than the general multinormal case. However, as a result of the multivariate central limit theorem, the multivariate normal distribution can be used to describe (at least qualitatively) any set of real-valued random variables, each of whose variates cluster around a given mean value. Even so, the bulk of the earliest literature (some of which dates back to the early 1800s) on multivariable extensions of the normal distribution focus on the bivariate and trivariate cases, which are applied in a wide range of fields, including genetics, materials science, evolutionary biology, economics, ecology, and medicine.
RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a multinormal distribution. Distributed[x,MultinormalDistribution[μ,Σ]] , written more concisely as xMultinormalDistribution[μ,Σ], can be used to assert that a random variable x is distributed according to a multinormal distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
The probability density and cumulative distribution functions for multinormal distributions may be given using PDF[MultinormalDistribution[μ,Σ],x] and CDF[MultinormalDistribution[μ,Σ],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
DistributionFitTest can be used to test if a given dataset is consistent with a multinormal distribution, EstimatedDistribution to estimate a multinormal parametric distribution from given data, and FindDistributionParameters to fit data to a multinormal distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic multinormal distribution and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic multinormal distribution.
TransformedDistribution can be used to represent a transformed multinormal distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a multinormal distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving multinormal distributions.
MultinormalDistribution is related to a number of other distributions, including the NormalDistribution and BinormalDistribution, as discussed above. The one-dimensional marginals of a MultinormalDistribution have a NormalDistribution, while each of the multivariate marginals is again an instance of MultinormalDistribution. MultinormalDistribution is a limiting case of MultivariateTDistribution in the sense that PDF[MultinormalDistribution[{μ₁,μ₂},{{1,ρ},{ ρ,1}}],{x,y}] is precisely the limit of PDF[MultivariateTDistribution[{μ₁,μ₂},{{1,ρ},{ ρ,1}},ν],{x,y}] as ν∞. Moreover, MultinormalDistribution can be obtained from LogMultinormalDistribution by a transformation (TransformedDistribution). MultinormalDistribution is also related to RiceDistribution and, because of its relation to the univariate NormalDistribution, is also related to LogNormalDistribution, DavisDistribution, LogLogisticDistribution, ExponentialDistribution, WeibullDistribution, GompertzMakehamDistribution, ExtremeValueDistribution, and GammaDistribution.

Examples

open all close all

Basic Examples (4)

Probability density function:

Wolfram Language code:

ParallelTable[Plot3D[PDF[MultinormalDistribution[{0, 0}, {{1, ρ 2}, {ρ 2, 4}}], {x, y}], ...], {ρ, {-.7, -0.4, 0, 0.3, 0.5, 0.8}}]

Wolfram Language code:

PDF[MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {{Subscript[σ, 1]^2, ρ Subscript[σ, 1] Subscript[σ, 2]}, {ρ Subscript[σ, 1] Subscript[σ, 2], Subscript[σ, 2]^2}}], {x, y}]

Cumulative distribution function:

Wolfram Language code:

ParallelTable[Plot3D[CDF[MultinormalDistribution[{0, 0}, {{1, ρ 2}, {ρ  2, 4}}], {x, y}], ...], {ρ, {-.7, -0.4, 0, 0.3, 0.5, 0.8}}]

Mean and variance:

Wolfram Language code:

Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};

Wolfram Language code: Mean[MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]

Wolfram Language code: Variance[MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]

Covariance:

Wolfram Language code:

Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};

Wolfram Language code: Covariance[MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]

Scope (8)

Generate a sample of pseudorandom vectors from a bivariate normal distribution:

Wolfram Language code: data = RandomVariate[𝒹 = MultinormalDistribution[{1, 2}, {{2, -1 / 3}, {-1 / 3, 2 / 3}}], 10 ^ 4];

Visualize the sample using a histogram:

Wolfram Language code: {Histogram3D[data, 20, "PDF", ...], Plot3D[PDF[𝒹, {x, y}], ...]}

Distribution parameters estimation:

Wolfram Language code:

sample = RandomVariate[MultinormalDistribution[{1, 2, 4}, {{2, -1 / 4, 1 / 3}, {-1 / 4, 2 / 3, 1 / 5}, {1 / 3, 1 / 5, 1 / 2}}], 10 ^ 3];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, MultinormalDistribution[Array[μ, 3], Array[s, {3, 3}]]]

Goodness-of-fit test:

Wolfram Language code: DistributionFitTest[sample, edist]

Skewness and kurtosis are constant vectors:

Wolfram Language code: Skewness[MultinormalDistribution[{1, 2, 3}, {{2, 1 / 2, -1 / 3}, {1 / 2, 1, 0}, {-1 / 3, 0, 2 / 3}}]]

Wolfram Language code: Kurtosis[MultinormalDistribution[{1, 2, 3}, {{2, 1 / 2, -1 / 3}, {1 / 2, 1, 0}, {-1 / 3, 0, 2 / 3}}]]

Correlation:

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);

Wolfram Language code: 𝒟1 = MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2], Subscript[μ, 3]}, Σ];

Wolfram Language code:

(R = Correlation[𝒟1])//FullSimplify[#, Subscript[σ, 1] > 0 && Subscript[σ, 2] > 0 && Subscript[σ, 3] > 0]&//MatrixForm

The ImplicitRegion for 3D correlation coefficients of a multinormal distribution:

Wolfram Language code: mat = {{1, r12, r13}, {r12, 1, r23}, {r13, r23, 1}};

Wolfram Language code: 𝒟 = MultinormalDistribution[mat];

Wolfram Language code: corℛ = ImplicitRegion[DistributionParameterAssumptions[𝒟], {{r12, -1, 1}, {r13, -1, 1}, {r23, -1, 1}}];

Use RandomPoint to sample from uniform distribution over 3D correlation coefficients region:

Wolfram Language code: cors = RandomPoint[corℛ, 5000];

Wolfram Language code: Graphics3D[{PointSize[Tiny], StandardBlue, Point[cors]}]

Estimate probability that determinant of the random correlation matrix is less than 0.1:

Wolfram Language code:

Probability[Det[mat] < 0.1, 
	{r12, r13, r23}RandomPoint[corℛ, 10 ^ 5]]//N

Hazard function:

Wolfram Language code:

ParallelTable[Plot3D[HazardFunction[MultinormalDistribution[{-1, 1}, {{1, ρ 2}, {ρ 2, 4}}], {x, y}], ...], {ρ, {-.4, 0.1, 0.8}}]

Univariate marginals follow a NormalDistribution:

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);𝒟 = MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2], Subscript[μ, 3]}, Σ];

Wolfram Language code: MarginalDistribution[𝒟, 1]

Multivariate marginals follow a multivariate normal distribution:

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

Consistent use of Quantity in parameters yields QuantityDistribution:

Wolfram Language code:

measurements𝒟 = MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2], Subscript[μ, 3]}, (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠)] /. {Subscript[μ, 1] -> Quantity[10, "Centimeters"^2], Subscript[σ, 1] -> Quantity[0.1, "Centimeters"^2], Subscript[μ, 2] -> Quantity[15, "Grams"], Subscript[σ, 2] -> Quantity[0.67, "Grams"], Subscript[μ, 3] -> Quantity[270, "Kelvins"], Subscript[σ, 3] -> Quantity[0.25, "Kelvins"], Subscript[ρ, 12] -> 0.4, Subscript[ρ, 13] -> 0, Subscript[ρ, 23] -> -0.1}

Find standard deviations of each measurement:

Wolfram Language code: StandardDeviation[measurements𝒟]

Generalizations & Extensions (1)

MultinormalDistribution[Σ] is understood to have zero mean:

Wolfram Language code:

MultinormalDistribution[(⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠)]

Applications (2)

Show a distribution function and its histogram in the same plot:

Wolfram Language code:

CompareHistogram3D[dist_, {xmin_, xmax_, dx_}, {ymin_, ymax_, dy_}, df_ : PDF, opts___ ? OptionQ] := 
	Module[{hist, dplot}, 
	hist = Histogram3D[RandomVariate[dist, 10 ^ 4], ...];
	dplot = Plot3D[df[dist, {x, y}], ...];
	Show[hist, dplot]
	];

Compare the PDF to its histogram version:

Wolfram Language code: 𝒟 = MultinormalDistribution[{1, 1}, {{2, 1 / 4}, {1 / 4, 3}}];

Wolfram Language code: CompareHistogram3D[𝒟, {-5, 6, 1}, {-3, 7, 1}, PDF]

Compare the CDF to its histogram version:

Wolfram Language code: CompareHistogram3D[𝒟, {-5, 6, 1}, {-3, 7, 1}, CDF]

Specify multinormal distribution for values of three incoming currents to a 4-way node:

Wolfram Language code:

ampDist = MultinormalDistribution[{Quantity[4, "Amperes"], Quantity[1.5, "Amperes"], Quantity[.5, "Amperes"]}, QuantityArray[{{.05, .012, .003}, {.012, .035, .001}, {.003, .001, .02}}, "Amperes" ^ 2]]

Find the distribution of the current leaving the node:

Wolfram Language code:

TransformedDistribution[Subscript[i, 1] + Subscript[i, 2] + Subscript[i, 3], {Subscript[i, 1], Subscript[i, 2], Subscript[i, 3]}ampDist]

Find the 95% confidence interval for the current value:

Wolfram Language code: InverseCDF[%, {(1 - 0.95/2), (1 + 0.95/2)}]

Properties & Relations (10)

Equal probability contours for a bivariate normal distribution:

Wolfram Language code: ContourPlot[PDF[MultinormalDistribution[{0, 0}, {{2, 1 / 2}, {1 / 2, 1}}], {x, y}], {x, -3, 3}, {y, -3, 3}]

The multinormal distribution is closed under affine transformation:

Wolfram Language code:

A = (⁠|     |     |     |
| --- | --- | --- |
| a11 | a12 | a13 |
| a21 | a22 | a23 |
| a31 | a32 | a33 |⁠);b = {b1, b2, b3};

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);

Wolfram Language code:

TransformedDistribution[A.{u, v, w} + b, {u, v, w}MultinormalDistribution[{μ1, μ2, μ3}, Σ]] == MultinormalDistribution[A.{μ1, μ2, μ3} + b, A.Σ.A//Expand]

For specific values:

Wolfram Language code:

M = (⁠|   |   |    |
| - | - | -- |
| 1 | 2 | 3  |
| 4 | 5 | -6 |
| 7 | 8 | 9  |⁠);c = {1, 2, 3};
Σ2 = (⁠|       |       |       |
| ----- | ----- | ----- |
| 3     | 1 / 3 | 3 / 2 |
| 1 / 3 | 2 / 3 | -1    |
| 3 / 2 | -1    | 4     |⁠);

Wolfram Language code: TransformedDistribution[M.{u, v, w} + c, {u, v, w}MultinormalDistribution[{1, -2, 2}, Σ2]]

Relationships to other distributions:

NormalDistribution is the univariate case of multinormal distribution:

Wolfram Language code: PDF[MultinormalDistribution[{μ}, {{σ^2}}], {x}]

Wolfram Language code: PDF[NormalDistribution[μ, σ], x]

Wolfram Language code: FullSimplify[% - %%, σ > 0]

BinormalDistribution is the two-dimensional case of multinormal distribution:

Wolfram Language code: PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], {x, y}]

Wolfram Language code: PDF[MultinormalDistribution[{μ1, μ2}, {{σ1 ^ 2, ρ σ1 σ2}, {ρ σ1 σ2, σ2 ^ 2}}], {x, y}]

Wolfram Language code: % - %%//Simplify[#, σ1 > 0 && σ2 > 0]&

Multinormal distribution is the limit of MultivariateTDistribution as goes to :

Wolfram Language code: Limit[PDF[MultivariateTDistribution[{μ1, μ2}, {{1, ρ}, { ρ, 1}}, ν], {x, y}], ν -> ∞]

Wolfram Language code: PDF[MultinormalDistribution[{μ1, μ2}, {{1, ρ}, { ρ, 1}}], {x, y}]

Wolfram Language code: % - %%//Simplify

Multinormal distribution is related to RiceDistribution:

Wolfram Language code:

𝒟 = TransformedDistribution[Norm[{u, v, w}], {u, v, w}MultinormalDistribution[{α, α, α}, {{β ^ 2, 0, 0}, {0, β ^ 2, 0}, {0, 0, β ^ 2}}]];

Wolfram Language code:

Block[{m = 3 / 2, α = 5, β = 2}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[RiceDistribution[m, α Sqrt[2m], β Sqrt[m]], x], {x, 0, 16}, PlotStyle -> Thick]]]

LogMultinormalDistribution is a transformation of MultinormalDistribution:

Wolfram Language code:

Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};

Wolfram Language code: TransformedDistribution[{Exp[u], Exp[v]}, {u, v}MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]

NormalDistribution can be obtained from MultinormalDistribution:

Wolfram Language code:

Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};TransformedDistribution[u + v, {u, v}MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, Σ]]

MultinormalDistribution is equivalent to CopulaDistribution with multinormal kernel and Gaussian marginals:

Wolfram Language code:

Σ = (⁠|     |     |     |
| --- | --- | --- |
| 1   | ρ12 | ρ13 |
| ρ12 | 1   | ρ23 |
| ρ13 | ρ23 | 1   |⁠);
c𝒟 = CopulaDistribution[{"Multinormal", Σ}, {NormalDistribution[μ1, σ1], NormalDistribution[μ2, σ2], NormalDistribution[μ3, σ3]}];

Corresponding multinormal distribution:

Wolfram Language code: mn𝒟 = MultinormalDistribution[{μ1, μ2, μ3}, Σ * KroneckerProduct[{σ1, σ2, σ3}, {σ1, σ2, σ3}]];

The probability density functions are equal:

Wolfram Language code: PDF[c𝒟, {x, y, z}] == PDF[mn𝒟, {x, y, z}]//Simplify[#, σ1 > 0 && σ2 > 0 && σ3 > 0]&

Possible Issues (2)

MultinormalDistribution is not defined when μ is not a vector of real numbers:

Wolfram Language code: Mean[MultinormalDistribution[{1, I}, {{2, 1 / 2}, {1 / 2, 1}}]]

MultinormalDistribution is not defined when the dimensions of μ and Σ are not consistent:

Wolfram Language code: Mean[MultinormalDistribution[{1, 2, 3}, {{2, 1 / 2}, {1 / 2, 1}}]]

MultinormalDistribution is not defined when Σ is not symmetric and positive definite:

Wolfram Language code: Mean[MultinormalDistribution[{1, 2}, {{2, 8}, {1 / 2, 1}}]]

Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:

Wolfram Language code:

Mean[MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {{Subscript[σ, 11]^2, ρ * Subscript[σ, 11] * Subscript[σ, 22]}, {ρ * Subscript[σ, 11] * Subscript[σ, 22], Subscript[σ, 22]^2}}]] /. {Subscript[μ, 1] -> 1, Subscript[μ, 2] -> I}

Top

More Learning

Tech Support

Data Science, Finance & Business

Engineering

Science & Technology

Technology for Education

Education Initiatives

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

MultinormalDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (8)

Generalizations & Extensions (1)

Applications (2)

Properties & Relations (10)

Possible Issues (2)

Text

CMS

APA

BibTeX

BibLaTeX

MultinormalDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (8)

Generalizations & Extensions (1)

Applications (2)

Properties & Relations (10)

Possible Issues (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX